Board logo

标题: [文本处理] 批处理如何检测一段字符/串中是否有指定的字符/串？ [打印本页]
作者: BingjianREMIX    时间: 2023-12-23 23:23     标题: 批处理如何检测一段字符/串中是否有指定的字符/串？

如题,概括了一下大概:
具体:
检测一段字符或字符串中是否有指定的字符或字符串
如:检测"echo"和"echo on"中是否有"echo on"
  1. @echo off

  2. set "x=echo"

  3. set "y=echo on"

  4. set "z=echo on"

  5. ::两串字符

  6. set a="%x%"

  7. set c="%y%"

  8. ::指定字符或串

  9. set b="%z%"

  10. echo %a%| findstr %b% >nul && (

  11.     echo %a%包含%b%

  12. ) || (

  13.     echo %a%不包含%b%

  14. )

  15. echo %c%| findstr %b% >nul && (

  16.     echo %c%包含%b%

  17. ) || (

  18.     echo %c%不包含%b%

  19. )

  20. 

  21. pause
复制代码
上述代码得到
  1. E:\office>e:\office\lib\new\reset\检测字符串内是否有指定字符或串.bat

  2. "echo"包含"echo on"

  3. "echo on"包含"echo on"

  4. Press any key to continue . . . 

  5. 

  6. E:\office>  
复制代码
求解,谢谢
作者: 77七    时间: 2023-12-23 23:34

参考： [批处理命令一日一教学 续]（13）字符串查找增强：findstr
帮助信息 第29-32行
作者: BingjianREMIX    时间: 2023-12-23 23:47

本帖最后由 BingjianREMIX 于 2023-12-23 23:53 编辑

回复 2# 77七


    我需要查找"echo on"这个整体,添加/c后finstr出现报错,并且都不匹配
  1. E:\office>e:\office\lib\new\reset\检测字符串内是否有指定字符或串.bat

  2. FINDSTR: Cannot open echo on

  3. "echo"不包含"echo on"

  4. FINDSTR: Cannot open on

  5. FINDSTR: Cannot open echo on

  6. "echo on"不包含"echo on"

  7. Press any key to continue . . . 

  8. 

  9. E:\office>
复制代码
作者: 77七    时间: 2023-12-24 00:09

回复 3# BingjianREMIX


  
  1. @echo off

  2. set "x=echo"

  3. set "y=echo on"

  4. set "z=echo on"

  5. ::两串字符

  6. set a="%x%"

  7. set c="%y%"

  8. ::指定字符或串

  9. set b="%z%"

  10. 

  11. set "_b=%b:"=\"%"

  12. echo %a%| findstr /c:"%_b%" >nul && (

  13.     echo %a%包含%b%

  14. ) || (

  15.     echo %a%不包含%b%

  16. )

  17. 

  18. echo %c%| findstr /c:"%_b%" >nul && (

  19.     echo %c%包含%b%

  20. ) || (

  21.     echo %c%不包含%b%

  22. )

  23. 

  24. pause
复制代码
作者: BingjianREMIX    时间: 2024-2-9 21:23

回复 4# 77七


    如果是需要让echo off & cls,echo off & dir等的也能检测出echo off呢
作者: 77七    时间: 2024-2-10 14:02

本帖最后由 77七 于 2024-2-10 14:14 编辑

回复 5# BingjianREMIX 

  1. set "str1=echo off & cls"

  2. set str2=echo off

  3. setlocal enabledelayedexpansion

  4. echo !str1!|find "%str2%" 1>nul && echo ok
复制代码
  1. for /f "delims=" %%a in ("echo off & cls") do (

  2.         echo %%a|find "echo off" 1>nul && echo ok

  3. )
复制代码
  1. echo echo off ^& cls|find "echo off" 1>nul && echo ok
复制代码
  1. set "str=echo off & cls"

  2. set /p="%str%"<nul|find "echo off" 1>nul && echo ok
复制代码
  1. set "str1=echo off & cls"

  2. set str2=echo off

  3. setlocal enabledelayedexpansion

  4. set "_str=!str1:%str2%=!"

  5. if "!_str!" neq "!str1!" (

  6. 	echo ok

  7. )
复制代码




欢迎光临 批处理之家 (http://bbs.bathome.net/) Powered by Discuz! 7.2