批处理之家 - Powered by Discuz! Board

标题: [文本处理] 如何把隐藏和解除隐藏文件的两个批处理合二为一？ [打印本页]

作者: FU8989 时间: 2009-12-22 14:37 标题: 如何把隐藏和解除隐藏文件的两个批处理合二为一？

隐藏批处理

@echo off
attrib e:\minefilm +s +h
attrib e:\minephoto +s +h
attrib g:\minefilm +s +h
attrib e:\数码图片 +s +h
复制代码

解除隐藏批处理

@echo off
attrib e:\minefilm -s -h
attrib e:\minephoto -s -h
attrib g:\minefilm -s -h
attrib e:\数码图片 -s -h
复制代码

怎样合并为一个批处理操作按一下隐藏再一下解除隐藏谢谢各位

作者: bluewing009 时间: 2009-12-22 14:45

@echo off
attrib e:\minefilm +s +h
attrib e:\minephoto +s +h
attrib g:\minefilm +s +h
attrib e:\数码图片 +s +h
pause
::下面是解除隐藏。
 attrib e:\minefilm -s -h
attrib e:\minephoto -s -h
attrib g:\minefilm -s -h
e:\数码图片 -s -h
复制代码

作者: FU8989 时间: 2009-12-22 14:54 标题: 回复 2楼的帖子

怎样合并为一个批处理谢谢

作者: neorobin 时间: 2009-12-22 16:14

@echo off & setlocal enabledelayedexpansion
for /d %%f in (e:\minefilm E:\minephoto g:\minefilm e:\数码图片) do (
  (set attr=%%~af)
  if /i "!attr:~3,1!"=="h" (attrib -r -s -h "%%~f") else attrib +s +h "%%~f"
)
复制代码

作者: FU8989 时间: 2009-12-22 16:33 标题: 回复 4楼的帖子

师傅谢谢你很好用

作者: zqz0012005 时间: 2009-12-22 19:09 标题: 回复 4楼的帖子

可以节省掉变量
dir %%f >nul 2>nul && attrib +s +h %%f || attrib -s -h %%f

作者: neorobin 时间: 2009-12-22 19:40 标题: 回复 6楼的帖子

思路不错!
但实测不成功
加隐藏可以, 解除隐藏不成功

@echo off & setlocal enabledelayedexpansion
for /d %%f in (e:\minefilm E:\minephoto g:\minefilm e:\数码图片) do (
  dir %%f >nul 2>nul && attrib +s +h %%f || attrib -s -h %%f
)
复制代码

作者: zqz0012005 时间: 2009-12-22 21:46 标题: 回复 7楼的帖子

唔，没注意到是目录。

另外，for是不需加/d的。幸而没有通配符，不然就与楼主本意完全不符。
没有通配符时 for /d 与单独 for 相同。

[ 本帖最后由 zqz0012005 于 2009-12-24 16:22 编辑 ]

作者: zqz0012005 时间: 2009-12-22 21:55 标题: 回复 8楼的帖子

那就更方便

@echo off
for %%f in (e:\minefilm E:\minephoto g:\minefilm e:\数码图片) do If "%%~af" gtr "d--g" (attrib -s -h %%f) else attrib +s +h %%f
pause
复制代码

作者: neorobin 时间: 2009-12-22 22:08 标题: 回复 9楼的帖子

还是有不适应的地方
如果目录没有存档属性, 可正常工作, 如果有存档属性, 将不能解除隐藏属性
因为文档属性对应的
d-ahs---- leq d--g
是这样吗?

测试了下,
if "d-ahs----" leq "d--g" (echo lll) else echo ggg
显示的是
lll

[ 本帖最后由 neorobin 于 2009-12-22 22:12 编辑 ]

作者: FU8989 时间: 2009-12-23 01:00

谢谢..............................

欢迎光临批处理之家 (http://bbs.bathome.net/)