@echo off&setlocal enabledelayedexpansion
(set/p=初始化中, 请稍等...<nul)&(call :initRoots)
echo.&echo cmd 下最大正整数 2147483647 (2^^31-1) 的各次方根整数部分(次数2--30):
(for /l %%a in (2,1,30) do set /p=!root%%a!,<nul) & (echo  )
:loop
set/p i=请输入正整数:
if %i% lss 1 goto loop
if %i% equ 1 echo 1的任意次方=1&goto loop
set /a exp=1
for /l %%a in (2,1,30) do if %i% leq !root%%a! set /a exp+=1
echo %i%的%exp%次方接近于cmd最大值.
goto loop

:initRoots 初始化 cmd 下最大正整数 2147483647 (2^31-1) 的各次方根(次数2--30)
for /l %%a in (2,1,30) do (call :searchRoot root%%a 2 50000 %%a)& set /p=^>^><nul
exit /b

:checkOverflow overflow x y rem 检测 x^y 是否溢出
(set tc=%2)&(set te=%3)
:next
if !te! gtr 1 set /a "t0=tc,tc*=%2,t1=tc/ %2,te-=1"
if !t0! neq !t1! (set %1=yes)&(exit /b)
if !t0! geq !tc! (set %1=yes)&(exit /b)
if !tc! leq 0 (set %1=yes)&(exit /b) else if !te! leq 1 (set %1=no)&(exit /b) else goto next
exit /b

:searchRoot root lower upper time
set /a "ll=%2,uu=%3"
:schNext
set /a t=(ll+uu)/2
if !t! equ !ll! set /a "%1=t" & exit /b
call :checkOverflow ofl !t! %4
if /i "!ofl!"=="yes" (set /a "uu=t") else (set /a "ll=t")
goto schNext
exit /b
复制代码

@echo off&setlocal enabledelayedexpansion
set t=1
:searchMaxInt
set /a "t<<=1"
if !t! leq 0 ((set /a "t>>=1,maxInt=t-1+t")& echo cmd 下最大正整数为:!maxInt!) else goto searchMaxInt

(set/p=初始化中, 请稍等...<nul)&(call :initRoots)
echo.&echo cmd 下最大正整数 !maxInt! 的各次方根整数部分(整数部分≥2)(次数2--!expMax!):
(for /l %%a in (2,1,!expMax!) do set /p=!root%%a!,<nul) & (echo  )
:loop
set/p i=请输入正整数:
if %i% lss 1 goto loop
if %i% equ 1 echo 1的任意次方=1&goto loop
set /a exp=1
for /l %%a in (2,1,!expMax!) do if %i% leq !root%%a! set /a exp+=1
echo %i%的%exp%次方接近于cmd最大值.
goto loop

:initRoots 初始化 cmd 下最大正整数 !maxInt! 的各次方根(次数2--!expMax!)
for /l %%a in (2,1,256) do (call :searchRoot root%%a 1 !maxInt!/2 %%a)&(if !root%%a! lss 2 set /a expMax=%%a-1& exit /b)& set /p=^>^><nul
exit /b

:checkOverflow overflow x y rem 检测 x^y 是否溢出
(set tc=%2)&(set te=%3)
:next
if !te! gtr 1 set /a "t0=tc,tc*=%2,t1=tc/ %2,te-=1"
if !t0! neq !t1! (set %1=yes)&(exit /b)
if !t0! geq !tc! (set %1=yes)&(exit /b)
if !tc! leq 0 (set %1=yes)&(exit /b) else if !te! leq 1 (set %1=no)&(exit /b) else goto next
exit /b

:searchRoot root lower upper time 二分法搜索方根
set /a "ll=%2,uu=%3"
:schNext
set /a t=(ll+uu)/2
if !t! equ !ll! set /a "%1=t" & exit /b
call :checkOverflow ofl !t! %4
if /i "!ofl!"=="yes" (set /a "uu=t") else (set /a "ll=t")
goto schNext
exit /b
复制代码

@echo off&setlocal
:loop2
set /p num=请输入大于1的正整数：
echo.
set count=0
set temp=1
:loop
set /a count+=1
set /a temp1=temp
rem 为了避免set/a的对超大的溢出数自动纠错，直接引用原数，并屏蔽可能的错误输出
set /a temp*=%num% 2>nul
set /a temp2=temp/%num% 2>nul
if "%temp1%"=="%temp2%"	goto :loop
set /a count-=1
echo %num%的%count%次方接近于cmd的最大值。
echo.
goto :loop2
复制代码

@echo off&setlocal enabledelayedexpansion 2>nul 3>nul
set n=1
set /p num=请输入大于1的正整数：
for /l %%a in (1 1 31) do (
set /a n*=num,"max+=^!((n-1)>>31)","test=1/n+1/(!max!-max)"||goto re
)
:re
echo %max%
pause
复制代码

@echo off&setlocal enabledelayedexpansion 2>nul 3>nul
set n=2147483648
set /p num=请输入大于1的正整数：
for /l %%a in (1 1 31) do (
set /a n/=num,"max+=^!((n-1)>>31)","test=1/n+1/(!max!-max)"||goto re
)
:re
echo %max%
pause
复制代码

@echo off&setlocal
:loop2
set /p num=请输入绝对值大于1的整数（可以是负数）：
echo.
set count=0
set temp=1
:loop
set /a temp1=temp
rem 为了避免set/a的对超大的溢出数自动纠错，直接引用原数，并屏蔽可能的错误输出
set /a temp*=%num% 2>nul
set /a temp2=temp/%num% 2>nul
rem 如果次方结果乘以整数n再除以整数n不再是原值，则认为乘方结果已接近溢出，跳出
if not "%temp1%"=="%temp2%"                                  goto :jump
if %count% gtr 1024 echo 程序溢出，请确认输入的整数是否正确&pause&goto :eof
set /a count+=1
goto :loop
:jump
echo %num%的%count%次方接近于cmd的最大值。
echo.
goto :loop2
复制代码

@echo off &setlocal enabledelayedexpansion
for /l %%i in  (1,1,256) do (
    set /a "_tmp=1<<%%i"
    if !_tmp! leq 0 (
        set /a "t2=%%i-1"
        set  /a "max=((1<<!t2!)-1)+(1<<!t2!)"
        goto 2out
    )
)
:2out
echo 2的!t2!次方最接近极大值!max!
pause>nul
复制代码

@echo off &setlocal enabledelayedexpansion
:input
cls
set /p _n=请输入正整数：
set /a  n=!_n!&&if  !n! lss 2 goto input
set  /a "varup=1,vardn=2147483647"
for /l %%i in (1,1,30) do (
        set /a "varup=!varup!*!n!,vardn=!vardn!/!n!"
        set /a "var=!vardn!/!varup!"
        if !var! lss !n! (
                if !var! equ 0 (set /a "cnt=2*%%i-1" && goto out)
                set /a "cnt=2*%%i" && goto out
        )
)
:out
echo !n!的!cnt!次方接近最大值！
PAUSE&goto input
复制代码

@echo off
set n=2
:loop
set /a "test=1/(1073741824*n)" 2>nul||echo %n%
set /a n+=2
if %n% lss 100 goto:loop
pause
复制代码

@echo off
set /p in=请输入正整数:
set /a inx=in
for /l %%i in (1,1,100) do (
2>nul  set /a ix=inx*in,"1/!(ix / inx - in)",inx=ix ||call :end %%i
)
:end
echo %in%的%1次方接近于CMD最大值，值为%inx%。
pause>nul&exit
复制代码

@echo off
set /p in=请输入整数:
set /a inx=in,flag=1&for /l %%i in (1,1,30) do (
2>nul set /a 1/flag,cs=%%i,ix=inx*in,"1/!(ix / inx - in)",inx=ix ||set flag=0)
echo %in%的%cs%次方接近于CMD最大值，值为%inx%。
pause>nul
复制代码