比如11271900转换成16进制是：ABFEDC
先拿16除11271900，商704493，余12
再拿16除704493，商44030，余13
再拿16除44030，商2751，余14
再拿16除2751，商171，余15
再拿16除171，商10，余11
再拿16除10，商0，余10
最后，倒着取这些：
10
11
15
14
13
12
然后按照这个表换算：
10=A
11=B
12=C
13=D
14=E
15=F
连起来就是：ABFEDC
复制代码

@echo off
set f=0123456789ABCDEF
set /p num=输入十进制数字:
:a
set /a mod = %num% %% 16
set /a num /=16
set en=%mod% %en%
if not %num% lss 1 (goto a)
for %%i in (%en%) do (call set/p=%%f:~%%i,1%%<nul)
pause>nul
复制代码

@echo off&set str=9
set max=10997
set var=%max%
for %%a in (A B C D E F) do (
  set /a str+=1
  call set _%%str%%=%%a
)
:lis
set /a a=var%%16,var=var/16
if defined _%a% call set a=%%_%a%%%
set num=%a%%num%
if %var% gtr 0 goto lis
echo\&echo 十进制数 %max% 转换为十六进制数为：%num%
echo\&pause
复制代码

@echo off
(set /a str=9,n=1,num=0)
set var=2AF5
echo %var%
for %%a in (0 1 2 3 4 5 6 7 8 9 A B C D E F) DO (
   call set var=%%var:%%a=%%a %%
)
for %%a in (%var%) do call set max=%%a %%max%%
for %%a in (A B C D E F) do (
  set /a str+=1
  call set %%a=%%str%%
)
for %%a in (%max%) do (
  set /a num=%%a*n+num
  set /a n*=16
)
echo %num%
pause>nul
复制代码

@echo off
::code by foxjl bbs.bathome.net
title 十进制转任意进制
mode con cols=40 lines=20
set f=0123456789ABCDEF
for %%i in (2.十进制转二进制,8.十进制转八进制,12.十进制转十二进制,16.十进制转十六进制) do (
        echo.&echo.&echo.&set /p=           %%i<nul)
        echo.&echo.&        set /p n=           选择:
cls
title 十进制转%n%进制
set /p num=输入十进制数字:
:a
set /a mod=num%%n,num /=n
set en=%mod% %en%
if not %num% lss 1 (goto a)
for %%i in (%en%) do (call set/p=%%f:~%%i,1%%<nul)
pause>nul
复制代码