@echo off &setlocal &set/p "md=输入日期（月值/日值）："
echo,%md%|findstr /rc:"[01][0-9]/[0-3][0-9]">nul||echo,非法&endlocal&pause&exit/b
powershell "('2024/%md%' -as [DateTime]) -ne $null"|find /i "true">nul
if errorlevel 1 (echo,非法) else (echo,合法) 
endlocal&pause&exit/b
复制代码

@echo off &setlocal &set "w=非法" &set/p "md=输入日期（月值/日值）："
powershell "('2024/%md%' -as [DateTime]) -ne $null"|find /i "true">nul
if errorlevel 1 (set k=1) else if "%md:~2,1%"=="/" if "%md:~-3,1%"=="/" set "w=合法"
echo,%w%&endlocal&pause&exit/b
复制代码

set/p="1&2"<nul|find "1">nul&&echo,#1
set/p="1&2"<nul|find "2">nul&&echo,#2
复制代码

@echo off 
for /l %%i in (1,1,31) do (
    if %%i lss 10 (
        set @0%%i=1
        set #0%%i=1
    ) else (
        set @%%i=1
        if %%i leq 12 set #%%i=1
    )
)
:o
set/p "md=Please Input the Date (MM/DD):"
if not "%md://=%"=="%md%" goto :p
for /f "tokens=1* delims=/" %%i in ("%md%") do (
    if defined #%%i if defined @%%j set n=1
    if defined n (
        if "%%i" equ "02" (
            if "%%j" geq "30"    set n=
        ) else (
            for %%k in (04 06 09 11) do if "%%i" equ "%%k" if "%%j" equ "31" set n=
        )
    )
)
:p
if not defined n echo,Input Error&goto :o
echo,Input Correct
pause
复制代码

@echo off
set/p "data=Please enter a date (MM/DD):"
set "error=echo,Invalid date&pause&goto :eof"
setlocal enabledelayedexpansion
for /l %%i in (5,-1,0) do (
    set "data%%i=!data:~%%i,1!"
    if not "!data%%i!"=="" (
        if %%i equ 5 (
            %error%
        ) else if %%i equ 2 (
            if "!data%%i!" neq "/" %error%
        ) else if "!data%%i!" lss "0" (
            %error%
        ) else if "!data%%i!" gtr "9" %error%
    ) else (
        if %%i equ 4 %error%
    )
)
if %data0% equ 0 set "data0="
if %data3% equ 0 set "data3="
set mm=%data0%%data1%
set dd=%data3%%data4%
if %mm% gtr 12 %error%
if %dd% gtr 31 %error%
for /f "tokens=2" %%i in ('wmic os get codeset^,localdatetime') do (
    set yyyy=%%i
    set "yyyy=!yyyy:~0,4!"
    )
endlocal&set /a mm=%mm%,dd=%dd%,yyyy=%yyyy%
set /a "gtm=!(mm-4)|!(mm-6)|!(mm-9)|!(mm-11)","leap=!(yyyy%%4)&!!(yyyy%%100)|!(yyyy%%400)","dlim=!(mm-2)*(28+leap)+gtm*30+(!!(mm-2)&!gtm)*31"
if %dd% gtr %dlim% (%error%) else (echo,Valid date)
pause&exit /b
复制代码

if not "%md:~2,1%"=="/" goto :p
复制代码

@echo off
set /p str=input:
setlocal enabledelayedexpansion
>1.txt echo=#!str!
endlocal
findstr /rxc:"#[0-9][0-9]/[0-9][0-9]" 1.txt
if not errorlevel 1 (
	echo ok
)
pause
复制代码

即便是批处这类简单脚本级的造码，也是讲究 ‘有效 》可靠 》高效 》简洁’ 四重关，新手过头关，老手要高攀，若每次出手都能 ‘会当凌绝顶’，真可谓功德圆满了... 共勉共勉

findstr /x "0[1-9]/[0-2][1-9] 1[0-2]/[0-2][1-9] 0[1-9]/[12]0 1[0-2]/[12]0 0[13-9]/30 1[0-2]/30 0[13578]/31 1[02]/31"
复制代码

再练一把 ‘纯P进行到底’ 的脑力操...
给一个纯P版本的日期输入合法性检查代码，不用外部方法，不用正则匹配
算法简明得益于采用 ‘字典变量’，尽可能考虑了各种防错对策》分隔符及其错位，日月数值溢出，日月相关，平闰年天数区分... 还是回归日月均为两位数的要求。
以下代码采用循环输入以便完成各种测试，直至空回车退出...

@echo off &setlocal
set/a "_1=31,_2=28,_3=31,_4=30,_5=31,_6=30,_7=31,_8=31,_9=30,_10=31,_11=30,_12=31,y=%date:~,4%%%4"
if %y% equ 0 set "_2=29"
:[md_loop]
set "md=" &set "c=" &set/p "md=输入日期（月值/日值）："
if not defined md endlocal&exit/b
setlocal enabledelayedexpansion &set k=!md:"=!
if "!k!" neq "!md!" echo,非法&endlocal&goto[md_loop]
endlocal &if "%md:~5%" neq "" echo,非法&goto[md_loop]
if "%md:~4,1%"=="" echo,非法&goto[md_loop]
for /f "tokens=1,2 delims=/" %%1 in ("%md%") do set "m=%%1"&set "d=%%2"
if "%md%"=="%m%" echo,非法&goto[md_loop]
for /f "delims=0123456789" %%n in ("%m%%d%") do set "c=1"
if defined c echo,非法&goto[md_loop]
if not defined d echo,非法&goto[md_loop]
if "%md:~2,1%" neq "/" echo,非法&goto[md_loop]
if "%m:~0,1%" equ "0" if "%m:~1,1%" neq "" set "m=%m:~1%"
set "_m=_%m%" &set "w=非法" &setlocal enabledelayedexpansion
if "%d:~0,1%" equ "0" if "%d:~1,1%" neq "" set "d=%d:~1%"
if %d% gtr 0 if %d% leq !%_m%! set "w=合法"
echo,!w!&endlocal&goto[md_loop]
复制代码

@echo off
for /f %%a in ('wmic os get localdatetime ^|findstr [0-9]') do set year=%%a&call set year=%%year:~0,4%%
set /a _1=_3=_5=_7=_8=_10=_12=31,_4=_6=_9=_11=30
set/a num=!(year%%4) ^& !(!(year%%100)) ^| !(year%%400),1/num 2>nul && set _2=29|| set _2=28

:loop
setlocal
set /p n=input:
set "n1=%n:~0,2%"
set "n2=%n:~2,1%"
set "n3=%n:~3,2%"
set "n4=%n:~5%"
setlocal enabledelayedexpansion
set a=非法
if "!n2!" equ "/" (
	if "!n4!" equ "" (
		for /l %%l in (1,1,12) do (
			set str=0%%l
			if "!n1!" equ "!str:~-2!" (
				for /l %%m in (1,1,!_%%l!) do (
					set str=0%%m
					if "!n3!" equ "!str:~-2!" (
						set a=合法
					)
				)
			)
		)
	)
)
endlocal & endlocal &echo %a%
goto :loop
复制代码

@echo off
for /f %%a in ('wmic os get localdatetime ^|findstr [0-9]') do set year=%%a&call set year=%%year:~0,4%%
set /a _1=_3=_5=_7=_8=_10=_12=31,_4=_6=_9=_11=30
set/a num=!(year%%4) ^& !(!(year%%100)) ^| !(year%%400),1/num 2>nul && set _2=29|| set _2=28

:loop
setlocal
set /p n=input:
setlocal enabledelayedexpansion
set a=非法
if "!n:~2,1!!n:~5,1!" equ "/" (
	for /l %%l in (1,1,12) do (
		set str=0%%l
		if "!n:~0,2!" equ "!str:~-2!" (
			for /l %%m in (1,1,!_%%l!) do (
				set str=0%%m
				if "!n:~3,2!" equ "!str:~-2!" (
					set a=合法
				)
			)
		)
	)
)
endlocal & endlocal &echo %a%
goto :loop
复制代码

45楼代码已订正，堵上了被多种 ‘怪异字符’ 轰击破防的缺口...

本帖歇后语》不用外部方法援助，不用正则匹配简化，感觉纯P自力更生的造码能力还可以...而真正的着力点落在了应对预处理和防止怪异字符的雷劈...

谢谢细心测试 45楼代码已被订正...
要纯P到底，那些 卡位，定界，全数字核查... 一点懒儿都不能偷

@echo off
for /f "tokens=2" %%i in ('wmic os get codeset^,localdatetime') do set yyyy=%%i&call set yyyy=%%yyyy:~0,4%%
set /a _01=_03=_05=_07=_08=_10=_12=31,_04=_06=_09=_11=30,"_02=28+(!(yyyy%%4)&!!(yyyy%%100)|!(yyyy%%400))"
set "error=echo,Invalid date&endlocal&goto :loop"

:loop
set /p "md=Please enter a date (MM/DD):"
setlocal enabledelayedexpansion
if "!md:~2,-2!" neq "/" (%error%)
set "mm=!md:~0,2!"&set "dd=!md:~3,2!"
for /f "delims=0123456789" %%i in ("!mm!!dd!") do (%error%)
if "!dd!" gtr "00" if "!dd!" leq "!_%mm%!" (echo,Valid date&endlocal&goto :loop)
%error%
复制代码

谢谢 代码已订正... 但愿是最后一把 ‘堵漏灵’...
从8楼调用 powershell+findstr 外援的4-5行代码到45楼的纯P自力更生版，已经垒起21行代码了，要经得起各种怪异字符的 ‘雷劈’ ... 纯粹是要过把瘾的一套脑力操...

@echo off
setlocal enabledelayedexpansion
:o
set/p "md=Please Input the Date (MM/DD):"
set "mm/dd=!md!"
if "!mm/dd:~2,-2!"=="/" (
    if "!mm/dd:00=!"=="!mm/dd!" (
        for /l %%i in (0,1,9) do set "mm/dd=!mm/dd:%%i=!"
        if "!mm/dd!"=="/" set n=1
    )
)
if not defined n goto :p
for /f "tokens=1* delims=/" %%i in ("!md!") do (
    if %%i gtr 12 (set n=) else if %%j gtr 31 (set n=)
    if defined n (
        if %%j equ 30 (
            if %%i equ 2 set n=
        ) else if %%j equ 31 (
            for %%k in (02 04 06 09 11) do if %%k equ %%i set n=
        )
    )
)
:p
if defined n (echo,Input Correct) else (echo,Input Error&goto :o)
pause
复制代码

12:07:14.02
12:07:15.26
1
12:07:15.26
复制代码

@echo off
for /f "tokens=2" %%i in ('wmic os get codeset^,localdatetime') do set yyyy=%%i&call set yyyy=%%yyyy:~0,4%%
set /a _01=_03=_05=_07=_08=_10=_12=31,_04=_06=_09=_11=30,"_02=28+(!(yyyy%%4)&!!(yyyy%%100)|!(yyyy%%400))"
set "error=echo,Invalid date&endlocal&goto :loop"

:loop
set /p "md=Please enter a date (M/D):"
setlocal enabledelayedexpansion
set "a=!md:*/=!"&set "dd=!a:/=!"
if "!a!" neq "!dd!" (%error%)
for /f "delims=0123456789" %%i in ("!md:/=!") do (%error%)
for /f "tokens=1* delims=/" %%i in ("!md!") do (endlocal&set "mm=%%i"&set "dd=%%j")
setlocal enabledelayedexpansion
if "!dd!"=="" (%error%)
if "!mm:~2,1!" neq "" (%error%)
if "!dd:~2,1!" neq "" (%error%)
if "!mm:~0,1!" equ "0" if "!dd:~1,1!"=="" (%error%)
if "!dd:~0,1!" equ "0" if "!mm:~1,1!"=="" (%error%)
set "mm=0!mm!"&set "mm=!mm:~-2!"
set "dd=0!dd!"&set "dd=!dd:~-2!"
if "!dd!" gtr "00" if "!dd!" leq "!_%mm%!" (echo,Valid date&endlocal&goto :loop)
%error%
复制代码

精简了45楼代码中的操作步骤和合法性核查逻辑，行数减至18行，8个goto减至2个...
操作步骤要点》
   双引号排查
   输入长度排查
   定界符及其错位排查
   日月值全数字排查
   日月相关变化所对应的字典变量 以及 平闰年天数增减修正
   全程严防 &!"^ 等特殊字符雷劈的对策...
再次感谢各位细心测试反馈 就算是一场把纯P贯彻到底的基本功组合复习吧...

@echo off &setlocal
set/a "_1=31,_2=28,_3=31,_4=30,_5=31,_6=30,_7=31,_8=31,_9=30,_10=31,_11=30,_12=31,y=%date:~,4%%%4"
if %y% equ 0 set "_2=29"
:[md_loop]
set "$md=" &set "c=" &set/p "$md=输入日期（月值/日值）："
if not defined $md endlocal&exit/b
setlocal enabledelayedexpansion &set #md=!$md:"=!
if "!#md!"=="!$md!" if "!$md:~5!"=="" if "!$md:~4,1!" neq "" if "!$md:~2,1!"=="/" (
	set "m=!$md:~0,2!"&set "d=!$md:~3!"
	for /f "delims=0123456789/" %%n in ("!$md!") do set "c=1"
	if not defined c goto[ok] )
echo,非法&endlocal&goto[md_loop]
:[ok]
if "!m:~0,1!" equ "0" set "m=!m:~1!"
set "_m=_!m!" &set "w=非法"
if "!d:~0,1!" equ "0" set "d=!d:~1!"
if !d! gtr 0 if !d! leq !%_m%! set "w=合法"
echo,!w!&endlocal&goto[md_loop]
复制代码

@echo off
for /l %%i in (1,1,12) do (
    for /l %%j in (1,1,31) do (
        if %%i lss 10 (
            if %%j lss 10 (
                set _"%%i/%%j"=0
                set _"0%%i/0%%j"=0
            ) else (
                set _"%%i/%%j"=0
                set _"0%%i/%%j"=0
            )
        ) else (
            if %%j lss 10 (
                set _"%%i/%%j"=0
                set _"%%i/0%%j"=0
            ) else (
                set _"%%i/%%j"=0
            )
        )
    )
)
for %%i in (2 4 6 9) do (
    set _"%%i/31"=
    set _"0%%i/31"=
)
set _"11/31"=
set _"2/30"=
set _"02/30"=
setlocal enabledelayedexpansion
:o
set/p "md=Please Input the Date (MM/DD):"
if defined _"!md!" (
    echo,Input Correct
) else (
    echo,Input Error
    goto :o
)
pause
复制代码

16:25:16.03
16:25:16.15
16:25:16.20
复制代码

批处是一种典型的解译型脚本，其执行原理基本上就是逐行处理（连注释行也不放过），也许对复合语块要先全块读尽再逐行处理，因此代码能并为一行会比分行的解译执行效率高，此被老帖早有述及，但这同时也会降低代码可读性... 总而言之，这是一个二者权衡尺度的问题，又是一个造码者编程风格或言个人偏好的问题...

@echo off
for /l %%l in (1,1,5) do (
	timeout 3 >nul
	setlocal
	echo 紧凑型
	call echo %%time%%
	call :1
	call echo %%time%%
	endlocal
	echo=
	timeout 3 >nul
	setlocal
	echo 分散型
	call echo %%time%%
	call :2
	call echo %%time%%
	endlocal
	echo=
)
pause
exit

	:1
	for /l %%l in (1,1,10000) do (
		set /a a=1&set /a b=2&set /a c=3&set /a d=4&set /a e=5&set /a f=6&set /a g=7
	)
	exit /b
	:2
	for /l %%l in (1,1,10000) do (
		set /a a=1
		set /a b=2
		set /a c=3
		set /a d=4
		set /a e=5
		set /a f=6
		set /a g=7
	)
	exit /b
复制代码

紧凑型
17:15:34.13
17:15:38.26

分散型
17:15:41.12
17:15:45.01

紧凑型
17:15:48.19
17:15:52.18

分散型
17:15:55.16
17:15:59.17

紧凑型
17:16:02.14
17:16:06.23

分散型
17:16:09.20
17:16:13.18

紧凑型
17:16:16.18
17:16:20.20

分散型
17:16:23.16
17:16:27.09

紧凑型
17:16:30.16
17:16:34.17

分散型
17:16:37.16
17:16:41.06

请按任意键继续. . .
复制代码

已说过也许批处对复合语块典型如for...句式是先全块读尽处理的，此乃for句式效率较高的原因，其内是不能如其外简单分行执行的...
与解译型脚本逐行解译执行原理一致的纯净测试应该如是：
   set a=...&set b=...&...
和
  set a=...
  set b=...
  ...
比对测试
但对批处的小微代码测试而言，其差别也许无感...

for %%i in (1) do (
    set "a=1"
    set "b=2"
    set "c=3"
)
复制代码

for %%i in (1) do set "a=1" & set "b=2" & set "c=3"
复制代码

for %%i in (1) do (
    set "a=1" & set "b=2" & set "c=3"
)
复制代码