ppll2030

VBA不熟。就不搀和了。习惯了用批处理，看看合不合用吧。
注意：
代码一定一定要保存为UTF-8格式的bat文件。
bat文件跟pdftk.exe文件放一块。
书签明细可在脚本后修改。
PDF文件支持拖放，也可打开后手动输入。

@echo off
setlocal enabledelayedexpansion
rem 注意：：一定要保存为UTF-8格式的bat文件
chcp 65001 >nul
:start
set f=%1
if not defined f echo. &set /p f=输入要添加书签的PDF文件：
if not defined f echo.&pause&cls&goto :start
for %%i in ("%f%") do set _nf=%%~ni&set _xf=%%~xi
set /a n=1
rem skip数值以 "以下为书签名单" 所在行为准
(for /f "skip=24 tokens=* delims=" %%a in ('type "%~f0"') do (
        set str=%%a
        echo BookmarkBegin
        echo BookmarkTitle: !str!
        echo BookmarkLevel: 1
        echo BookmarkPageNumber: !n!
        set /a n+=1
))>bookmark.txt
pdftk "%f%" update_info_utf8 bookmark.txt output "%_nf%_bookmark%_xf%"
del /q bookmark.txt
pause&exit

以下为书签名单：
红旗小学1
红旗小学2
红旗小学3
红旗小学4
红旗小学5
红旗小学6
红旗小学7
红旗小学8
红旗小学9
红旗小学10
红旗小学11
红旗小学12
红旗小学13
红旗小学14
红旗小学15
红旗小学16
红旗小学17
红旗小学18
红旗小学19
红旗小学20
红旗小学21
红旗小学22
红旗小学23
红旗小学24
红旗小学25
红旗小学26
红旗小学27
红旗小学28
红旗小学29
红旗小学30
复制代码

ppll2030

回复 3# qd2024


    把12行的内容改一下就可以了。
自己新建一个标签.txt，一行开始直接放标签明细即可。

(for /f "delims=" %%a in ('type "标签.txt"') do (
复制代码

ppll2030

回复 5# qd2024


    你把标签.txt也要保存为UTF-8的格式就可以了。

ppll2030

回复 5# qd2024


    再次修改了一下脚本，这样你就不需要把PDF文件跟脚本放一块了。这样应该更方便一些。
注意：
代码一定要保存为UTF-8编码格式的bat文件，跟pdftk放置一块
标签.txt一定一定要保存为UTF-8编码格式的txt文件
标签.txt和PDF放在一起即可，不需要把他俩复制粘到pdftk的同一个文件夹内。
直接拖拽PDF到bat上面即可，也可先打开bat，再拖拽过去，或复制PDF完整路径进来。

@echo off
setlocal enabledelayedexpansion
rem 注意：：一定要保存为UTF-8格式的bat文件
chcp 65001 >nul
:start
set f=%1
if not defined f echo. &set /p f=输入要添加书签的PDF文件：
if not defined f echo.&pause&cls&goto :start
for /f "delims=" %%i in ("%f%") do set _nf=%%~dpni&set _xf=%%~xi&set _pf=%%~dpi
set /a n=1
rem 标签.txt一定一定要保存为UTF-8编码格式的txt文件
(for /f "delims=" %%a in ('type "!_pf!标签.txt"') do (
        set str=%%a
        echo BookmarkBegin
        echo BookmarkTitle: !str!
        echo BookmarkLevel: 1
        echo BookmarkPageNumber: !n!
        set /a n+=1
))>!_pf!bookmark.txt
%~dp0pdftk "!f!" update_info_utf8 "!_pf!bookmark.txt" output "!_nf!_bookmark!_xf!"
del /q !_pf!bookmark.txt
echo.&echo.书签添加完毕！&timeout /t 3 &exit
复制代码

ppll2030

回复 11# qd2024


    直接改动源文件比较危险哦。切记做好备份
关于桌面失败，可能是路径带空格的问题，现已修复，你可以再试试。
在代码第20行后面添加了两行，直接改动源文件，默认无备份，需要备份就去掉21行的两个::冒号。

@echo off
setlocal enabledelayedexpansion
rem 注意：：一定要保存为UTF-8格式的bat文件
chcp 65001 >nul
:start
set f=%1
if not defined f echo. &set /p f=输入要添加书签的PDF文件：
if not defined f echo.&pause&cls&goto :start
for /f "delims=" %%i in ("%f%") do set _nf=%%~ni&set _xf=%%~xi&set _pf=%%~dpi
set /a n=1
(for /f "delims=" %%a in ('type "!_pf!标签.txt"') do (
        set str=%%a
        echo BookmarkBegin
        echo BookmarkTitle: !str!
        echo BookmarkLevel: 1
        echo BookmarkPageNumber: !n!
        set /a n+=1
))>bookmark.txt
"%~dp0pdftk" !f! update_info_utf8 "!_pf!bookmark.txt" output "!_pf!!_nf!_bookmark!_xf!"
rem 备份源文件，需要去掉前面两个 :: 冒号
::ren "!f!" "!_nf!_bak!_xf!"
move /y "!_nf!_bookmark!_xf!" !f! >nul
del /q "!_pf!bookmark.txt"
echo.&echo.书签添加完毕！&timeout /t 3&exit
复制代码

ppll2030

回复 16# qd2024


经过77大佬的提醒和指导，目前拖拽和粘贴复制的方式都没有问题了。

@echo off
setlocal enabledelayedexpansion
rem 注意：：一定要保存为UTF-8格式的bat文件
chcp 65001 >nul
:start
set f=%1
if not defined f echo. &set /p f=添加PDF文件（拖拽文件或者填写文件的完整路径）：
if not defined f echo.&pause&cls&goto :start
set f=%f:"=%
for /f "delims=" %%i in ("%f%") do set _nf=%%~ni&set _xf=%%~xi&set _pf=%%~dpi
set /a n=1
cd /d %_pf%
(for /f "delims=" %%a in ('type "标签.txt"') do (
        set str=%%a
        echo BookmarkBegin
        echo BookmarkTitle: !str!
        echo BookmarkLevel: 1
        echo BookmarkPageNumber: !n!
        set /a n+=1
))>bookmark.txt 
"%~dp0pdftk" "!f!" update_info_utf8 bookmark.txt output "!_nf!_bookmark!_xf!"
rem 备份源文件，需要去掉前面两个 :: 冒号
::ren "!f!" "!_nf!_bak!_xf!"
move /y "!_nf!_bookmark!_xf!" "!f!" >nul
del /q bookmark.txt
echo.&echo.书签添加完毕！&timeout /t 3&exit
复制代码

ppll2030

回复  ppll2030


   6、7行的两种方式，%1会改变工作路径，而set /p却不会，%1含有空格加引号，而set  ...
77七 发表于 2024-7-8 15:13

    唉，学艺不精，这也是改了又改的原因了。一会儿拖拽成功，但粘贴路径有莫名bug
%1是为了拖拽功能，set /p 是为了粘贴复制，
我周围的人习惯不同，为了方便就都统一这么写了。
上面我也只是测试了拖拽的功能对空格文件名和路径没问题。回头再看看粘贴复制的情况吧。
至于%~dp0pdftk，也是无奈之举，不是同一目录的pdf文件，会提示：
'pdftk' is not recognized as an internal or external command,
operable program or batch file.
The system cannot find the file specified.
这也是之前我补齐所有文件的完整路径的原因。越搞越麻烦。哈哈
最后，感谢大佬的指点。让我对%1和set /p又有了一些新的认知。

ppll2030

回复 21# aloha20200628


    哈哈，老大的代码看不懂。就直接代楼主上自己的测试结果吧
1、脚本bat和标签.txt必须是ANSI，任意一个是utf-8结果就会乱码。都是ANSI下，结果正确。
2、多个pdf只会操作一个。