批处理之家 - Powered by Discuz! Board

标题: [系统相关] 批处理怎么获取操作系统型号 [打印本页]

作者: jshuanya 时间: 2024-1-19 11:35 标题: 批处理怎么获取操作系统型号

求批处理怎么获取操作系统型号的语句，网上看到很多都不能识别现在的win 10 ，win 11了。

作者: gfd 时间: 2024-1-19 14:05

本帖最后由 gfd 于 2024-1-19 14:07 编辑

ver
wmic os
wmic os get Caption

作者: jshuanya 时间: 2024-1-19 20:09

ver
wmic os
wmic os get Caption
gfd 发表于 2024-1-19 14:05

能否直接导出其中的操作系统，最好是包含多少位的，是32位还是64位

作者: gfd 时间: 2024-1-19 21:27

回复 3# jshuanya

http://www.bathome.net/thread-68226-1-1.html

作者: gfd 时间: 2024-1-19 21:28

回复 3# jshuanya

@echo off
setlocal enabledelayedexpansion

for /f "tokens=1* delims=:=" %%a in ('"wmic os get Caption,InstallDate,OSArchitecture,Version /Format:List"') do (
    IF /I "%%a"=="Caption" set Caption=%%b
    IF /I "%%a"=="InstallDate" set InstallDate=%%b
    IF /I "%%a"=="OSArchitecture" set OSArchitecture=%%b
    IF /I "%%a"=="Version" set Version=%%b
)
echo Windows_信息：%Caption%%Version% 【%OSArchitecture%】 安装日期：%InstallDate:~0,4%年%InstallDate:~4,2%月%InstallDate:~6,2%日_%InstallDate:~8,2%点%InstallDate:~10,2%分%InstallDate:~12,2%秒
echo.
pause
复制代码

作者: jshuanya 时间: 2024-1-20 09:44

回复 5# gfd

牛，非常好用。

作者: hfxiang 时间: 2024-1-21 16:06

把5楼的脚本变换了一下

（只变了for的表述形式，本质完成一样）

@echo off
for /f "tokens=* delims=:=" %%a in ('"wmic os get Caption,InstallDate,OSArchitecture,Version /Format:List"^|findstr ^=') do set "%%~a"
echo Windows_信息：%Caption%%Version% 【%OSArchitecture%】 安装日期：%InstallDate:~0,4%年%InstallDate:~4,2%月%InstallDate:~6,2%日_%InstallDate:~8,2%点%InstallDate:~10,2%分%InstallDate:~12,2%秒
echo.
pause
复制代码

作者: jshuanya 时间: 2024-1-21 20:34

把5楼的脚本变换了一下（只变了for的表述形式，本质完成一样）
hfxiang 发表于 2024-1-21 16:06

也可以用哦。谢谢。

欢迎光临批处理之家 (http://bbs.bathome.net/)