@echo off & setlocal enabledelayedexpansion
cd /d "%~dp0"
set "count=1"
for /f "tokens=%n%,6-7 delims={}:^/"  %%a in ('type "R23日志.txt" ^| find /i "Values"') do (
set /a "count+=1"
echo 第!count!轮CPU参考分数:%%a___实际跑分:%%b___跑分差值:%%c
)
:end
echo.
echo CPU稳定性测试完成！
echo.
pause
复制代码

@echo off
cd /d "%~dp0"
setlocal enabledelayedexpansion
set "count=1"
for /f "tokens=2-3 delims={}" %%i in ('type "R23日志.txt" ^| find /i "Values"') do (
    set /a "count+=1"
    for %%a in (%%i) do (
        set "ScoreRefer=%%a"
    )
    for /f "tokens=4-5 delims=/ " %%a in ("%%j") do (
        set "ScoreActual=%%a"
        set "ScoreMinus=%%b"
    )
    echo 第!count!轮CPU参考分数:!ScoreRefer!___实际跑分:!ScoreActual!___跑分差值:!ScoreMinus!
)
pause
复制代码

@echo off &setlocal enabledelayedexpansion
for /f "delims=" %%a in (' findstr /ic:"Values:" "R23日志.txt" ') do (
	set/a "n+=1" & set a="%%a/"
	for /f "tokens=2 delims={}" %%m in ("%%~a") do for %%v in (%%m) do set "v1=%%v"
	for /f "tokens=1-2 delims=/" %%b in ("!a:*Deviation: =!") do (
		echo,第!n!轮CPU参考分数:!v1!___实际跑分:%%b___跑分差值:%%c
	)
)
endlocal&pause&exit/b
复制代码

@echo off
setlocal enabledelayedexpansion
for /f "tokens=2,4 delims=:{}-> " %%i in ('type "R23日志.txt"^|findstr /bi Values:') do (
    set /a n+=1
    for %%a in (%%i) do set value1=%%a
    for /f "tokens=1,2 delims=/" %%b in ("%%j") do (echo,第!n!轮CPU参考分数:!value1!___实际跑分:%%b___跑分差值:%%c)
)
pause
复制代码

3楼代码第4行是对{n1,n2,...,ne}花括号中的数列遍历（无论其长度增减）并最终提取最后一个目标值ne；
代码第5行是用关键词 ‘Deviation: ’ 直接锚定其后的 k1/k2 字段，再用分隔符/取出目标值k1和k2。
仅用分隔符界定的字段(token)序号若每次可变，就不能用来唯一性锚定每个目标值，除非其具有自己的专属分隔符，而非与那些非目标值字段共用 ,: / 等分隔符
楼主所谓的改变操作路线，其逻辑步骤能否明确一下...

@echo off
for /f "tokens=%n%" %%a in ("q w e r") do (
	set /a n+=1
	echo %%a
)
pause
复制代码

@echo off
set "count=0"
cd /d "%~dp0"
setlocal enabledelayedexpansion
for /f "tokens=2,6-7 delims={}:/ " %%a in ('type "R23日志.txt" ^| find /i "Values"') do (
    set /a count+=1
    call :GetRefer "%%a" !count!
    echo 第!count!轮CPU参考分数:!ScoreRefer!___实际跑分:%%b___跑分差值:%%c
)
pause
exit /b

:GetRefer
REM tokens数值递增变动的部分单独拿出来作为子函数被call命令调用
for /f "tokens=%2 delims=," %%h in ("%~1") do (
    set "ScoreRefer=%%h"
)
goto :eof
复制代码

用{n1,n2,...,ne}遍历方法获取最后目标值ne的令牌序号Qne，再根据与其后k1,k2两个目标值的相对不变位序获取其令牌序号 Qk1,Qk2，批处不支持分割表达式中直接使用延迟变量!v!，就只能丢给子过程 call !Qne! !Qk1! !Qk2! 重新提取三个目标值，也是另一种解法，但步骤会增加，舍简求繁了...

用9楼的算法给一个新版本，看楼主是否可口...

@echo off &setlocal enabledelayedexpansion &set/a "n=0,i=0"
for /f "delims=" %%a in (' findstr /ic:"Values:" "R23日志.txt" ') do (
	for /f "tokens=2 delims={}" %%m in ("%%~a") do for %%v in (%%m) do set/a "i+=1"
	set/a "q1=2+i,q2=q1+3,q3=q2+1"
	set/a "n+=1" & (call :get3v "%%~a" !n! !q1! !q2! !q3!) &set "i="
)
endlocal&pause&exit/b
:get3v
	for /f "tokens=%~3,%~4,%~5 delims=:{,}/" %%a in ("%~1") do (
		echo,第%~2轮CPU参考分数:%%a___实际跑分:%%b___跑分差值:%%c
	)
	exit/b
复制代码

@echo off
cd /d "%~dp0"

set "count=1"

set "@value1=3"
set "@value2=6"
set "@value3=7"

for /f "delims="  %%z in ('type "R23日志.txt" ^| find /i "Values"') do (
set "@line=%%z"
set /a "count+=1"
call :aaa
set /a @value1+=1&set /a @value2+=1&set /a @value3+=1
)
echo.
echo CPU稳定性测试完成！
echo.
pause&exit/b

:aaa
setlocal enabledelayedexpansion
for /f "tokens=%@value1%,%@value2%-%@value3% delims={}:^/,"  %%a in ("!@line!") do (
endlocal
echo 第%count%轮CPU参考分数: %%a___实际跑分:%%b___跑分差值: %%c
)
复制代码