批处理之家 - Powered by Discuz! Board

标题: [文本处理] 【已解决】bat怎样指定字符行分割成多个文本？ [打印本页]

作者: zllk 时间: 2023-9-16 20:44 标题: 【已解决】bat怎样指定字符行分割成多个文本？

本帖最后由 zllk 于 2023-9-17 11:37 编辑

“文档”文件夹有以下文件：
01.txt
02.txt

01.txt文本内容如下：

ABCD
A
CD
ABCD
EF
A
批处理
复制代码

执行批处理效果

例如01.文档01.txt文本内容如下：

ABCD
复制代码

例如01.文档02.txt文本内容如下：

C
CD
ABCD
EF
复制代码

例如01文档03.txt文本内容如下：

C
批处理
复制代码

“文档”文件夹有以下文件：
01.txt
01.文档01.txt
01.文档02.txt
01.文档03.txt
02.txt
02.文档01.txt
02.文档02.txt

作者: 77七 时间: 2023-9-16 21:52

@echo off
set n=101
for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
	setlocal
	for /f "useback delims=" %%a in ("%%i") do (
		if "%%a" equ "A" (
			if exist "%%~ni文档%n:~-2%.txt" (
				set /a n+=1
			)
			set str=123456%%a
		) else (
			set str=%%a
		)
		setlocal enabledelayedexpansion
		>>"%%~ni文档!n:~-2!.txt" echo !str!
		endlocal
	)
	endlocal
)
pause
复制代码

作者: zllk 时间: 2023-9-17 03:02

本帖最后由 zllk 于 2023-9-17 11:40 编辑

回复 2# 77七

谢谢

作者: 77七 时间: 2023-9-17 06:00

本帖最后由 77七于 2023-9-17 11:27 编辑

回复 3# zllk

@echo off
set n=101
for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
	setlocal
	for /f "tokens=1* delims=[]" %%a in ('find /n /v "" ^<"%%i"') do (
		if "%%b" equ "A" (
			if exist "%%~ni.文档%n:~-2%.txt" (
				set /a n+=1
			)
			set str=C
		) else (
			set str=%%b
		)
		setlocal enabledelayedexpansion
		>>"%%~ni.文档!n:~-2!.txt" echo=!str!
		endlocal
	)
	endlocal
)
pause
复制代码

作者: hfxiang 时间: 2023-9-17 09:54

回复 3# zllk

可用第 3 方工具 gawk （ http://bcn.bathome.net/tool/4.1.0/gawk.exe ）来实现。
bat 脚本方式如下：

@echo off
::保存为ANSI编码
cd /d "%~dp0"
for /f "usebackq delims=" %%a IN (`dir/b *.txt^|findstr /RE /V "\.文档.[0-9][0-9]*\.txt"`) DO @gawk "FNR==1{i=1;F=substr(FILENAME,1,length(FILENAME)-3);Fn=sprintf(\"%%s文档%%02d%%s\",F,i,\".txt\")}/^A$/{$0=\"12345A\";if(NR==1){i=1}else{i++};Fn=sprintf(\"%%s文档%%02d%%s\",F,i,\".txt\")}{print $0>(Fn)}" %%a
复制代码

命令行方式如下:

for /f "usebackq delims=" %a IN (`dir/b *.txt^|findstr /RE /V "\.文档.[0-9][0-9]*\.txt"`) DO @gawk "FNR==1{i=1;F=substr(FILENAME,1,length(FILENAME)-3);Fn=sprintf(\"%s文档%02d%s\",F,i,\".txt\")}/^A$/{$0=\"12345A\";if(NR==1){i=1}else{i++};Fn=sprintf(\"%s文档%02d%s\",F,i,\".txt\")}{print $0>(Fn)}" %a
复制代码

作者: zllk 时间: 2023-9-17 10:52

本帖最后由 zllk 于 2023-9-17 11:40 编辑

回复 4# 77七

非常感谢，很好用

作者: 77七 时间: 2023-9-17 11:27

回复 6# zllk

已在4楼修改。

欢迎光临批处理之家 (http://bbs.bathome.net/)