Board logo

标题: [注册表类] [已解决]注册表指定路径下，含有关键字的键值。如何搜索并删除？ [打印本页]
作者: ygqiang    时间: 2023-9-28 10:28     标题: [已解决]注册表指定路径下，含有关键字的键值。如何搜索并删除？

本帖最后由 ygqiang 于 2023-9-28 14:44 编辑

[已解决]注册表指定路径下，含有关键字的键值。如何搜索并删除？

HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Run

关键字是：MicrosoftEdgeAutoLaunch

键值名如下类似的，可能还有其他更多的。
MicrosoftEdgeAutoLaunch_98769996E24836F99EC8617644423B4C
MicrosoftEdgeAutoLaunch_ED290F2741A0DC7799A9C29B127CCBAC
MicrosoftEdgeAutoLaunch_B8188322885C6DD24FAC5C8FE26E079B
MicrosoftEdgeAutoLaunch_85C848D66A0F5F006EC89D7F6F2AD429
。。。等等类似的

删除某个键值
reg delete "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Run" /v "键值名" /f
作者: Batcher    时间: 2023-9-28 12:15

回复 1# ygqiang


test-1.bat
  1. @echo off

  2. set "RegKey=HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Run"

  3. set "StrKey=MicrosoftEdgeAutoLaunch"

  4. for /f "delims=" %%i in ('reg query "%RegKey%" ^| findstr /i /c:"%StrKey%"') do (

  5.     set "StrFull=%%i"

  6.     setlocal enabledelayedexpansion

  7.     for /f "delims=|" %%a in ("!StrFull:    =|!") do (

  8.         reg delete "%RegKey%" /v "%%a" /f

  9.     )

  10.     endlocal

  11. )
复制代码
作者: Batcher    时间: 2023-9-28 13:19

回复 1# ygqiang


test-2.bat
  1. @echo off

  2. set "RegKey=HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Run"

  3. set "StrKey=MicrosoftEdgeAutoLaunch"

  4. for /f "tokens=*" %%i in ('reg query "%RegKey%" ^| findstr /i /c:"%StrKey%"') do (

  5.     set "StrFull=%%i"

  6.     setlocal enabledelayedexpansion

  7.     set "StrSuffix=!StrFull:*    REG_SZ=!"

  8.     call set "ValueName=%%StrFull:    REG_SZ!StrSuffix!=%%"

  9.     reg delete "%RegKey%" /v "!ValueName!" /f

  10.     endlocal

  11. )
复制代码
作者: ygqiang    时间: 2023-9-28 14:28

回复  ygqiang


test-2.bat
Batcher 发表于 2023-9-28 13:19



    这个代码，
echo reg delete "%RegKey%" /v "!ValueName!" /f >b1.txt
测试输出结果b1.txt内容如下：

reg delete "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Run" /v "MicrosoftEdgeAutoLaunch_B8188322885C6DD24FAC5C8FE26E079B    " /f

键值后面带空格了。
作者: Batcher    时间: 2023-9-28 14:39

回复 4# ygqiang


点击右上角的COPY按钮复制代码，不要使用鼠标选中之后再复制。
如果还是不行，而且你也不知道如何调整test-2.bat，那么就先用test-1.bat吧。
作者: ygqiang    时间: 2023-9-28 14:43

回复  ygqiang


点击右上角的COPY按钮复制代码，不要使用鼠标选中之后再复制。
如果还是不行，而且你 ...
Batcher 发表于 2023-9-28 14:39



    谢谢，代码正常了



欢迎光临 批处理之家 (http://bbs.bathome.net/) Powered by Discuz! 7.2