Board logo

标题: [数值计算] 根据给定的两个起止日期按先后/早晚顺序列出指定范围内的所有日期 [打印本页]
作者: namejm    时间: 2010-4-7 19:40     标题: 根据给定的两个起止日期按先后/早晚顺序列出指定范围内的所有日期

本帖最后由 pcl_test 于 2017-4-6 08:42 编辑

在其他论坛看到有这样一个需求：
建立以日期为名字的文件夹，从20100406到20101230

　　感觉这个需求有很多地方都可能用得到，因此，我想把这个问题扩展一下，使得它更具有通用性，具体要求为：

　　1、能在批处理界面中通过手工输入起止日期的方式，自动生成起止日期范围内的所有日期数列（必须考虑平年闰年大月小月），按日期早晚输出到文本中去，一行一条数据，日期格式为8位的纯数字格式，比如20100407；
　　2、如果在批处理界面中只输入一个日期，将以系统当前日期为起点，以输入的日期为终点，按照上一条的格式输出数据；
　　3、最好不生成临时数据。
=====================================

　　再加一条：
　　4、最好通过纯批处理来处理，速度不能太慢。

　　对第2点做稍许变动：如果只输入一个日期，则和系统当前日期做比较，以较早的日期为起点，较晚的日期为终点，按照第1条的要求输出数据。

　　其中，难点在于第1和第3点，把这两点解决了，第2点将迎刃而解。

　　难点提示：
　　1、年份有平年闰年之分，日期大小月各不相同；
　　2、系统的日期格式有很多种，在处理时需要做格式化，统一成形如YYYYMMDD的8位纯数字；
　　3、若照搬以前那个批处理版万年历的代码，将难以按照日期早晚的顺序输出数据。


　　关于闰年的判断方法（转自百度百科：http://baike.baidu.com/view/29649.htm?fr=ala0_1）：
　　判定公历闰年遵循的一般规律为: 四年一闰,百年不闰,四百年再闰.
　　公历闰年的精确计算方法:（按一回归年365天5小时48分45.5秒）
　　①、普通年能被4整除的为闰年。（如2004年就是闰年,1901年不是闰年）　
　　②、世纪年能被100整除而不能被400整除的不是闰年。(如2000年是闰年，3200年是闰年，1900年不是闰年)
　　③、对于数值很大的年份能整除3200,但同时又能整除172800则又是闰年.(如172800年是闰年，864000年不是闰年）
作者: GNU    时间: 2010-4-7 21:39

BAT调用VBS或者第三方命令行工具均可实现，不过似乎和第三点有些冲突。
还可以调用现成的日期计算函数，但效率估计不是很高。
作者: namejm    时间: 2010-4-7 21:49

最好通过纯批处理来实现。
作者: hanyeguxing    时间: 2010-4-7 21:53

  1. @echo off&setlocal enabledelayedexpansion

  2. :han

  3. set a=

  4. set b=

  5. set/p a=起始日期，格式20071221：

  6. set/p b=终止日期，格式20080310，允许为空：

  7. if "%a%"=="" echo.此数值不允许为空，请按任意键重新开始&pause>nul&goto :han

  8. set m=寒夜312831303130313130313031孤星

  9. for /f "tokens=1,2,3 delims=-:/ " %%i in ("%date%") do set i=%%i%%j%%k

  10. if "%b%"=="" (if %i% gtr %a% (set b=%i%) else set a=%i%&set b=%a%)

  11. if "%a:~4,1%"=="0" (set tm=%a:~5,1%) else set tm=%a:~4,2%

  12. if "%a:~6,1%"=="0" (set td=%a:~7,1%) else set td=%a:~6,2%

  13. set ty=%a:~0,4%&echo.%a%

  14. :ye

  15. set/a "n=tm*2","td=td+1","y=(^!(ty%%4)&^!^!(ty%%100))|^!(ty%%400)"

  16. set e=!m:~%n%,2!

  17. if %tm%==2 if %y%==1 set e=29

  18. if %td% gtr %e% set/a "tm=tm+1",td=1

  19. if %tm%==13 set/a "ty=ty+1",tm=1

  20. set em=0%tm%&set ed=0%td%&set em=!em:~-2!&set ed=!ed:~-2!&set d=%ty%!em!!ed!

  21. if %d% gtr %b% echo 完成&pause>nul&goto :eof

  22. echo.%d%&goto :ye
复制代码
改了好几次，问题太多。。。还请大家多多指教

[ 本帖最后由 hanyeguxing 于 2010-4-8 01:05 编辑 ]
作者: neorobin    时间: 2010-4-7 22:10

稍作修改, 少许提高效率:
  1. @echo off & setlocal enabledelayedexpansion

  2. set /p ymds=请输入起始日期(yyyymmdd):

  3. set /p ymde=请输入截止日期(yyyymmdd):

  4. (set y=!ymds:~0,4!)&(set m=!ymds:~4,2!)&(set d=!ymds:~6,2!)

  5. set /a "y=1!y!-10000, m=1!m!-100, d=1!d!-100"

  6. echo 起始日期为:!y!-!m!-!d!

  7. set /a "leap=(^!(y%%4)&^!^!(y%%100))|^!(y%%400)"

  8. set /a "f=^!(m-2), s=^!(m-4)|^!(m-6)|^!(m-9)|^!(m-11)"

  9. set /a "dmax=f*(28+leap)+s*30+(^!f&^!s)*31"

  10. (set _y=000!y!)&(set _y=!_y:~-4!)&(set _m=0!m!)&(set _m=!_m:~-2!)

  11. :loop

  12. (set _d=0!d!)&(set _d=!_d:~-2!)

  13. if "!_y!!_m!!_d!" leq "!ymde!" (echo !_y!!_m!!_d!) else goto :break

  14. set /a d+=1

  15. if !d! gtr !dmax! (

  16. 	(set d=1)&(set /a m+=1)

  17. 	if !m! gtr 12 (

  18. 		(set m=1)&(set /a y+=1)&(set _y=000!y!)&(set _y=!_y:~-4!)

  19. 		set /a "leap=(^!(y%%4)&^!^!(y%%100))|^!(y%%400)"

  20. 	)

  21. 	set /a "f=^!(m-2), s=^!(m-4)|^!(m-6)|^!(m-9)|^!(m-11)"

  22. 	set /a "dmax=f*(28+leap)+s*30+(^!f&^!s)*31"

  23. 	(set _m=0!m!)&(set _m=!_m:~-2!)

  24. )

  25. goto :loop

  26. :break

  27. pause
复制代码
作者: FOR    时间: 2010-4-7 22:14

计算 100 年的日期 耗时 3.7 秒
  1. @echo off&setlocal enabledelayedexpansion

  2. set t=%time%

  3. echo 请输入8位数的起始日期和结束日期用空格分开

  4. echo 或只输入结束（开始）日期，默认当前日期为起始（结束）日期

  5. echo 输入格式 20080205 21080529&echo.

  6. set xx=19100201

  7. for /f "tokens=1,2" %%i in ("%xx%") do (

  8.    if not "%%j"=="" (set qs=%%i&set js=%%j) else (

  9.       for /f "tokens=1-3 delims=.\-/ " %%a in ("!date!") do (

  10.          if %%a%%b%%c gtr %%i (set/a qs=xx,js=%%a%%b%%c) else (

  11.             set/a qs=%%a%%b%%c,js=%%i

  12. ))))

  13. for %%a in (31 28 31 30 31 30 31 31 30 31 30 31) do set/a n+=1&set/a yue!n!=%%a

  14. set /a qsd=100%qs:~4,2%%%100,qsm=100%qs:~6,2%%%100

  15. set /a yuq=qsd,yuh=12,mq=qsm,mh=yue!qsd!

  16. (

  17. echo 起始日期 %qs:~0,4%-%qs:~4,2%-%qs:~6,2%

  18. echo 结束日期 %js:~0,4%-%js:~4,2%-%js:~6,2%

  19. for /l %%i in (%qs:~0,4% 1 %js:~0,4%) do (

  20.     if %%i equ %js:~0,4% set /a yuh=100%js:~4,2%%%100&set flag=a

  21.     for /l %%j in (!yuq! 1 !yuh!) do (

  22.        if %%j equ 2 (

  23.           set /a yue2="^!(%%i%%4)&^!(^!(%%i%%100))|^!(%%i%%400)"+28,mh=yue2

  24.         ) else set /a mh=yue%%j

  25.        if defined flag if %%j equ !yuh! set /a mh=100!js:~-2!%%100

  26.        for /l %%k in (!mq! 1 !mh!) do (

  27.           set numd=0%%j&set "numm=0%%k"

  28.           echo %%i!numd:~-2!!numm:~-2!

  29.         )

  30.        set /a mq=1&echo;

  31.      )

  32.      set yuq=1

  33. )

  34. echo 耗时：

  35. echo %t%

  36. echo !time!

  37. )>c.txt

  38. start c.txt

  39. exit
复制代码

[ 本帖最后由 FOR 于 2010-4-7 23:22 编辑 ]
作者: namejm    时间: 2010-4-7 22:43

　　对第2点做稍许变动：如果只输入一个日期，则和系统当前日期做比较，以较早的日期为起点，较晚的日期为终点，按照第1条的要求输出数据。
作者: namejm    时间: 2010-4-7 22:58

　　hanyeguxing在4楼的代码没有做准确的平年闰年检测；FOR在7楼的代码输出的格式为 2010-4-1 ，由于未做充分测试，其他问题尚未发现。
作者: FOR    时间: 2010-4-7 23:03

输出格式已改，但对系统日期作统一处理不会。
作者: namejm    时间: 2010-4-7 23:10

Re FOR：
　　运行了你修改后的代码，发现生成350多K的数据竟然只花费了0秒——嘿嘿，貌似 echo %time% 要改成 call echo %%time%% 才对。
作者: FOR    时间: 2010-4-7 23:18

改成了 echo !time! 发现把输出格式改了后，多运行了一句set numd=0%%j&set "numm=0%%k" 速度居然到了3秒多
作者: hanyeguxing    时间: 2010-4-7 23:23

原帖由 namejm 于 2010-4-7 22:58 发表
　　hanyeguxing在4楼的代码没有做准确的平年闰年检测；FOR在7楼的代码输出的格式为 2010-4-1 ，由于未做充分测试，其他问题尚未发现。

判定公历闰年遵循的一般规律为: 四年一闰,百年不闰,四百年再闰.
崩溃。。。。。。。光记得4年的事了，其他的不是忘记了，而是根本就不知道，汗一个。。。

[ 本帖最后由 hanyeguxing 于 2010-4-7 23:27 编辑 ]
作者: neorobin    时间: 2010-4-7 23:43

4 楼还有起始月输出不正确的问题:
  1. e=!m:~%n%,2!
复制代码
如此截取是有问题的
作者: neorobin    时间: 2010-4-7 23:47

借鉴了 4 楼日数序列的方法, 效率仍不高, 看来可看下 FOR 的思路并尝试
  1. @echo off&setlocal enabledelayedexpansion

  2. (set days=312831303130313130313031)

  3. set /p ymds=请输入起始日期(yyyymmdd),要使用系统当前日期,请直接回车:

  4. set /p ymde=请输入截止日期(yyyymmdd),要使用系统当前日期,请直接回车:

  5. if not defined ymds (set ymds=%date:~0,4%%date:~5,2%%date:~8,2%)

  6. if not defined ymde (set ymde=%date:~0,4%%date:~5,2%%date:~8,2%)

  7. if "!ymde!" lss "!ymds!" (

  8.   (set tt=!ymde!)&(set ymde=!ymds!)&(set ymds=!tt!)

  9. )

  10. (set y=!ymds:~0,4!)&(set m=!ymds:~4,2!)&(set d=!ymds:~6,2!)

  11. set /a "y=1!y!-10000, m=1!m!-100, d=1!d!-100"

  12. echo 起始日期为:!y!-!m!-!d!, 截止日期为:!ymde!

  13. (set /a index=m*2-2)& for %%i in (!index!) do set dmax=!days:~%%i,2!

  14. if !m!==2 set /a "dmax+=(^!(y%%4)&^!^!(y%%100))|^!(y%%400)"

  15. (set _y=000!y!)&(set _y=!_y:~-4!)&(set _m=0!m!)&(set _m=!_m:~-2!)

  16. :loop

  17. (set _d=0!d!)&(set _d=!_d:~-2!)

  18. if "!_y!!_m!!_d!" leq "!ymde!" (echo !_y!!_m!!_d!) else goto :break

  19. set /a d+=1

  20. if !d! gtr !dmax! (

  21.   (set d=1)&(set /a m+=1)

  22.   if !m! gtr 12 (set m=1)&(set /a y+=1)&(set _y=000!y!)&(set _y=!_y:~-4!)

  23.   (set _m=0!m!)&(set _m=!_m:~-2!)  

  24. 	(set /a index=m*2-2)& for %%i in (!index!) do set dmax=!days:~%%i,2!

  25. 	if !m!==2 set /a "dmax+=(^!(y%%4)&^!^!(y%%100))|^!(y%%400)"

  26. )

  27. goto :loop

  28. :break

  29. pause
复制代码
作者: hanyeguxing    时间: 2010-4-7 23:52

原帖由 neorobin 于 2010-4-7 23:43 发表
4 楼还有起始月输出不正确的问题:e=!m:~%n%,2!如此截取是有问题的

没明白。。。能不能具体说一下？
作者: neorobin    时间: 2010-4-8 00:17

实质是变量延迟的问题, 调试代码:
  1. @echo off&setlocal enabledelayedexpansion

  2. set/p a=起始日期，格式20071221：

  3. set/p b=终止日期，格式20080310：

  4. set m=寒夜312831303130313130313031孤星

  5. if "%a:~4,1%"=="0" (set tm=%a:~5,1%) else set tm=%a:~4,2%

  6. if "%a:~6,1%"=="0" (set td=%a:~7,1%) else set td=%a:~6,2%

  7. set ty=%a:~0,4%&echo.%a%

  8. :hanye

  9. echo n=!n!

  10. set/a n=%tm%*2,y=%ty%%%4,td=%td%+1,e=!m:~%n%,2!

  11. echo n=!n!,e=!e!

  12. pause

  13. if %tm%==2 if %y%==0 set e=29

  14. if %td% gtr %e% set/a tm=%tm%+1,td=1

  15. if %tm%==13 set/a ty=%ty%+1,tm=1

  16. if %tm% lss 10 (set em=0%tm%) else set em=%tm%

  17. if %td% lss 10 (set ed=0%td%) else set ed=%td%

  18. set d=%ty%%em%%ed%

  19. if %d% gtr %b% pause>nul&goto :eof

  20. echo.%d%&goto :hanye
复制代码
测试结果:
起始日期，格式20071221：18991125
终止日期，格式20080310：20000305
18991125
n=
n=22,e=0

我的代码中用的是如下方式来截取的:
  1. (set /a index=m*2-2)& for %%i in (!index!) do set dmax=!days:~%%i,2!
复制代码
作者: hanyeguxing    时间: 2010-4-8 00:31

原帖由 neorobin 于 2010-4-8 00:17 发表
实质是变量延迟的问题, 调试代码echo off&setlocal enabledelayedexpansion
set/p a=起始日期，格式20071221：
set/p b=终止日期，格式20080310：
set m=寒夜312831303130313130313031孤星
if "%a:~4,1%"=="0" ...

谢谢，第一次是分两行写的，结果后来贪图美观就给和并到一行了，忘记了延迟的问题。。。
作者: neorobin    时间: 2010-4-8 03:15

以下代码同样用 100 年的日期测试, 用时与 7 楼 FOR 的代码极为接近
对输入的日期前后无限制, 可自动将在前的日期作为起始日期
其中 如: if "!_y!!_m!%%d" gtr "!ymde!" (goto :break) 这样的判断语句还可省去, 进一步提高效率, 但未有简洁方案, 太显繁长
  1. @echo off&setlocal enabledelayedexpansion

  2. set /p ymds=请输入起始日期(yyyymmdd),要使用系统当前日期,请直接回车:

  3. set /p ymde=请输入截止日期(yyyymmdd),要使用系统当前日期,请直接回车:

  4. (set t=%time%)&(cd.>outFile.txt)

  5. for /l %%m in (1,1,12) do (set days_%%m=31)

  6. for %%m in (4,6,9,11) do (set days_%%m=30)

  7. if not defined ymds (set ymds=%date:~0,4%%date:~5,2%%date:~8,2%)

  8. if not defined ymde (set ymde=%date:~0,4%%date:~5,2%%date:~8,2%)

  9. if "!ymde!" lss "!ymds!" (set tt=!ymde!)&(set ymde=!ymds!)&(set ymds=!tt!)

  10. echo 起始日期为:!ymds!, 截止日期为:!ymde!

  11. (set /a ys=1!ymds:~0,4!-10000, ye=1!ymde:~0,4!-10000)

  12. (set /a ms=1!ymds:~4,2!-100, me=1!ymde:~4,2!-100)

  13. (set /a ds=1!ymds:~6,2!-100, de=1!ymde:~6,2!-100)

  14. set /a "y_1=ys+1,m_1=ms+1,d_1=ds+1"

  15. for /l %%y in (!ys!,1,!ys!) do (

  16.   (set _y=000%%y)&(set _y=!_y:~-4!)

  17.   for /l %%m in (!ms!,1,!ms!) do (

  18.     (set _m=0%%m)&(set _m=!_m:~-2!)

  19.     if %%m==2 set /a "days_2=28+(^!(%%y%%4)&^!^!(%%y%%100))|^!(%%y%%400)"

  20.     for /l %%d in (!ds!,1,9) do (

  21.       if "!_y!!_m!0%%d" gtr "!ymde!" (goto :break) else echo !_y!!_m!0%%d

  22.     )

  23.     if !ds! geq 10 (set d_2=!ds!) else set d_2=10

  24.     for /l %%d in (!d_2!,1,!days_%%m!) do (

  25.       if "!_y!!_m!%%d" gtr "!ymde!" (goto :break) else echo !_y!!_m!%%d

  26.     )

  27.   )

  28.   for /l %%m in (!m_1!,1,12) do (

  29.     (set _m=0%%m)&(set _m=!_m:~-2!)

  30.     if %%m==2 set /a "days_2=28+(^!(%%y%%4)&^!^!(%%y%%100))|^!(%%y%%400)"

  31.     for /l %%d in (1,1,9) do (

  32.       if "!_y!!_m!0%%d" gtr "!ymde!" (goto :break) else echo !_y!!_m!0%%d

  33.     )

  34.     for /l %%d in (10,1,!days_%%m!) do (

  35.       if "!_y!!_m!%%d" gtr "!ymde!" (goto :break) else echo !_y!!_m!%%d

  36.     )

  37.   )

  38. )>>outFile.txt

  39. for /l %%y in (!y_1!,1,!ye!) do (

  40.   (set _y=000%%y)&(set _y=!_y:~-4!)

  41.   for /l %%m in (1,1,12) do (

  42.     (set _m=0%%m)&(set _m=!_m:~-2!)

  43.     if %%m==2 set /a "days_2=28+(^!(%%y%%4)&^!^!(%%y%%100))|^!(%%y%%400)"

  44.     for /l %%d in (1,1,9) do (

  45.       if "!_y!!_m!0%%d" gtr "!ymde!" (goto :break) else echo !_y!!_m!0%%d

  46.     )  

  47.     for /l %%d in (10,1,!days_%%m!) do (

  48.       if "!_y!!_m!%%d" gtr "!ymde!" (goto :break) else echo !_y!!_m!%%d

  49.     )

  50.   )

  51. )>>outFile.txt

  52. :break

  53. echo 用时: !t! ==^> %time%

  54. start outFile.txt

  55. pause

  56. exit /b
复制代码

[ 本帖最后由 neorobin 于 2010-4-8 03:46 编辑 ]
作者: terse    时间: 2010-4-8 04:10

参照日期算法 应该可行 效率没测试
作者: FOR    时间: 2010-4-8 13:52

提速，100 个日期 只需 1.81 秒
  1. @echo off&setlocal enabledelayedexpansion

  2. set t=%time%

  3. echo 请输入8位数的起始日期和结束日期用空格分开

  4. echo 或只输入结束（开始）日期，默认当前日期为起始（结束）日期

  5. echo 输入格式 20080205 21080529&echo.

  6. set xx=19100201

  7. for /f "tokens=1,2" %%i in ("%xx%") do (

  8.    if not "%%j"=="" (set qs=%%i&set js=%%j) else (

  9.       for /f "tokens=1-3 delims=.\-/ " %%a in ("!date!") do (

  10.          if %%a%%b%%c gtr %%i (set/a qs=xx,js=%%a%%b%%c) else (

  11.             set/a qs=%%a%%b%%c,js=%%i

  12. ))))

  13. for %%a in (31 28 31 30 31 30 31 31 30 31 30 31) do set/a n+=1&set/a yue!n!=%%a

  14. set /a qsd=100%qs:~4,2%%%100,qsm=100%qs:~6,2%%%100

  15. set /a yuq=qsd,yuh=12,mq=qsm,mh=yue!qsd!

  16. echo 起始日期 %qs:~0,4%-%qs:~4,2%-%qs:~6,2%

  17. echo 结束日期 %js:~0,4%-%js:~4,2%-%js:~6,2%

  18. for /l %%i in (1 1 31) do set .%%i=0%%i&set ".%%i=!.%%i:~-2!"

  19. (

  20. for /l %%i in (%qs:~0,4% 1 %js:~0,4%) do (

  21.     set /a yue2="^!(%%i%%4)&^!(^!(%%i%%100))|^!(%%i%%400)"+28

  22.     if %%i equ %js:~0,4% set /a yuh=100%js:~4,2%%%100&set flag=a

  23.     for /l %%j in (!yuq! 1 !yuh!) do (

  24.        set /a mh=yue%%j

  25.        if defined flag if %%j equ !yuh! set /a mh=100!js:~-2!%%100

  26.        for /l %%k in (!mq! 1 !mh!) do echo %%i!.%%j!!.%%k!

  27.        set /a mq=1&echo;

  28.      )

  29.      set yuq=1

  30. )

  31. )>c.txt

  32. pause
复制代码
作者: hanyeguxing    时间: 2010-4-8 13:55

看楼上各位把for /l用到这境界，羡一个。。。
作者: terse    时间: 2010-4-8 14:30

发现已经迟到一步
  1. @echo off&setlocal enabledelayedexpansion

  2. set "YmdP=19080521"

  3. set "YmdT=20110902"

  4. if "%YmdP%" gtr "%YmdT%" set/a "YmdP=YmdT,YmdT=%YmdP%"

  5. set /a "p1=%YmdP:~,4%,p2=1%YmdP:~4,2%%%100,p3=1%YmdP:~6,2%%%100,T1=%YmdT:~,4%,T2=1%YmdT:~4,2%%%100,T3=1%YmdT:~6,2%%%100"

  6. for /l %%i in (%p1% 1 %t1%) do set /a "i%%i=1,j%%i=12"

  7. set /a "i%p1%=p2,j%t1%=t2"

  8. for %%i in (31 28 31 30 31 30 31 31 30 31 30 31) do set /a n+=1&set "_n!n!=%%i"

  9. for /l %%i in (%p1% 1 %t1%) do (

  10. set /a "_n2=^!(%%i%%4)&^!(^!(%%i%%100))|^!(%%i%%400)+28"

  11.     for /l %%j in (!i%%i! 1 !j%%i!) do (

  12.        set i=1

  13.        if "%%i%%j" equ "!p1!!p2!" set /a "i=p3"

  14.        if "%%i%%j" equ "!t1!!t2!" set /a "_n%%j=t3"

  15.        set "m=0%%j"

  16.        for /l %%k in (!i! 1 !_n%%j!) do (

  17.        set "d=0%%k"

  18.        echo;%%i!m:~-2!!d:~-2!

  19. )))

  20. pause
复制代码
作者: FOR    时间: 2010-4-8 15:04

继续提速，减少for循环内代码运行的次数，效率略有提高，测试100个日期耗时1.66秒左右

  1. @echo off&setlocal enabledelayedexpansion

  2. set t=%time%

  3. echo 请输入8位数的起始日期和结束日期用空格分开

  4. echo 或只输入结束（开始）日期，默认当前日期为起始（结束）日期

  5. echo 输入格式 20080205 21080529&echo.

  6. set xx=19100201

  7. for /f "tokens=1,2" %%i in ("%xx%") do (

  8.    if not "%%j"=="" (set qs=%%i&set js=%%j) else (

  9.       for /f "tokens=1-3 delims=.\-/ " %%a in ("!date!") do (

  10.          if %%a%%b%%c gtr %%i (set/a qs=xx,js=%%a%%b%%c) else (

  11.             set/a qs=%%a%%b%%c,js=%%i

  12. ))))

  13. for %%a in (31 28 31 30 31 30 31 31 30 31 30 31) do set/a n+=1&set/a yue!n!=%%a

  14. set /a qsd=100%qs:~4,2%%%100,qsm=100%qs:~6,2%%%100

  15. set /a yuq=qsd,yuh=12,mq=qsm,mh=yue!qsd!

  16. for /l %%i in (1 1 31) do set .%%i=0%%i&set ".%%i=!.%%i:~-2!"

  17. set /a a=100!js:~4,2!%%100,b=100!js:~-2!%%100

  18. set #2010!a!=!js:~0,4!&set yue!js:~0,4!!a!=!b!

  19. set _!js:~0,4!=!a!&set yuh!a!=!a!

  20. echo 起始日期 %qs:~0,4%-%qs:~4,2%-%qs:~6,2%

  21. echo 结束日期 %js:~0,4%-%js:~4,2%-%js:~6,2%

  22. (for /l %%i in (%qs:~0,4% 1 %js:~0,4%) do (

  23.     set /a yue2="^!(%%i%%4)&^!(^!(%%i%%100))|^!(%%i%%400)"+28,yuh=yuh!_%%i!

  24.     for /l %%j in (!yuq! 1 !yuh!) do (

  25.        set /a mh=yue!#%%i%%j!%%j

  26.        for /l %%k in (!mq! 1 !mh!) do echo %%i!.%%j!!.%%k!

  27.        set mq=1

  28.      )

  29.      set yuq=1

  30. ))>c.txt

  31. pause
复制代码

[ 本帖最后由 FOR 于 2010-4-8 15:06 编辑 ]
作者: neorobin    时间: 2010-4-9 01:18

借鉴各位的技巧和思路,特别是 FOR 的, 再发一个:
  1. @echo off&setlocal enabledelayedexpansion

  2. set /p ymds=请输入起始日期(yyyymmdd),要使用系统当前日期,请直接回车:

  3. set /p ymde=请输入截止日期(yyyymmdd),要使用系统当前日期,请直接回车:

  4. if not defined ymds (set ymds=%date:~0,4%%date:~5,2%%date:~8,2%)

  5. if not defined ymde (set ymde=%date:~0,4%%date:~5,2%%date:~8,2%)

  6. if "!ymde!" lss "!ymds!" (set tt=!ymde!&set ymde=!ymds!&set ymds=!tt!)

  7. echo 起始日期为:!ymds!, 截止日期为:!ymde!

  8. set /p=%time% ==^><nul

  9. for /l %%i in (0 1 31) do set _%%i=0%%i&set "_%%i=!_%%i:~-2!"

  10. (for /l %%m in (1,1,12) do set SD_%%m=31)&for %%m in (4,6,9,11) do set SD_%%m=30

  11. 

  12. set /a ys=1!ymds:~0,4!-10000, ye=1!ymde:~0,4!-10000

  13. set /a ms=1!ymds:~4,2!-100, me=1!ymde:~4,2!-100

  14. set /a ds_diff=1!ymds:~6,2!-101, dEnd=1!ymde:~6,2!-100

  15. 

  16. (for /l %%y in (%ymds:~0,4% 1 %ymde:~0,4%) do (

  17.   set /a "SD_2=28+(^!(%%y%%4)&^!^!(%%y%%100))|^!(%%y%%400)"

  18.   if %%y gtr !ys! (set ms=1)

  19.   if %%y lss !ye! (

  20.     for /l %%m in (!ms!,1,12) do (

  21.       set /a "ds=1+(^!(%%y^^ys)&^!(%%m^^ms))*ds_diff"

  22.       for /l %%d in (!ds!,1,!SD_%%m!) do echo %%y!_%%m!!_%%d!

  23.     )

  24.   ) else for /l %%m in (!ms!,1,!me!) do (

  25.       set /a "ds=1+(^!(%%y^^ys)&^!(%%m^^ms))*ds_diff"

  26.       if %%m geq !me! (set de=!dEnd!) else (set de=!SD_%%m!)

  27.       for /l %%d in (!ds!,1,!de!) do echo %%y!_%%m!!_%%d!

  28.   )

  29. ))>out.txt

  30. echo %time%&start out.txt&pause
复制代码




欢迎光临 批处理之家 (http://bbs.bathome.net/) Powered by Discuz! 7.2