@echo off
setlocal enabledelayedexpansion
set "k=                    "
(for /f "tokens=1-4  delims=  " %%a in (a.txt) do (
    set "n1=%%a" && set "n2=%%b" && set "n3=%%c" && set "n4=%%d"
    set a=!n1!%k% && set b=!n2!%k%  && set  c=!n3!%k%  && set  d=!n4!%k% 
    echo.  !a:~0,15! !b:~0,15! !c:~0,15! !d:~0,15! 
)) > b.txt
endlocal
复制代码

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1-2*" %%i in (a.txt) do (
    set f1=%%i                    
    set f2=%%j                    
    echo,!f1:~,20!!f2:~,20!%%k
)
pause
复制代码

@echo off &setlocal enabledelayedexpansion &set "maxZ=0"
for /f "delims=" %%a in (1.txt) do for %%s in (%%a) do (
	set/p="%%s"<nul>0.0
	for %%b in (0.0) do if %%~zb gtr !maxZ! set "maxZ=%%~zb"
)
echo,!maxZ!
del/q "0.0"&endlocal&pause&exit/b
复制代码

@echo off
setlocal enabledelayedexpansion
type a.txt>temp
echo,a>>temp
set /a n=0,y=0
for /f "delims=:" %%i in ('findstr /o .* temp') do (
    set /a x=%%i-y
    if !n! lss !x! set /a n=x
    set y=%%i
)
del temp
for /l %%i in (1,1,!n!) do set BS= !BS!
for /f "tokens=1-2*" %%i in (a.txt) do (
    set f1=%%i!BS!
    set f2=%%j!BS!
    echo,!f1:~,%n%!!f2:~,%n%!%%k
)
pause
复制代码

@echo off &setlocal enabledelayedexpansion &set "maxZ=0"
for /f "delims=" %%a in (1.txt) do for %%s in (%%a) do (
	set "s=%%s" & (call :_strLen s z)
	if !z! gtr !maxZ! set "maxZ=!z!"
)
set "ms=" &for /l %%n in (1,1,!maxZ!) do set "ms=!ms! "
endlocal &set "maxZ=%maxZ%"&set "ms=%ms%"
setlocal enabledelayedexpansion
for /f "delims=" %%a in (1.txt) do (
	set "s="
	for %%s in (%%a) do (set "_s=%%s"&set "_s=!_s!%ms%"&set "s=!s!	!_s:~0,%maxZ%!")
	echo,!s:~1!
)
endlocal&pause&exit/b
:_strLen
   set "_str=_!%~1!" &set "_Len=0"
   for %%n in (64 32 16 8 4 2 1) do (
      if "!_str:~%%n,1!" neq "" (set/a "_Len+=%%n"&set "_str=!_str:~%%n!")
   )
   set "%~2=!_Len!" &exit/b
复制代码

awk  -v OFS="\t"  '{print $1,$2,$3}' a.txt
复制代码

@echo off
for /f "tokens=1-3" %%i in (a.txt) do (
    echo,%%i>>temp1
    echo,%%j>>temp2
)
set /a n1=n2=0,y1=y2=0
setlocal enabledelayedexpansion
for %%a in (1 2) do (
    echo,a>>temp%%a
    for /f "delims=:" %%i in ('findstr /o .* temp%%a') do (
        set /a x%%a=%%i-y%%a
        if !n%%a! lss !x%%a! set /a n%%a=x%%a
        set y%%a=%%i
    )
    del temp%%a
    set /a n%%a+=4
for /l %%i in (1,1,!n%%a!) do set BS%%a= !BS%%a!
)
(for /f "tokens=1-2*" %%i in (a.txt) do (
    if "%%j"=="" (set f1=%%i) else (set f1=%%i!BS1!&set f1=!f1:~,%n1%!)
    if "%%k"=="" (set f2=%%j) else (set f2=%%j!BS2!&set f2=!f2:~,%n2%!)
    set f3=%%k
    echo,!f1!!f2!!f3!
))>b.txt
pause
复制代码

参考12楼的经验，谢谢 重写了9楼代码，用以下1.txt示例文件测试效果明显 楼主可试试...
1.txt》
aa  自x车 1232   米
mm命名  abc 5555  米
bbbbb  密码可靠 66  米
同轴3xx   国产321   456 米

awk '{ printf "%-10s %-10s %-10s\n", $1, $2, $3 }' a.txt
复制代码

@echo off
set colsn=4
set /a colsn-=1
for /f "tokens=1-%colsn%" %%1 in (a.txt) do (
    echo,%%1>>temp1
    echo,%%2>>temp2
    echo,%%3>>temp3
)
setlocal enabledelayedexpansion
for /l %%a in (1,1,%colsn%) do (
    echo,a>>temp%%a
    set /a x=n%%a=0
    for /f "tokens=1,2 delims=:" %%i in ('findstr /n /o .* temp%%a') do (
        set /a "x%%a=%%j-x"
        set /a "m=%%i-1"
        set "n%%a#!m!=!x%%a!"
        if !n%%a! lss !x%%a! set /a "n%%a=x%%a"
        set "x=%%j"
    )
    del temp%%a
)
for /f "tokens=1-%colsn%*" %%1 in (a.txt) do (
    set /a "n+=1"
    set f=
    set "f1=%%1"
    set "f2=%%2"
    set "f3=%%3"
    for /l %%x in (1,1,%colsn%) do (
        set /a "m%%x=n%%x-n%%x#!n!"
        for /l %%y in (1,1,!m%%x!) do set "f%%x=!f%%x! "
        set "f=!f!!f%%x!    "
    )
    echo,!f!%%4
)
pause
复制代码

@echo off 
setlocal enabledelayedexpansion 
rem 计算字符的字节，cmd下输出是对齐状态，导出txt会变形，需改换等宽字体，cmd默认是Consolas。
REM 获取文本最大字符串的字节
for /f "delims=" %%a in (1.txt) do for %%s in (%%a) do (
	set/p="%%s"<nul>$
	for %%b in ($) do if %%~zb gtr !maxZ! set "maxZ=%%~zb"
)
for /f "tokens=1-4*  delims= " %%a in (1.txt) do (
    rem 获取每列字符串的字节
    set "a=%%a"&set "b=%%b"&set "c=%%c"&set "d=%%d"&set "e=%%e"
    set/p="%%a"<nul>$&for %%i in ($) do (set az=%%~zi) 
    set/p="%%b"<nul>$&for %%i in ($) do (set bz=%%~zi) 
    set/p="%%c"<nul>$&for %%i in ($) do (set cz=%%~zi) 
    set/p="%%d"<nul>$&for %%i in ($) do (set dz=%%~zi) 
    set/p="%%e"<nul>$&for %%i in ($) do (set ez=%%~zi) 
    rem 获取每列字符串的字节差，并用空格补齐
    set/a Na=!maxZ!-!az!&set/a Nb=!maxZ!-!bz!&set/a Nc=!maxZ!-!cz!&set/a Nd=!maxZ!-!dz!&set/a Ne=!maxZ!-!ez!
    for /l %%i in (1,1,!Na!) do set "a=!a! "
    for /l %%i in (1,1,!Nb!) do set "b=!b! "
    for /l %%i in (1,1,!Nc!) do set "c=!c! "
    for /l %%i in (1,1,!Nd!) do set  "d=!d! "
    rem for /l %%i in (1,1,!Ne!) do set  "e=!e! "
    echo !a! !b! !c! !d! !e!
)
del/q $&pause&exit
复制代码

BEGIN {
	FS = " "
	while ( getline < ARGV[1] ) {
		for (i = 1; i <= NF; i++) {
			if ( length($i) > maxlen[i] ) {
				maxlen[i] = length($i)
			}
		}
	}
}

{
	for (i = 1; i <= NF; i++) {
		printf "%-*s\t",maxlen[i],$i
	}
	printf "\r\n"
}
复制代码

$file = Get-Content -Path "data.txt" -Encoding UTF8
$maxlen = @(0) *10

$file | ForEach-Object {
	$arr = $_  -split "\s+"
	for ( $i =0 ; $i -lt $arr.count ; $i++ ){
		if ( $maxlen[$i] -lt ($arr[$i]).length ) {
			$maxlen[$i] = ($arr[$i]).length
		} 
	}
}
$maxlen = $maxlen -join " " -replace "( 0)*" -split "\s+"

$file | ForEach-Object {
	$arr = $_  -split "\s+"
	$str = ""
	for ( $i =0 ; $i -lt $arr.count ; $i++ ){
		$str += ($arr[$i]).PadRight($maxlen[$i]," ") + "  "
	}
	write-host ( $str -replace "\s$","" )
}
复制代码

aa          1232    米
bbbbb     66       米
b 66  米 
cccccccccccccccccccccccccccccccccccc    c   cccccccccccccccccccccccccccccc  cc   c          米 c
c cc    ccc     v          米
补补补补补补补补补补补补补补补补补  cccccccccccccccccccccccccccccc          补补补补补补补补补补补补补补补补补       c       c                 c
补  c                      cccccccccccccccccccccccccccccc    c             c                c
复制代码

@echo off
chcp 437 >nul
set "Separator=@"
set "inputfile=a.txt"
setlocal enabledelayedexpansion
:loop
set /a column+=1
set /a #C%column%max=mark=0
for /f "tokens=%column%" %%i in (%inputfile%) do (
    call :strlen "%%i"
    if !len! geq !#C%column%max! set /a #C%column%max=len
    set mark=1
    )
if %mark% equ 1 goto :loop
set /a column-=1
chcp 936 >nul
set /a lines=0
(for /l %%i in (1,1,%column%) do call :output %%i)>$.temp
set "Separator="&set arg=" delims=%Separator%" "rem"
set "inputfile=$.temp"&(for /l %%i in (1,1,%lines%) do call :output %%i %arg%)>output_%inputfile%
del /q $ $.temp
pause&exit

:strlen
set "str=_%~1"
set "len=0"
for %%n in (64 32 16 8 4 2 1) do (
    if "!str:~%%n,1!" neq "" (
        set/a "len+=%%n"
        set "str=!str:~%%n!"
        )
)
exit /b
:output
if %1 equ 1 goto :output_2
for /f "tokens=1,%1%~2" %%a in (%inputfile%) do (
    if "%%b"=="" (set "field=-") else set "field=%%b"
    %~3 set/p="!field!"<nul>$&for %%i in ($) do (set len=%%~zi)
    %~3 set /a spaceNum=!#C%1max!-len+2,n+=1
    set "outstr=!outstr!%Separator%!field!"
    %~3 for /l %%i in (1,1,!spaceNum!) do set "outstr=!outstr! "
    )
%~3 if %n% geq %lines% set /a lines=n
%~3 set /a n=0
echo,!outstr!
set "outstr="
exit /b
:output_2
for /f "tokens=%1%~2" %%a in (%inputfile%) do (
    if "%%a"=="" (set "field=-") else set "field=%%a"
    %~3 set/p="!field!"<nul>$&for %%i in ($) do (set len=%%~zi)
    %~3 set /a spaceNum=!#C%1max!-len+2,n+=1
    set "outstr=!outstr!%Separator%!field!"
    %~3 for /l %%i in (1,1,!spaceNum!) do set "outstr=!outstr! "
    )
%~3 if %n% geq %lines% set /a lines=n
%~3 set /a n=0
echo,!outstr!
set "outstr="
复制代码

@echo off &setlocal enabledelayedexpansion &set "maxZ=0"
for /f "delims=" %%a in (1.txt) do for %%s in (%%a) do (
	set "s=%%s"&set "_len="&(call :_strLen)
	if !_len! gtr !maxZ! set "maxZ=!_len!"
)
for /f "delims=" %%a in (1.txt) do (
	set "ss=" &for %%s in (%%a) do (
		set "s=%%s"&set "_len="&(call :_strLen)
		set/a "z=maxZ-_len"&set "_s="&for /l %%k in (1,1,!z!) do set "_s=!_s! "
		set "ss=!ss! %%s!_s!"
	)
	echo,!ss:~1!
)
endlocal&pause&exit/b
:_strLen //逐个字符计算》中文字符累加2，英文字符累加1。
   if not defined s exit/b
   if "!s:~0,1!" gtr "Z" (set/a "_len+=2") else (set/a "_len+=1")
   set "s=!s:~1!" &goto :_strLen
复制代码

@echo off &setlocal enabledelayedexpansion &set "maxZ=0"
for /f "delims=" %%a in (1.txt) do for %%s in (%%a) do (
	set/p="%%s"<nul>"0.0"
	for %%b in (0.0) do if %%~zb gtr !maxZ! set "maxZ=%%~zb"
)
for /f "delims=" %%a in (1.txt) do (
	set "ss=" &for %%s in (%%a) do (
		set/p="%%s"<nul>"0.0" &for %%b in (0.0) do set/a "z=maxZ-%%~zb"
		set "_s="&for /l %%k in (1,1,!z!) do set "_s=!_s! "
		set "ss=!ss! %%s!_s!"
	)
	echo,!ss:~1!
)
del/q "0.0"&endlocal&pause&exit/b
复制代码

function getWidth(str,LenStr,LenASC,LenHZ) {
	LenStr = length(str)
	LenASC = gsub( /[\x00-\x7F]/ , "" , str )
	LenHZ = length(str) / length("一")
	return  LenASC + LenHZ * 2
}

function getLengthHZ(str,LenHZ) {
	gsub( /[\x00-\x7F]/ , "" , str )
	LenHZ = length(str) / length("一")
	return  LenHZ
}

BEGIN {
	FS = " "
	while ( getline < ARGV[1] ) {
		for (i = 1; i <= NF; i++) {
			len = getWidth($i)
			if ( len > maxWidth[i] ) {
				maxWidth[i] = len
			}
		}
	}
#	print "--maxWidth--"
#	for ( i in maxWidth ) {
#		printf "%4s" , maxWidth[i]
#	}
#	printf "\r\n"
#	print "----"
}

{
	for (i = 1; i <= NF; i++) {
		LenHZ = getLengthHZ($i)
		printf "%-*s:" , maxWidth[i] + LenHZ , $i
	}
	printf "\r\n"
}
复制代码

param(
	[String]$filenameIn ,
	[String]$filenameOut
)

$file = Get-Content -Path $filenameIn -Encoding UTF8
$maxWidth = @{}

$file | ForEach-Object {
	$arr = $_  -split "\s+"
	for ( $i = 0 ; $i -lt $arr.count ; $i++ ){
		$Width = ($arr[$i]).length + ( $arr[$i] -replace "[\x00-\x7F]","" ).length
		if ( $maxWidth[$i] -lt $Width ) {
			$maxWidth[$i] = $Width
		} 
	}
}

$strTable = [System.Collections.ArrayList]@()

$file | ForEach-Object {
	$arr = $_  -split "\s+"
	$str = ""
	for ( $i = 0 ; $i -lt $arr.count ; $i++ ){
		$LenHZ = ( $arr[$i] -replace "[\x00-\x7F]","" ).length
		$str += ($arr[$i]).PadRight( $maxWidth[$i] - $LenHZ , " " ) + ":"
	}
	[void]$strTable.add( $str ) #$str -replace "\s$",""
}
$strTable | Out-File -Encoding 'UTF8' -FilePath $filenameOut
复制代码

跑完35层楼，总算能踏踏实实给楼主一个用批处拿下本帖（最长混合字段可自定义，列数可自定义）的解决方案了...

- LenHZ

---

作者: buyiyang    时间: 2024-7-21 17:09

回复 35# aloha20200628


    使用这段代码如果字段中有=,等批处理分隔符的话会被错误分割；而且以“全文最大字段长度”为标准，当原文件字段长度差距悬殊时会使结果中字符较少的列视觉间隔过大而不协调。

---

作者: 娜美    时间: 2024-7-21 17:30

本帖最后由 娜美 于 2024-7-21 17:40 编辑

我带着好奇心, 跟着这个贴题测过上面你们所说的解决方案,  都没有通过以下文本测试,   有的虽然解决了在cmd屏幕里对齐,  但输出到文本又是另一个不对齐现象发生了
测试要对齐文本 a.txt

aa          1232    米
bbbbb     66       米
b 66  米 
cccccccccccccccccccccccccccccccccccc    c   cccccccccccccccccccccccccccccc  cc   c          米 c
c cc    ccc     v          米

补补补补补补补补补补补补补补补补补  cccccccccccccccccccccccccccccc          补补补补补补补补补补补补补补补补补       c       c                 c
补  c                      cccccccccccccccccccccccccccccc    c             c                c
复制代码

Out.txt  请复制到txt文本中观看才能看到对齐大概样式
对齐后, 输出到文本中它们大概至少应该是这样的吧,  但是都相差甚远呢,  到目前为止还没有解决输出到文本对齐问题

aa                                                          1232                                                   米
bbbbb                                                    66                                                      米
b                                                            66                                                      米 
cccccccccccccccccccccccccccccccccccc    c                                                        cccccccccccccccccccccccccccccc             cc            c                米 c
c                                                            cc                                                       ccc                                                        v             米
补补补补补补补补补补补补补补补补补       cccccccccccccccccccccccccccccc          补补补补补补补补补补补补补补补补补       c             c                 c
补                                                          c                                                         cccccccccccccccccccccccccccccc             c             c                 c
复制代码

---

作者: buyiyang    时间: 2024-7-21 17:34

有的虽然解决了在cmd屏幕里对齐,  但输出到文本但输出到文本又是另一个不对齐现象发生了
娜美 发表于 2024-7-21 17:30

先看看我20楼和30楼说的字体问题……

---

作者: newswan    时间: 2024-7-21 19:34

回复 40# buyiyang


对，由于 awk 使用环境不同，有的地方是 + 有的地方是 -

---

作者: newswan    时间: 2024-7-21 20:00

本帖最后由 newswan 于 2024-7-21 20:05 编辑

回复 42# 娜美

#36 #37 输出正确
输出到屏幕正确，保存到文件也应该正确，文件不能对齐，是因为编辑器的字体问题

---

作者: ppll2030    时间: 2024-7-21 21:01

回复 38# aloha20200628


    还是老大厉害啊。完美解决列数问题，还有全角空格等字符的问题。代码依旧如此简单明了。

---

作者: ppll2030    时间: 2024-7-21 23:37

回复 38# aloha20200628


    老大，发现一个bug：
如果某组字符中带有*号，这组字符就会被整体抹掉。
而带有英文"!"感叹号的，只会是感叹号抹掉，不会影响这组字符的其他字符。
貌似你的代码第7行中分别提取每行中每组字符的时候，带*号的这组就会被抹掉。
我自己用tokens来提取不会有这个问题，但是我的代码太繁琐，也有列数限制。
所以还是倾向于你的代码，请问可有解决办法？

---

作者: qixiaobin0715    时间: 2024-7-22 09:50

回复 47# ppll2030
感叹号的问题是变量延迟造成的，你可以试试如果感叹号成对出现，感叹号以及一对感叹号之间的字符都会“隐藏”。*的问题没有遇见过，还是留给大佬们来解释吧。

---

作者: qixiaobin0715    时间: 2024-7-22 09:53

回复 41# buyiyang
是的，相似的字符还有分号、跳格。

---

作者: aloha20200628    时间: 2024-7-22 16:23

本帖最后由 aloha20200628 于 2024-7-23 11:19 编辑


若批处字符串里包含转义字符，有如一旦撞上 “台风” 就是 “天灾”，只能尽量减免吧...
更新35楼代码如下，用递归子过程替换 for %%s in (%%a) do ... 以便纠正 ,;= 等其余系统默认分隔符以及*?通配符的影响...

@echo off &setlocal &set "maxZ=0"
for /f "delims=" %%a in (1.txt) do for /f "delims=	　 " %%b in ("%%a") do (
	set "a=%%a"&call :getMaxZ
	call set/p=%%maxZ%%<nul>0.0
	set/p maxZ=<0.0
)
for /f "delims=" %%a in (1.txt) do for /f "delims=	　 " %%b in ("%%a") do (set "a=%%a"&set "ss="&call :printAll)
del/q "0.0" 2>nul&endlocal &pause &exit/b
:getMaxZ
	for /f "tokens=1* delims=	　 " %%1 in ("%a%") do (set "a=%%2"&set/p="%%1"<nul>"0.0")
	if "%a%"=="" (exit/b) else for %%v in (0.0) do (set "v=%%~zv")
	(if %v% gtr %maxZ% set "maxZ=%v%") & goto :getMaxZ
:printAll
	for /f "tokens=1* delims=	　 " %%1 in ("%a%") do (set "s=%%1"&set "a=%%2"&set/p="%%1"<nul>"0.0")
	for %%v in (0.0) do (set/a "z=maxZ-%%~zv")
	setlocal enabledelayedexpansion &set "_s=" &for /l %%k in (1,1,!z!) do (set "_s=!_s! ")
	set "ss=!ss! !s!!_s!" &if "%a%"=="" (set/p="!ss:~1!"<nul&echo,&endlocal&exit/b)
	endlocal &set "ss=%ss%" &goto :printAll
复制代码

---

作者: 77七    时间: 2024-7-22 16:47

回复 47# ppll2030


  

for %%a in (1 2 *xx ?xx 5) do echo %%a
复制代码

含有通配符，*?，又没有通配到文件，自然就消失了。

---

作者: qixiaobin0715    时间: 2024-7-22 17:00

本帖最后由 qixiaobin0715 于 2024-7-22 17:02 编辑

自己又偷偷的写了一个代码，对for默认分隔符和通配符 *？以及延迟变量中的 ! 免疫，效率不行，没好意思发出来。

---

作者: ppll2030    时间: 2024-7-22 19:49

回复 51# 77七
回复 48# qixiaobin0715

感谢两位大佬的指点。原因是已经找到了。只是想知道有没有什么好的经验或是取巧的办法可以避免这些通配符。
毕竟还想保持这么精简而干练的代码

---

作者: ppll2030    时间: 2024-7-22 20:54

回复 50# aloha20200628


    厉害了。换一个思路就搞定了特殊符号问题。这思维真是服了。

不过又有一个新问题: 对于包含有空格或制表符的空行（整行都不显示字符的，看着就像一空行），脚本会卡住，无法进行下去。

不过这不是很大的问题。我目前是加一段去除所有空行的命令，再继续执行就完美了。

再次感谢老大，通过这几段，学习到了很多。

---

作者: 77七    时间: 2024-7-22 22:54

回复 53# ppll2030


   50楼大佬已经给出答案了。如果没有其它特殊字符，只有通配符，也可以试试以下思路(老帖子看到的)，将行变成竖排

@echo off
set "str=1  2 3 *  ?    "
set "str=%str: =&echo;%"
for /f %%a in ('echo %%str%%') do (
	echo [%%a]
)
pause
复制代码

---

作者: qixiaobin0715    时间: 2024-7-23 10:28

本帖最后由 qixiaobin0715 于 2024-7-24 09:40 编辑

回复 53# ppll2030
字符串分行显示时，不使用for %%a in (...) do...这样的循环结构，可以避免出现默认分隔符以及*?通配符的影响；
至于变量延迟中!会”隐藏“的问题有多种解决方法，其中一种方法可以参考http://www.bathome.net/thread-11193-1-1.html

---

作者: ppll2030    时间: 2024-7-23 10:42

回复 55# 77七


    哈哈。果然有取巧的办法。感谢指导

不过这个用在这里会引发另一个bug

当每行开头是几个空格开始的情况，取值第一个会是ECHO

---

作者: aloha20200628    时间: 2024-7-23 10:51

本帖最后由 aloha20200628 于 2024-7-23 11:18 编辑

回复 54# ppll2030

更新了50楼代码，滤掉了全空白字符行（仅包含中英文空格+制表符），以免运行中被阻塞...

---

作者: ppll2030    时间: 2024-7-23 11:25

回复 56# qixiaobin0715


    你的代码有些还看不明，需要研究一下
不过31楼的大佬，貌似也是按列来取值，然后根据每列最大字符串得到每列最大宽度。从而使得结果排版更加的完美。
而它第一段可以自动识别最大的列数。不需要手动填写，或许可以借鉴到你的代码里。
他的代码后半段很复杂。我一时半会不能理解透。
等研究透aloha的版本，再去研究31楼的。毕竟aloha的版本感觉思路跟我的有相似之处，好理解一些。

---

作者: ppll2030    时间: 2024-7-23 13:03

回复 58# aloha20200628


    老大。你的delims那边的有点问题，害我找了好久。
就是那个中英文空格你给打了三个。直接卡当了。修改为一个制表符和一个空格就OK了
像我这边，还加入全角符的空格，也完美支持了。标点符号也完美显示。
大赞哦~！

---

作者: aloha20200628    时间: 2024-7-23 14:17

本帖最后由 aloha20200628 于 2024-7-23 14:37 编辑

回复 60# ppll2030

我说的过滤掉中英文空格+制表符构成的 ‘全空白行’，其中的中文空格即全角空格。delims表达式指定的这三个字符复制到代码区中有时会 ‘变形’ 不过知道此意你在自己的代码中调整就是了

---

作者: 77七    时间: 2024-7-23 15:49

本帖最后由 77七 于 2024-7-23 15:52 编辑

回复 57# ppll2030


   
去掉就行，提供两种方法...

@echo off
set "str=    1  2 3 *  ?    "
set "str=x %str%"
set "str=%str: =&echo;%"
for /f "skip=1" %%a in ('echo %%str%%') do (
	echo [%%a]
)
pause
for /f "tokens=*" %%a in ("    1  2 3 *  ?    ") do (
	set str=%%a
	if defined str (
		call set "str=%%str: =&echo;%%"
		for /f %%a in ('call echo %%str%%') do (
			echo [%%a]
		)
	)
)
pause
复制代码

---

作者: qixiaobin0715    时间: 2024-7-23 15:53

本帖最后由 qixiaobin0715 于 2024-7-23 15:54 编辑

回复 59# ppll2030
1.排版美不美观个人看法不一，只要达到各列上下对齐的效果，调整列的宽度就是小kiss，增加或减少几个空格而已；
2.如果列数都懒得搞清楚，就太那个了吧。实际上要解决这个问题也不复杂，就是在原有代码外层加上goto循环，再if几下即可。个人感觉goto语句太过难看，很少使用此循环。

---

作者: buyiyang    时间: 2024-7-23 22:19

算字节长度其实也可以将文本转换为16进制字串进行计算和处理，而且不用担心任何特殊字符。

@echo off&setlocal enabledelayedexpansion
set "input=a.txt"&set /a m=line=1&set "act=set/p=,&set/a m=1"
for %%i in ("%input%") do fsutil file creATenew "%input%.zero" %%~zi >nul
(for /f "tokens=2" %%a in ('fc /b "%input%" "%input%.zero"^|findstr /irc:"[0-9A-F]*: [0-9A-F][0-9A-F] 00"') do (
    if /i "%%a"=="0A" (echo,&set/a m=1,line+=1,col=0) else if /i "%%a"=="0D" (echo,
        for %%l in (!line!) do for /l %%i in (1,1,!col!) do (
            if !C%%i_%%l! gtr !C%%imax! set/a C%%imax=C%%i_%%l
            set "C%%i_%%l="
            ) ) else if /i "%%a"=="20" (%act%) else if /i "%%a"=="09" (%act%) else (
                    set/p=%%a
                    set /a col+=m,m=0
                    set /a C!col!_!line!+=1
                   )
        ))<nul >"%input%.temp"
(for /f "delims=" %%a in (%input%.temp) do (
    set /a col=0
    for %%i in (%%a) do (
        set /a col+=1&set "space="
        set /a size=C!col!max,len=size*2+2
        for /l %%i in (1,1,!size!) do set "space=!space!20"
        set "outstr=%%i!space!"
        for %%i in (!len!) do echo,!outstr:~0,%%i!
        )   
    set /p =0d0a
)   )<nul >"out_%input%"
del /q "%input%.zero" "%input%.temp" 
certutil -decodehex -f "out_%input%" "out_%input%" >nul
pause
复制代码

---

作者: qixiaobin0715    时间: 2024-7-25 15:32

嵌套变量延迟开关， 来消除文本中“!”的影响，弃用for %%i in (...) do...的方法，通吃文本中存在默认分隔符以及*?通配符等字符的影响，使用大多数人熟悉的cmd命令书写代码。感觉效率还可以：

@echo off
echo,>$1
:a
set Em=
set /a colsn+=1
if %colsn% equ 1 (
    (for /f "tokens=1" %%i in (a.txt) do (echo,%%i&set Em=1))>temp
) else (
    (for /f "tokens=1,%colsn%" %%i in (a.txt) do (echo,%%j&if not "%%j"=="" set Em=1))>temp
)
if not defined Em goto :b
echo,>>temp
findstr /n /o .* temp>$2
setlocal enabledelayedexpansion
    for /f "tokens=1,2 delims=:" %%i in ($2) do (
        set /a m=%%j-x
        set /a n=%%i-1
        set "a!n!=!m!"
        if !max! lss !m! set "max=!m!"
        set "x=%%j"
    )
set /a n+=1
    (for /f "delims=:" %%i in ('findstr /n .* temp') do (
        set str1=
        set str2=
        set /p str1=
        set /a z=max-a%%i
        for /l %%k in (1,1,!z!) do set str2=!str2! 
        if %%i neq !n! echo,!str1!!str2!
    ))<temp>$2
    (for /f "tokens=1* delims=:" %%i in ('findstr /n .* $2') do (
        endlocal
        set /p Line1=
        set Line2=%%j
        setlocal enabledelayedexpansion
        if "!Line1!"=="" (echo,!Line2!) else echo,!Line1!    !Line2!
    ))<$1>b.txt
type b.txt>$1
endlocal
if defined Em goto :a
:b
del temp $1 $2
pause
复制代码

---

欢迎光临 批处理之家 (http://bbs.bathome.net/)

Powered by Discuz! 7.2