sjzong

请问楼主：是产生一个四位数都不重复的数，还是产生四个四位数都不重复的数？？
思路：随机取出该数的千、百、十、个位的数字，然后判断该数是否跟前面取的数重复；还要判断是否已经取满四个数

@echo off
setlocal enabledelayedexpansion
set str=0123456789
:main
cls
set var=
:a
set s1=!str:0=!
set/a num=%random%%%9
set num1=!s1:~%num%,1!
set s2=!str:%num1%=!
set/a num=%random%%%9
set num2=!s2:~%num%,1!
set s3=!s2:%num2%=!
set/a num=%random%%%8
set num3=!s3:~%num%,1!
set s4=!s3:%num3%=!
set/a num=%random%%%7
set num4=!s4:~%num%,1!
set num=!num1!!num2!!num3!!num4!
set/a n=0
for %%a in (!var!) do (
set/a n+=1
if %%a equ !num! goto :a
)
if !n!==4 (echo !var!&pause>nul&goto main) else (set var=!var! !num!&goto :a)COPY

[ 本帖最后由 sjzong 于 2009-4-25 15:55 编辑 ]

sjzong

15楼的思路的确很有新意！
但是我有两个疑问：
1、如果题目假设成求出全部四位不重复的四位数时，那循环次数是非常多了，速度就慢多了，因为1000~9999就有9000个，然后每一个再来删除重复字符（0~9共10），那就要运行9000*10次数！
       换成另一种思路：先取千位（千位为10个数字扣除0，共9个），再取百位（百位为10个数字扣除千位的数字，共9个），再取十位（十位为10个数字扣除千位、百位两个，共8个），最后取个位（个位为10个数字扣除千位、百位、十位三个，共7个），利用排列组合，列出所有的数需要运行9*9*8*7=4536次。
       那两种思路的效率高呢？？？ 希望楼主按你的思路写出可以列出四位不重复的四位数代码，然后跟下面代码对比一下，看看速度怎么样？

@echo off
setlocal enabledelayedexpansion
set str=0 1 2 3 4 5 6 7 8 9
set s1=!str:0=!
for %%a in (!s1!) do (
set s2=!str:%%a=!
for %%b in (!s2!) do (
set s3=!s2:%%b=!
for %%c in (!s3!) do (
set s4=!s3:%%c=!
for %%d in (!s4!) do (
set/a num+=1
echo %%a%%b%%c%%d
))))
echo !num!
pauseCOPY

2、题目所提出的数字要求是随机数，按照15楼的方法时就难免会出现重复的数，就是第一次取随机数1234，有可能也取1234，虽然这种概率很小的！但毕竟存在。