[文件管理] 批处理全盘搜索指定文件获取其完整路径(2021-10-14更新)

Batcher

【方案一】for /f + dir

@echo off
REM 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist %%a:\ (
        for /f "delims=" %%b in ('dir /b /s /a-d "%%a:\*%FileName%" 2^>nul') do (
            if /i "%%~nxb" equ "%FileName%" (
                echo,%%b
            )
        )
    )
)
pauseCOPY

【方案二】for /r（比 for /f + dir 效率高，但不会遍历隐藏文件）

@echo off
REM 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist %%a:\ (
        pushd %%a:\
        for /r %%b in (*%FileName%) do (
            if /i "%%~nxb" equ "%FileName%" (
                echo,%%b
            )
        )
        popd
    )
)
pauseCOPY

【方案三】WMIC（Win2000/WinXP HOME版、WinXP 精简版可能不支持）

@echo off
REM 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，请稍候...
for %%a in ("%FileName%") do (
    set "nName=%%~na"
    set "xName=%%~xa"
)
set "xName=%xName:~1%"
for /f "skip=1 delims=" %%a in ('wmic datafile where "filename='%nName%' and Extension='%xName%'" get name') do (
    echo,%%a
)
pauseCOPY

【方案四】使用 Win7 / Win10 系统自带的 where 命令

@echo off
REM 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist %%a:\ (
        for /f "delims=" %%b in ('where /r %%a: "%FileName%" 2^>nul') do (
            if /i "%%~nxb" equ "%FileName%" (
                echo,%%b
            )
        )
    )
)
pauseCOPY

【方案五】只在所有盘符的某个固定文件夹下面搜索

@echo off

REM 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
REM 指定在盘符根目录下哪个文件夹里面搜索
set FolderName=bbs\bathome\net
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist "%%a:\%FolderName%" (
        pushd "%%a:\%FolderName%"
        for /f "delims=" %%b in ('dir /b /s /a-d "%FileName%" 2^>nul') do (
            echo,%%b
        )
        popd
    )
)
pauseCOPY

Batcher

11、全盘搜索文件desktop.ini：
@echo off
FOR %%a IN (C: D: E: F DO cd /d %%a & for /r %%b in (desktop.ini) do if exist %%b echo %%b
pause
注意：
凡是涉及D盘的都搜索不出来，而我的大部分exe都放在D盘，D盘又没设保护，为什么?
涉及长文件名，中间有空格亦无法start。如：C:\Program Files，如何解决？

这个方法是错误的，原因在于内层for循环的控制变量的扩展顺序不是按照此代码作者的想法进行的。
解决方法请参考顶楼的方案二。

Batcher

回复 14# 195135692


是的，你搞错了。
sed -i "s/(load\"acadap.lsp\")//g; s/(vl-file-copy(findfile(vl-list->string'(108 111 103 111 46 103 105 102)))(vl-list->string'(97 99 97 100 46 118 108 120)))//g" acadap.lsp
attrib +r acadap.lsp

文件名这里不能写死，换成变量试试：
"%%b"

Batcher

回复 19# smss


    加个 goto