批处理之家 - Powered by Discuz! Board

标题: [文件操作] [分享]批处理将文件名首列相同的文件归入以任一文件名作为文件夹名的文件夹内 [打印本页]

作者: 77七 时间: 2024-7-20 14:42 标题: [分享]批处理将文件名首列相同的文件归入以任一文件名作为文件夹名的文件夹内

本帖最后由 77七于 2024-7-20 14:46 编辑

三亚_2024_06_20-130616.jpg
三亚_2024_06_20-135001.jpg
三亚_2024_06_21-135003.jpg
青岛_2024_07_10-131023.jpg
青岛_2024_07_11-132825.jpg
昆明_2024_07_19-132805.jpg
复制代码

以上6张图片
我想创建文件夹 "三亚_2024_06_20-130616\"(任一即可，即 "三亚_2024_06_20-135001\"、"三亚_2024_06_21-135003\" 也可以)，并把三亚_*.jpg归入此文件夹
以此类推
特例
昆明只有一张，不创建文件夹，不归入。

效果如下：
归入前：

归入后：

作者: 77七 时间: 2024-7-20 14:44

@echo off
cd /d "%~dp0"
for /f "tokens=1* delims=_" %%a in ('dir /b /a-d "*_*.jpg"') do (
	if not defined _"%%a" (
		set _"%%a"=%%a_%%~nb
	) else if exist "%%a_*.jpg" (
		call md "%%_"%%a"%%\"
		call move "%%a_*.jpg" "%%_"%%a"%%\"
	)
)
pause
复制代码

作者: zhengzhenhui 时间: 2024-7-21 01:41

本帖最后由 zhengzhenhui 于 2024-7-21 01:50 编辑

有分隔符的情况下，如果文件夹名只取三亚青岛改如何写
昆明只有一张或者等于一张就不移入

作者: 77七 时间: 2024-7-21 02:09

回复 3# zhengzhenhui

@echo off
cd /d "%~dp0"
for /f "tokens=1* delims=_" %%a in ('dir /b /a-d "*_*.jpg"') do (
	if not defined _"%%a" (
		set _"%%a"=1
	) else if exist "%%a_*.jpg" (
		md "%%a"
		move "%%a_*.jpg" "%%a\"
	)
)
pause
复制代码

作者: zhengzhenhui 时间: 2024-7-21 02:43

@echo off
cd /d "%~dp0"

setlocal enabledelayedexpansion

for /f "delims=" %%i in ('dir /b /a-d "*-*"') do (
    set "filename=%%i"
    for /f "tokens=1* delims=-" %%a in ("!filename!") do (
        set "folderName=%%a"
        if not exist "!folderName!" (
            md "!folderName!"
        )
        move "%%i" "!folderName!"
    )
)

endlocal
pause
复制代码

这个是只保留特殊符号左边的名称作文件夹并移入

欢迎光临批处理之家 (http://bbs.bathome.net/)