; cgi.fix_pathinfo = 0
复制代码

; cgi.fix_pathinfo = 0
复制代码

cgi.fix_pathinfo = 1
复制代码

set "PHP_INI_FILE=php.ini-dist"
for /f "delims=" %%i in ('type "%PHP_INI_FILE%"') do ( 
            set "line=%%i" 
            set "line=!line:%SEARCH_TEXT%=%REPLACE_TEXT%!" 
            echo !line!>>"php.ini" 
)
复制代码

set "PHP_INI_FILE=php.ini-dist"
for /f "delims=" %%i in ('type "%PHP_INI_FILE%"') do ( 
            set "line=%%i" 
            if "!line!" == "%SEARCH_TEXT%" (
                echo "%REPLACE_TEXT%" >> "%OUTPUT_FILE%" 
            )
            echo !line!>>"php.ini" 
)
复制代码

@echo off &setlocal
set "PHP_INI_FILE=php.ini-dist"
set "SEARCH_TEXT=; cgi.fix_pathinfo = 0"
set "REPLACE_TEXT=cgi.fix_pathinfo = 1"
(for /f "eol=╟ delims=" %%i in (%PHP_INI_FILE%) do (
    if /i "%%i"=="%SEARCH_TEXT%" (echo,%REPLACE_TEXT%) else echo,%%i
))>"php.ini"
pause&exit/b
复制代码

@echo off
set "PHP_INI_FILE=php.ini-dist"
set "SEARCH_TEXT=; cgi.fix_pathinfo = 0"
set "REPLACE_TEXT=cgi.fix_pathinfo = 1"
(for /f "delims="eol^= %%i in (%PHP_INI_FILE%) do (
	if /i "%%i"=="%SEARCH_TEXT%" (echo,%REPLACE_TEXT%) else echo,%%i
))>"php.ini"
pause&exit/b
复制代码

@echo off
set "PHP_INI_FILE=php.ini-dist"
set "SEARCH_TEXT=; cgi.fix_pathinfo=0"
set "REPLACE_TEXT=cgi.fix_pathinfo=1"
(for /f "tokens=1* delims=:" %%a in ('findstr /n ".*" %PHP_INI_FILE%') do (
    if /i "%%b"=="%SEARCH_TEXT%" (echo,%REPLACE_TEXT%) else echo,%%b
))>"php.ini"
pause&exit/b
复制代码

@echo off & setlocal
set "SEARCH_TEXT=; cgi.fix_pathinfo=0"
set "REPLACE_TEXT=cgi.fix_pathinfo=1"
sed.exe "s/%SEARCH_TEXT%/%REPLACE_TEXT%/gi" "php.ini-dist">"php.ini"
pause&exit/b
复制代码

@echo off

set "PHP_INI_FILE=php.ini-dist"
set "SEARCH_TEXT=; cgi.fix_pathinfo = 0"
set "REPLACE_TEXT=cgi.fix_pathinfo = 1"

(
for /f "delims=" %%i in ('findstr /n .* "%PHP_INI_FILE%"') do ( 
set "line=%%i" 
setlocal enabledelayedexpansion
set "line=!line:*:=!"
if /i "!line!" == "!SEARCH_TEXT!" (
echo(!REPLACE_TEXT!||/ ^)
) else (
echo(!line!||/ ^)
)
endlocal
)
)>"php.ini"

pause&exit/b
复制代码

set "SEARCH_TEXT=; cgi.fix_pathinfo=0"
        set "REPLACE_TEXT=cgi.fix_pathinfo = 1"
        (for /f "delims=" %%i in ('findstr /n ".*" %PHP_INI_FILE%') do (
            if /i "%%i"=="%SEARCH_TEXT%" (echo,%REPLACE_TEXT%) else echo,%%i
        ))>"%OUTPUT_FILE%" 
复制代码

[PHP]
;;;;;;;;;;;
; Directive names are *case sensitive* - foo=bar is different from FOO=bar.
;
; |        bitwise OR
; &        bitwise AND
; !        boolean NOT
engine = On
; Allow the <? tag.  Otherwise, only <?php and <script> tags are recognized.
precision    =  12
;output_handler =
zlib.output_compression = Off
; *NOT* affected by whether Safe Mode is turned On or Off.

; cgi.fix_pathinfo provides *real* PATH_INFO/PATH_TRANSLATED support for CGI.  PHP's
; cgi.fix_pathinfo=0

;fbsql.default_user = "_SYSTEM"
soap.wsdl_cache_dir="/tmp"
复制代码

set "SEARCH_TEXT=; cgi.fix_pathinfo=0"
        set "REPLACE_TEXT=cgi.fix_pathinfo=1"
        (for /f "tokens=1* delims=:" %%a in ('findstr /n ".*" %PHP_INI_FILE%') do (
            if /i "%%b"=="%SEARCH_TEXT%" (echo,%REPLACE_TEXT%) else echo,%%b
        ))>>"%OUTPUT_FILE%" 
复制代码

@echo off

set "PHP_INI_FILE=php.ini-dist"
set "SEARCH_TEXT=; cgi.fix_pathinfo=0"
set "REPLACE_TEXT=cgi.fix_pathinfo=1"

(
for /f "delims=" %%i in ('findstr /n .* "%PHP_INI_FILE%"') do ( 
set "line=%%i" 
setlocal enabledelayedexpansion
set "line=!line:*:=!"
if /i "!line!" == "!SEARCH_TEXT!" (
echo(!REPLACE_TEXT!||/ ^)
) else (
echo(!line!||/ ^)
)
endlocal
)
)>"php.ini"

pause&exit/b
复制代码

24楼报告结果表明用14楼代码处理20楼所附 'php-5.2.9-Win32.zip' 中的 php.ini-dist 文件（该文件是ansi编码，1284行，没有中文字符，仅在第520行出现被替换字段）已经顺利通过
处理结果是第520行被正确替换，且全文中的 ! 字符均得以保留（包括113、193、316、401、772、807行中的 ! 字符）因为14楼代码全程没有开启延迟变量，字符串包含的 ! 字符不会被转义求值...
楼主采用的全部测试代码中除了14楼代码还有其他前置代码吗？被测试的是这个 php-5.2.9-Win32.zip' 中的 php.ini-dist 文件吗

@echo off
set "file=D:\php-5.2.9-Win32\php.ini-dist"

rem a对应b，不需要空格
set "#"a"=b"
set "#"cgi.fix_pathinfo"=1"
rem 替换为空值，则值为 / 在21行判断，如
set "#"c"=/"

(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "%file%"') do (
	if "%%b" neq "" (
		for /f "delims==" %%c in (" %%b") do (
			for /f "tokens=1* delims=; " %%d in ("%%c") do (
				if defined #"%%d" (
					if "%%e" equ "" (
						for /f "tokens=* delims=; " %%f in (" %%b#") do (
							for /f "tokens=1* delims==" %%g in ("%%f") do (
								for /f "tokens=*" %%i in ("%%h") do (
									set str=%%f
									setlocal enabledelayedexpansion
									if "!#"%%d"!" equ "/" (
										echo=%%g=
									) else (
										call echo=!str:%%i=%%#"%%d"%%!
									)
									endlocal
									set m_e=1
								)
							)
						)
					)
				)
			)
		)
	)
	if defined m_e (
		set m_e=
	) else (
		echo=%%b
	)
)) > "out.txt"
rem move "out.txt" "%file%"
pause
复制代码

@echo off &endlocal &setlocal
set "PHP_INI_FILE=php.ini-dist"
set "SEARCH_TEXT=; cgi.fix_pathinfo=0"
set "REPLACE_TEXT=cgi.fix_pathinfo=1"
for /f "tokens=1 delims=:" %%a in ('findstr /n ".*" "%PHP_INI_FILE%"^|findstr /ic:"%SEARCH_TEXT%" ') do set "_#%%a=1"
(for /f "tokens=1* delims=:" %%a in ('findstr /n ".*" %PHP_INI_FILE%') do (
    if defined _#%%a (echo,%REPLACE_TEXT%) else echo,%%b))>"php.ini"
pause&exit/b
复制代码

   set "INPUT_FILE_52_dev=php.ini-dist"
   setlocal enabledelayedexpansion
    <略 去一些其他代码>
   endlocal

   @REM 获取配置文件
    set PHP_INI_FILE=
    if exist "%INPUT_FILE_52_dev%" (
        set PHP_INI_FILE="%INPUT_FILE_52_dev%"
    ) else if exist "%INPUT_FILE_dev%" (
        set PHP_INI_FILE="%INPUT_FILE_dev%"
    ) else (
        echo. & echo.
        echo [ Error ] 没有匹配的 dev 版 ini 配置文件:%PHP_INI_FILE% ！！！ 
        echo. & echo. & pause & exit /b
    )
复制代码

[ Error ] 没有匹配的 dev 版 ini 配置文件: ！！！
复制代码

rem 另存为 ANSI 编码 bat
' & cls & cscript.exe /nologo /e:vbscript "%~f0" %* & pause & exit /b

PHP_INI_FILE = "php.ini-dist"
SEARCH_TEXT  = "; cgi.fix_pathinfo = 0"
REPLACE_TEXT = "cgi.fix_pathinfo = 1"
OUT_FILE     = "php.ini"

Set oStream = CreateObject("ADODB.Stream")
oStream.Type = 2
oStream.Mode = 3
oStream.Charset = "GBK"
oStream.Open()
oStream.LoadFromFile PHP_INI_FILE
s = oStream.ReadText()
oStream.Close()
m = Replace(SEARCH_TEXT, " ", "")
m = Replace(m, ".", "\.")
Pattern = "^"
If Left(m, 1) = ";" Then
    Pattern = Pattern & "; *"
    m = Right(m , Len(m) - 1)
End If
m = Split(m, "=")
Pattern = Pattern & m(0) & " *= *" & m(1)
Set oRegExp = CreateObject("VBScript.RegExp")
oRegExp.Global = True
oRegExp.MultiLine = True
oRegExp.IgnoreCase = True
oRegExp.Pattern = Pattern
If oRegExp.Test(s) Then s = oRegExp.Replace(s, REPLACE_TEXT)
oStream.Open()
oStream.WriteText s
oStream.SaveToFile OUT_FILE, 2
oStream.Close()
复制代码

set "INPUT_FILE_529_dev=php.ini-dist"
set "INPUT_FILE_541_dev=php.ini-development"
set "PHP_INI_FILE=php.ini-development"

if "%INPUT_FILE_529_dev%" == "%PHP_INI_FILE%" ( 
        @REM 替换v5.2.9版 dev 的 php.ini-dist 文件内容
        set "SEARCH_TEXT=; cgi.fix_pathinfo=0"
        set "REPLACE_TEXT=cgi.fix_pathinfo=1"
        (for /f "tokens=1* delims=:" %%a in ('findstr /n ".*" %PHP_INI_FILE%') do (
            if /i "%%b"=="%SEARCH_TEXT%" (echo,%SEARCH_TEXT% & echo,%REPLACE_TEXT%) else echo,%%b
        ))>"%OUTPUT_FILE%" 

) else if  "%INPUT_FILE_541_dev%" == "%PHP_INI_FILE%" (
    @REM 替换v5.4.1版 dev 的 php.ini-development 文件内容

    set "SEARCH_TEXT=;cgi.fix_pathinfo=1"
    set "REPLACE_TEXT=cgi.fix_pathinfo=1"
    (for /f "tokens=1* delims=:" %%a in ('findstr /n ".*" %PHP_INI_FILE%') do (
        echo b=%%b
        echo SEARCH_TEXT=%SEARCH_TEXT%
        echo REPLACE_TEXT=%REPLACE_TEXT%
        if /i "%%b"=="%SEARCH_TEXT%" (echo,%REPLACE_TEXT%) else echo,%%b
    ))>"%OUTPUT_FILE%" 
)
复制代码

@echo off

if ""=="" (
    set "PHP_INI_FILE=php-5.2.9-Win32\php.ini-dist"
    set "SEARCH_TEXT=; cgi.fix_pathinfo=0"
    set "REPLACE_TEXT=cgi.fix_pathinfo=1"
    echo %PHP_INI_FILE%
    echo "PHP_INI_FILE=%PHP_INI_FILE%"
    echo "SEARCH_TEXT=%SEARCH_TEXT%"
    echo "REPLACE_TEXT=%REPLACE_TEXT%"
    (for /f "tokens=1* delims=:" %%a in ('findstr /n ".*" %PHP_INI_FILE%') do (
        if /i "%%b"=="%SEARCH_TEXT%" (echo,%REPLACE_TEXT%) else echo,%%b
    ))>"php-5.2.9-Win32\php.ini"
)
exit/b
复制代码