批处理之家 - Powered by Discuz! Board

标题: 批处理提取目录中的文件 [打印本页]

作者: novaa 时间: 2008-3-12 13:19 标题: 批处理提取目录中的文件

好久没写东西了。这次给大家送歌来了。这次的目标是把任意一个文件夹里面的所有歌曲取出来。(*^__^*)
------------>
一：知识讲解
1.set /p 变量=想显示的提示语这里
这个是提示用户输入的语句
set /p 变量=请输入：
则会显示
请输入：
单用户输入后就会把用户输入的保存到变量中
我们还经常遇到这样的
set /p=请输入:<nul
即没有变量,<代替了要输入的。这个一般用来提示用户。后面一般跟pause或ping比如
set /p=这只是提示作用<nul
pause>nul
echo novaa
就是提示你按键。只要用户输入了就echo novaa；
2.for 的 R开关
在CMD下输入for /?可以看到关于for的4个开关
FOR /R [[drive:]path] %variable IN (set) DO command [command-parameters]
检查以 [drive:]path 为根的目录树，指向每个目录中的
FOR 语句。如果在 /R 后没有指定目录，则使用当前
目录。如果集仅为一个单点(.)字符，则枚举该目录树。
/R开关就是吧一个磁盘里面符合一定格式的文件提取出来。比如
for /r c:\windows\system32 %%i in (*.dll) do echo %%i&pause
就是把系统目录里面的dll文件提取出来。
3.从完整的文件路径中提取文件名
在for /?里面可以看到
另外，FOR 变量参照的替换已被增强。您现在可以使用下列
选项语法:
   ~I       - 删除任何引号(")，扩充 %I
   %~fI       - 将 %I 扩充到一个完全合格的路径名
   %~dI       - 仅将 %I 扩充到一个驱动器号
   %~pI       - 仅将 %I 扩充到一个路径
   %~nI       - 仅将 %I 扩充到一个文件名
   %~xI       - 仅将 %I 扩充到一个文件扩展名
   %~sI       - 扩充的路径只含有短名
   %~aI       - 将 %I 扩充到文件的文件属性
   %~tI       - 将 %I 扩充到文件的日期/时间
我们利用这个就可以将文件名提取出来了
------------>
二：实战
先讲下这次要做的事情。先提示用户讲自己保存歌曲的文件夹拖进窗口。从而得到目录
然后从目录中提取文件名。然后把完整的文件路径（c:\windows\system32\bootvid.dll）中提取出文件名bootvid
好了
我们开始写代码了:

@echo off&setlocal enabledelayedexpansion
set /p mulu=请将歌曲所放文件夹拖进本窗口：
cls
for /r %mulu% %%i in (*.mp3 *.wma) do (
set name=%%~nxi
rem 这里就是讲完整目录名换为文件名和文件类型
set /p= !name!<NUL&ECHO\
)
echo 完毕.!
pause>nul
复制代码

作者: 封印 时间: 2008-3-17 00:14

本人没成功，VISTA系统。不知道支不支持拖动。。。不知道错在哪里指点一下，谢谢。

作者: novaa 时间: 2008-3-18 21:22

怎么没成功呢。？什么情况。？

作者: lhjoanna 时间: 2008-11-6 18:07

可以成功啊，只是因为echo\这一句，使每输出的名字后都跟一个\，还有就是对于文件夹下有几个子文件夹内都不同分类的歌曲，这样输出的话就有些乱，我在楼主基础上改编了一下，可以支持子文件夹分类，我菜鸟啊，还望高手多给建议。

@echo off
setlocal enabledelayedexpansion
set /p mulu=请将歌曲文件夹拖进本窗口：
cls
for /r %mulu% %%i in (*.mp3 *.wma) do (
set m=%%~dpi
if !m! neq !t! echo.&echo [!m:~0,-1!]
echo   %%~nxi
set t=!m!
)
echo [完毕]
pause>nul
复制代码

大家运行看看，有什么错误就指出啊，一起学习。

作者: wangmz5908 时间: 2008-12-5 15:04

C:\Documents and Settings\Administrator>for /r c:\windows\system32 %%i in (*.dll
) do echo %%i&pause
此时不应有 %%i。
什么原因？

作者: Batcher 时间: 2008-12-5 15:24 标题: 回复 5楼的帖子

批处理中用%%i
命令行中用%i

作者: 心愿怕人 时间: 2009-1-31 17:15 标题: 我是菜鸟

是啊，我也不会！这太复杂了

作者: kingerpk 时间: 2009-2-4 23:33

set /p= !name!<NUL&ECHO\
是什么意思？
能解释一下吗？

作者: Batcher 时间: 2009-2-5 09:41 标题: 回复 8楼的帖子

在屏幕上输出一个空格再加上变量!name!的内容，然后输出一个换行。

作者: zjw1987_51 时间: 2009-7-29 19:50

我是菜鸟
我也不会！这太复杂了

作者: caimingbing 时间: 2010-1-11 09:26

慢慢消化中!真费劲!

作者: baixfps 时间: 2010-1-19 01:17

本人绝对新手。。现在只回贴，日后再交流！谢谢各大虾！

作者: a590687 时间: 2010-1-20 21:50

我比较习惯用dir . 之前忘了设delims为空值遇到有空格的文件路径就废了.

@echo off
set /p mulu=请将歌曲所放文件夹拖进本窗口：
for /f "delims=" %%i in ('dir /a /s /b %mulu%^|findstr /i /e "mp3 wma"') do (
 echo %%~nxi
)
pause
复制代码

[ 本帖最后由 a590687 于 2010-1-21 10:34 编辑 ]

作者: gxuan2008 时间: 2010-1-20 22:42

郁闷。。。情况跟二楼一样。
是不是VISTA系统不支持文件夹拖动CMD窗口。。。

作者: Batcher 时间: 2010-1-20 23:31 标题: 回复 14楼的帖子

把@echo off删掉，再试试，仔细看看执行过程。

作者: summerflower 时间: 2010-1-21 11:08

为什么要这么麻烦，一个命令不就解决了吗

dir /s /b *.mp3,*.wma [拖入文件夹]
复制代码

这样就可以呀

作者: q1x2x3 时间: 2010-1-29 09:05

set name=%%~nxi
请问这句什么意思。。。没理解

欢迎光临批处理之家 (http://bbs.bathome.net/)