批处理之家 - Powered by Discuz! Board

标题: [文件操作] 求助，批处理如何判断变量是否为空？ [打印本页]

作者: LTSC1809 时间: 2023-7-9 16:30 标题: 求助，批处理如何判断变量是否为空？

我写了这样一段代码，用来全盘扫描Yua.exe这个文件，如果找到了那么显示它的具体路径，如果没找到那么显示aaa三个字，但是现在发现无论如何都无法显示aaa，明明没有找到这个文件。代码如下，我试过两种方案，都不行。分别是

@echo off
rem 指定待搜索的文件
set "FileName=Yua.exe"
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
  if exist %%a:\ (
    for /f "delims=" %%b in ('dir /a-d /s /b "%%a:\*%FileName%" 2^>nul') do (
      if /i "%%~nxb" equ "%FileName%" (
        echo %%b
	set a=%%b
	if "%a%" equ "" echo aaa
      )
    )
  )
)
pause
复制代码

和

@echo off
rem 指定待搜索的文件
set "FileName=Yua.exe"
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
  if exist %%a:\ (
    for /f "delims=" %%b in ('dir /a-d /s /b "%%a:\*%FileName%" 2^>nul') do (
      if /i "%%~nxb" equ "%FileName%" (
        echo %%b
	set a=%%b
	if not defined %a% echo aaa
      )
    )
  )
)
pause
复制代码

就算直接判断%%b是否为空，也不行。怎么办？

作者: BingjianREMIX 时间: 2023-7-9 17:25

回复 1# LTSC1809

两段代码的7行

2>nul
复制代码

改成

1>nul
复制代码

作者: LTSC1809 时间: 2023-7-9 17:30

回复 2# BingjianREMIX

现在变成了这样，输出了好几个找不到文件，还是没显示aaa

正在搜索，请稍候...
找不到文件
找不到文件
找不到文件
找不到文件
请按任意键继续. . .
复制代码

作者: BingjianREMIX 时间: 2023-7-9 18:01

找不到就好了吗

作者: 77七 时间: 2023-7-9 18:03

@echo off
rem 指定待搜索的文件
set "FileName=Yua.exe"
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
	if exist %%a:\ (
		for /f "delims=" %%b in ('dir /a-d /s /b "%%a:\*%FileName%" 2^>nul') do (
			if /i "%%~nxb" equ "%FileName%" (
				echo %%b
				set a=1
			)
		)
	)
)
if not defined a (
	echo aaa
)
pause
复制代码

作者: LTSC1809 时间: 2023-7-9 18:04

回复 4# BingjianREMIX

不行，我现在要求if判断它是否找不到，这个内容到时候要用到另一个bat里的，那个需要当找不到时自动打开一个网址，并且还要显示找不到文件，请自行下载，三秒后为您打开的提示

作者: BingjianREMIX 时间: 2023-7-9 18:06

回复 6# LTSC1809

那直接if not exist不就好了

作者: LTSC1809 时间: 2023-7-9 20:30

回复 7# BingjianREMIX

不可以，我需要先全盘寻找这个文件，如果这样，我又不知道它在什么路径下，我怎么输入if exist的路径是什么呢

作者: Batcher 时间: 2023-7-10 12:12

回复 1# LTSC1809

@echo off
REM 指定待搜索的文件
set "FileName=Yua.exe"
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist %%a:\ (
        for /f "delims=" %%b in ('dir /b /s /a-d "%%a:\*%FileName%" 2^>nul') do (
            if /i "%%~nxb" equ "%FileName%" (
                echo %%b
                set a=1
            )
        )
    )
)
if not defined a (
    echo 找不到文件，请自行下载
    ping -n 4 127.0.0.1 >nul
    start www.baidu.com
)
pause
复制代码

欢迎光临批处理之家 (http://bbs.bathome.net/)