批处理之家 - Powered by Discuz! Board

标题: [文本处理] [已解决]批处理如何使用findstr作为if条件？ [打印本页]

作者: meiszp 时间: 2024-5-29 16:58 标题: [已解决]批处理如何使用findstr作为if条件？

本帖最后由 meiszp 于 2024-7-10 08:31 编辑

需要在多个文件中查找error，如果找到了，列出文件名，输出“包含”，如果找不到，输出“不包含”

::/m 输出文件名
findstr /m "error" 123.txt 456.txt 789.txt

if 【findstr 找到了】 (
echo "包含"
）else (
echo "不包含"
)

作者: ShowCode 时间: 2024-5-29 17:24

回复 1# meiszp

1.bat

@echo off
for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
    findstr "error" "%%i" >nul 2>&1
    if errorlevel 1 (
        echo "%%i" 不包含
    ) else (
        echo "%%i" 包含
    )
)
pause
复制代码

作者: ShowCode 时间: 2024-5-29 17:27

回复 1# meiszp

2.bat

@echo off
for %%i in (*.txt) do (
    findstr "error" "%%i" >nul 2>&1
    if errorlevel 1 (
        echo "%%i" 不包含
    ) else (
        echo "%%i" 包含
    )
)
pause
复制代码

作者: ShowCode 时间: 2024-5-29 17:31

回复 1# meiszp

3.bat

@echo off
findstr /m "error" *.txt
if errorlevel 1 (
    echo 不包含
) else (
    echo 包含
)
pause
复制代码

作者: aloha20200628 时间: 2024-7-10 11:37

本帖最后由 aloha20200628 于 2024-8-3 10:21 编辑

在批处理脚本中用系统变量 errorlevel 判断时，须注意‘预处理’对复合语块（典型如for或if）内的系统变量会预先赋值的影响，errorlevel 也是系统变量，亦在‘法网’之中，如下式中的 errorlevel 会被预先赋值=0，即运行时会无视以前 findstr 的真实执行结果

for %%F in (*.txt) do (
	findstr /i "abc" "%%F">nul
	if errorlevel 0 (echo,有》%%F) else (echo,无》%%F)
)
复制代码

所以，还是老办法，采用延迟变量解决预处理问题，如下式

setlocal enabledelayedexpansion
for %%F in (*.txt) do (
	findstr /i "abc" "%%F">nul
	if !errorlevel! equ 0 (echo,有》%%F) else (echo,无》%%F)
)
复制代码

就是不用延迟变量，也有其道，如下式

for %%F in (*.txt) do (findstr /i "abc" "%%F">nul&&echo,有》%%F||echo,无》%%F)
复制代码

以上关于 ‘errorlevel 也是系统变量’ 的更严谨说法及其更多用法可详见另帖》http://www.bathome.net/thread-69472-1-1.html 18楼

作者: 77七 时间: 2024-7-10 13:36

有关if errorlevel 用法，我记得站长讲过一次，大概意思是这样的

@echo off
for /l %%l in (0,1,5) do (
	call :1 %%l
	if errorlevel 3 (
		echo [errorlevel=%%l  ^>=3]
	) else (
		echo [errorlevel=%%l  ^<3]
	)
)
pause
exit

:1
exit /b %1
复制代码

作者: aloha20200628 时间: 2024-7-10 14:22

本帖最后由 aloha20200628 于 2024-7-10 14:26 编辑

回复 6# 77七

阁下跑题了

作者: buyiyang 时间: 2024-7-10 20:04

回复 5# aloha20200628

if errorlevel 0的意思是判断变量errorlevel的值是否大于或等于0，
“预处理”只扩展%var%形式引用的变量，errorlevel的取值和比较是执行时进行的，类似set /a error=errorlevel

欢迎光临批处理之家 (http://bbs.bathome.net/)