buyiyang

才5个字符，用批处理的话逐字符判断更可靠一些

@echo off
set/p "data=Please enter a date (MM/DD):"
set "error=echo,Invalid date&pause&goto :eof"
setlocal enabledelayedexpansion
for /l %%i in (5,-1,0) do (
    set "data%%i=!data:~%%i,1!"
    if not "!data%%i!"=="" (
        if %%i equ 5 (
            %error%
        ) else if %%i equ 2 (
            if "!data%%i!" neq "/" %error%
        ) else if "!data%%i!" lss "0" (
            %error%
        ) else if "!data%%i!" gtr "9" %error%
    ) else (
        if %%i equ 4 %error%
    )
)
if %data0% equ 0 set "data0="
if %data3% equ 0 set "data3="
set mm=%data0%%data1%
set dd=%data3%%data4%
if %mm% gtr 12 %error%
if %dd% gtr 31 %error%
for /f "tokens=2" %%i in ('wmic os get codeset^,localdatetime') do (
    set yyyy=%%i
    set "yyyy=!yyyy:~0,4!"
    )
endlocal&set /a mm=%mm%,dd=%dd%,yyyy=%yyyy%
set /a "gtm=!(mm-4)|!(mm-6)|!(mm-9)|!(mm-11)","leap=!(yyyy%%4)&!!(yyyy%%100)|!(yyyy%%400)","dlim=!(mm-2)*(28+leap)+gtm*30+(!!(mm-2)&!gtm)*31"
if %dd% gtr %dlim% (%error%) else (echo,Valid date)
pause&exit /b
复制代码

buyiyang

回复 27# aloha20200628


    因为09不是有效的八进制数字，试试0x9

buyiyang

回复 37# 77七


    感谢测试，限制上限的时候忘记限制下限了，再补上 set /a "1/(!!mm&!!dd)" 2>nul ||(%error%) 就没有问题了。

buyiyang

回复 45# aloha20200628
1//1a
1/--1
1/+1
一个是分隔符被忽略的问题，一个是if比较时不能转换成有效数字的会按字符比较，数字比较时没有排除正负号。
忘了还有变量延迟下的两个特殊字符，
1/!1
1/!^1

buyiyang

回复 45# aloha20200628

endlcoal 后第二行设定的变量也无了，
第14行的if %m% lss 1 if %m% gtr 12 逻辑有误，其实这一行不要也行，第17行if %d% gtr 0 if %d% leq !%_m%! 兼有限制月份的作用。

buyiyang

综合一下35、45、48、55楼，有一些不错的写法
最终主体只需要9、11、12行三句判断就够了。
第9行限制输入字符数和分隔符位置，
第11行限制月份和日期均为数字，
第12行限制月份和日期范围。

@echo off
for /f "tokens=2" %%i in ('wmic os get codeset^,localdatetime') do set yyyy=%%i&call set yyyy=%%yyyy:~0,4%%
set /a _01=_03=_05=_07=_08=_10=_12=31,_04=_06=_09=_11=30,"_02=28+(!(yyyy%%4)&!!(yyyy%%100)|!(yyyy%%400))"
set "error=echo,Invalid date&endlocal&goto :loop"

:loop
set /p "md=Please enter a date (MM/DD):"
setlocal enabledelayedexpansion
if "!md:~2,-2!" neq "/" (%error%)
set "mm=!md:~0,2!"&set "dd=!md:~3,2!"
for /f "delims=0123456789" %%i in ("!mm!!dd!") do (%error%)
if "!dd!" gtr "00" if "!dd!" leq "!_%mm%!" (echo,Valid date&endlocal&goto :loop)
%error%
复制代码

buyiyang

回复 55# qixiaobin0715


    我尝试写了一个

@echo off
for /f "tokens=2" %%i in ('wmic os get codeset^,localdatetime') do set yyyy=%%i&call set yyyy=%%yyyy:~0,4%%
set /a _01=_03=_05=_07=_08=_10=_12=31,_04=_06=_09=_11=30,"_02=28+(!(yyyy%%4)&!!(yyyy%%100)|!(yyyy%%400))"
set "error=echo,Invalid date&endlocal&goto :loop"

:loop
set /p "md=Please enter a date (M/D):"
setlocal enabledelayedexpansion
set "a=!md:*/=!"&set "dd=!a:/=!"
if "!a!" neq "!dd!" (%error%)
for /f "delims=0123456789" %%i in ("!md:/=!") do (%error%)
for /f "tokens=1* delims=/" %%i in ("!md!") do (endlocal&set "mm=%%i"&set "dd=%%j")
setlocal enabledelayedexpansion
if "!dd!"=="" (%error%)
if "!mm:~2,1!" neq "" (%error%)
if "!dd:~2,1!" neq "" (%error%)
if "!mm:~0,1!" equ "0" if "!dd:~1,1!"=="" (%error%)
if "!dd:~0,1!" equ "0" if "!mm:~1,1!"=="" (%error%)
set "mm=0!mm!"&set "mm=!mm:~-2!"
set "dd=0!dd!"&set "dd=!dd:~-2!"
if "!dd!" gtr "00" if "!dd!" leq "!_%mm%!" (echo,Valid date&endlocal&goto :loop)
%error%
复制代码