<item>
		<!-- Stormbringer -->
		<ingredient count="1" id="72" />
		<!-- Red Soul Crystal - Stage 5 -->
		<ingredient count="1" id="4634" />
		<!-- Gemstone C -->
		<ingredient count="97" id="2131" />
		<!-- Adena -->
		<ingredient count="291000" id="57" />
		<!-- Stormbringer - Critical Anger -->
		<production count="1" id="4681" />
	</item>
	<item>
		<!-- Stormbringer -->
		<ingredient count="1" id="72" />
		<!-- Green Soul Crystal - Stage 5 -->
		<ingredient count="1" id="4645" />
		<!-- Gemstone C -->
		<ingredient count="97" id="2131" />
		<!-- Adena -->
		<ingredient count="291000" id="57" />
		<!-- Stormbringer - Focus -->
		<production count="1" id="4682" />
	</item>
复制代码

for f in *.xml; do awk -v RS='</item>' -F '\n' '/Soul Crystal/{for(i=1;i<=NF;i++){if($i~/Soul Crystal/){gsub(".*id=\"|\".*","",$(i+1));gsub(".*id=\"|\".*","",$(NF-1));print $(i+1)","$(NF-1)}}}' "$f" > "$f.csv"; done
复制代码

@echo off &setlocal enabledelayedexpansion
findstr /inc:"Soul Crystal" /inc:"</item>" "test.xml" 2>nul>tmp.0
(for /f "tokens=1 delims=:" %%k in (tmp.0) do (
	if not defined v1 (call :getV "test.xml" %%k v1) else (
		set/a "n=%%k-2"
		(call :getV "test.xml" !n! v2)
		echo,!v1!,!v2!
		set "v1="
	)
))>"test.csv"
del /q tmp.0
endlocal &pause &exit/b
:getV //%1=文件名 %2=行号 %3=返回值变量名
	for /f "usebackq skip=%~2 delims=" %%s in ("%~1") do (
		for /f tokens^=1-4^delims^=^" %%1 in ("%%~s") do (set "%~3=%%4")
		exit/b
	) & exit/b
复制代码

@echo off
cd /d "%~dp0"
(for %%i in (*.xml) do (
	setlocal
	for /f "useback delims=" %%a in ("%%i") do (
		set str=%%a
		setlocal enabledelayedexpansion
		set "str1=!str:Soul Crystal=!"
		set "str2=!str:	</item>=!"
		if "!str!" neq "!str1!" (
			endlocal
			set m=1
		) else if defined m (
			endlocal
			for /f tokens^=4delims^=^" %%x in ("%%a") do (
				set n=%%x
			)
			set m=
		) else if "!str!" neq "!str2!" (
			endlocal
			if defined n (
				setlocal enabledelayedexpansion
				for /f tokens^=4delims^=^" %%x in ("!_str!") do (
					echo !n!,%%x
				)
				endlocal
				set n=
			)
		) else (
			endlocal
		)
		set _str=%%a
	)
	endlocal
))>data.csv
pause
复制代码

awk -v"OFS=," "/^\t+<item>$/,/^\t+<\/item>$/{if(/Soul Crystal/)exist_id=1;if(/^\t+<ingredient count=\"1\" id=\"[0-9]+\" \/>$/)if(exist_id)A=gensub(/^\t+<ingredient count=\"1\" id=\"([0-9]+)\" \/>$/,\"\\1\",\"g\",$0);if(/^\t+<production count=\"1\" id=\"[0-9]+\" \/>$/)if(exist_id)print A,gensub(/^\t+<production count=\"1\" id=\"([0-9]+)\" \/>$/,\"\\1\",\"g\",$0);if(/^\t+<\/item>$/)exist_id=0}" *.xml>out.csv
复制代码

@if(0)==(0) echo off
dir /b *.xml | cscript -nologo -e:jscript "%~f0" > result.csv
pause & exit
@end

var fso = new ActiveXObject('Scripting.FileSystemObject');

while(!WSH.StdIn.AtEndOfStream) {
    var f = WSH.StdIn.ReadLine();
    var s = fso.OpenTextfile(f, 1).ReadAll();
    var m = s.match(/<item>(?:(?!<\/?item>)[\s\S])+<\/item>/g);
    for(var i=0; i<m.length; i++) {
        var m1 = m[i].match(/\bSoul Crystal\b.+\n(?:(?!\bid=).)+\bid="([^"]+)"/);
        var m2 = m[i].match(/\bproduction\b(?:(?!\bid=).)+\bid="([^"]+)"/);
        if(m1 && m2) WSH.Echo(m1[1] + ',' + m2[1]);
    }
}
复制代码

@if(0)==(0) echo off
dir /b *.xml | cscript -nologo -e:jscript "%~f0" > result.csv
pause & exit
@end

var xml = new ActiveXObject('Microsoft.XMLDOM');
var reg = /\bSoul Crystal\b/;

while(!WSH.StdIn.AtEndOfStream) {
    var f = WSH.StdIn.ReadLine();
    getXmlData(f);
}

function getXmlData(fileName) {
    xml.load(fileName);
    var nodes = xml.selectNodes('//item');
    for(var i=0; i<nodes.length; i++) {
        var s2 = nodes[i].lastChild.getAttribute('id');
        var childs = nodes[i].childNodes;
        for(var j=0; j<childs.length; j++) {
            if(childs[j].nodeName == '#comment' && reg.test(childs[j].text)) {
                var s1 = childs[j+1].getAttribute('id');
                WSH.Echo(s1 + ',' + s2);
                break;
            }
        }
    }
}
复制代码

@echo off&chcp 936
echo 进行中,请耐心等待
set "outfile=___output.csv"

cd.>"%outfile%"
for %%b in ("*.xml") do (
setlocal
echo,file,%%~b>>%outfile%
(for /f "skip=1 delims=" %%c in ('findstr /n .* "%%~b"') do (
set line1=
set /p line1=
set line2=%%c

if not defined item (
setlocal enabledelayedexpansion
if "!line1:<item>=!" neq "!line1!" (
for %%- in (1) do endlocal&set item=%%-) else endlocal
) else (

setlocal enabledelayedexpansion
if "!line1:Soul Crystal=!" neq "!line1!" (
set line3=!line2:* =!&set line3=!line3:~0,-2!
2>nul set /a !line3:id=,id!
for %%- in ("!id!") do endlocal&set o=%%~-&set match=1
if "!p!" == "!q!" endlocal
) else endlocal

if defined match (
setlocal enabledelayedexpansion
if "!line2:</item>=!" neq "!line2!" (
set line3=!line1:* =!&set line3=!line3:~0,-2!
2>nul set /a !line3:id=,id!
echo,!o!,!id!
endlocal&set o=&set match=&set item=
) else endlocal
)

)
))<"%%~b">>"%outfile%"
endlocal
)
echo,&echo 完成&pause
复制代码

$out = [Collections.ArrayList]@();
$comments = Select-XML *.xml -XPath '//item/comment()[contains(string(),"Soul Crystal")]'; #item节点中包含关键字的注释节点

forEach ($comment In $comments) {
    $s1 = $comment.Node.NextSibling.NextSibling.id;
    $s2 = $comment.Node.ParentNode.production.id;
    if ($s1 -ne $null -and $s2 -ne $null) {
        [void]$out.Add($s1 + ',' + $s2);
    }
}

sc 1.csv -Value $out;
复制代码

@echo off
(for /f "delims=" %%i in ('findstr /m /c:"Soul Crystal" *.xml') do (
    for /f "tokens=1,3,4" %%a in ('type "%%i"') do (
        if "%%a"=="<item>" (
            set x=true
        ) else if "%%a"=="</item>" (
            set x=
            setlocal enabledelayedexpansion
            for /f "tokens=2 delims==" %%d in ("!str1!") do echo,!str2!,%%~d
            endlocal
        ) else if defined x (
            if "%%b%%c"=="SoulCrystal" (
                set y=true
            ) else if defined y (
                set y=
                for /f "tokens=2 delims==" %%d in ("%%b") do set str2=%%~d
            )
            set str1=%%b
        )
    )
))>out.csv
pause
复制代码

@echo off
(for /f "delims=" %%i in ('findstr /m /c:"Soul Crystal" *.xml') do (
    setlocal enabledelayedexpansion
    for /f "tokens=1,2 delims=:	 " %%j in ('findstr /ilnc:"Soul Crystal" /inc:"</item>" "%%i"') do (
        set n=%%j
        if "%%k"=="</item>" (
            set /a n-=1
            set _!n!=true
        ) else (
            set /a n+=1
            set #!n!=true
        )
    )
    for /f "tokens=1,4 delims=:	 " %%a in ('findstr /n .* "%%i"') do (
        if defined #%%a (
            for /f "tokens=2 delims==" %%c in ("%%b") do set "str=%%~c"
        ) else if defined _%%a (
            for /f "tokens=2 delims==" %%c in ("%%b") do echo,!str!,%%~c
        )
    )
    endlocal
))>out.csv
pause
复制代码

@echo off
set "XPath1=//item/comment()[contains(string(),'Soul Crystal')]/following-sibling::*[1]"
set "XPath2=//item/comment()[contains(string(),'Soul Crystal')]/following-sibling::*[last()]"
setlocal enabledelayedexpansion
(for %%i in (*.xml) do (
    for /f %%j in ('xml sel -t -m "%XPath1%|%XPath2%" -n -v "@id" "%%i"') do (
        if defined s (
            echo;!s!,%%j
            set "s="
        ) else (
            set "s=%%j"
        )
    )
)) > 0.csv
pause
复制代码

sed -r -n "/<item>/,/<\/item>/{/Soul Crystal/,/production/{/Soul Crystal/{n;h};/production/{G;s/^.*id=\"([0-9]+)\".*\n.*id=\"([0-9]+)\".*$/\2,\1/;p}}}" *.xml > 1.csv
复制代码