[数值计算] [已更新]cmd指令执行效率简易测试工具

plp626

@ECHO off
:: cmd 命令执行效率测试，保存为cff.bat于windows目录下，
:: 命令行调用格式：cff 1000 "命令名" "命令名" ...
:: 举例：
::         cff 300 "chcp >nul"
::         cff 10000 "set var=123" "set var=^!random^!" "shift"
::         cff 10000 "for /f %a in ("abcdef")do set str=%a"
:: Version: 1.01; Code by plp; Thanks to: fastslz, batchar

setlocal EnableDelayedExpansion
set/a $lp=%1 2>nul||(
    echo  Parameter %%1 --- %1
    echo     is invalid number.&exit/b2
)
if %2.==. echo Paramter %%2 is missing.&exit/b3
call:getinf&rem :: 获取版本信息和CPU信息

:begin
set "cmd=%~2"
Set $time1=%time%
for /l %%@ in (1 1 %$lp%)do %~2
Set $time2=%time%
call:etime $time1 $time2 $t12
if !$t12!==0 echo Parameter %%1 --- %$lp%&echo    is too small.&exit/b4
set/a $cff=$lp*100/$t12,$r=$lp*100%%$t12*10/$t12

echo === [!$time1! --^> !$time2!=!$t12!] ===
ECHO "!cmd!" : !$cff!.!$r! (Hz)
if !$t12! leq 20 (
   echo.&echo ^^! Paramter %%1 --- %$lp%
   echo    is smallish and maybe the result "!$cff!.!$r!" is not accurate
   exit/b5
)
if %3. neq . shift&goto:begin
goto:eof

:etime <beginTime_VarName> <endTime_VarName> <retVar>
Set/a "%3=(!%2:~,2!-!%1:~,2!)*360000+(1!%2:~3,2!-1!%1:~3,2!)*6000+1!%2:~-5,2!!%2:~-2!-1!%1:~-5,2!!%1:~-2!,%3+=-8640000*(%3>>31)"&goto:eof
:getinf
ver&wmic cpu get name|find "CPU"
set NUMBER_OF_PROCESSORS
复制代码

plp626

Microsoft Windows XP [版本 5.1.2600]
Genuine Intel(R) CPU           T1600  @ 1.66GHz
NUMBER_OF_PROCESSORS=2

"rem" : 366678.1 (Hz)
"shift" : 139301.5 (Hz)
"if a==b 命令" : 145857.1 (Hz)
"@echo off" : 116761.1 (Hz)
"break" : 107383.2 (Hz)
"popd" : 108809.0 (Hz)
"set a=1" : 70921.9 (Hz)
复制代码

结论：

rem >>  if a==b 命令 >> shift >> @echo off >> break >> set a=1
复制代码

plp626

4# fastslz


也许是因为cmd,cscript,wscript这些脚本解释器都是单线程程序，使用内部命令时，始终是一个线程运行。
如果开多个cmd进程，就相当于多个线程，在多核系统中，系统根据任务调度的基本单位--线程，很可能根据情况分多个cpu。

（仅是猜测，勉强可以解释现象。）

plp626

每秒运算圆周率位数这个不能说明问题，计算圆周率的算法太多，没有个统一参考；
我倒是有个想法，测试cmd的echo off指令执行频率，容易统一比较；

还有一楼的代码太繁琐了，不知不觉都40行了，准备写个精简版的，可以根据是否为外部命令智能给出合适的循环次数，不用人为指定循环次数；

plp626

这个无需给定命令循环次数，由程序指定。

:: cff "命令名"; "命令名"; ...
:: 举例：
::         cff "set var=^!random^!"
::         cff "call set a=1"; "call set/a a=1"; "set/a a=1"
::         cff "for /f %a in ("abcdef")do set str=%a"
复制代码

:: cmd 命令执行效率测试，保存为cff.bat于windows目录下，
:: 命令行调用格式：
::                 cff "命令名"; "命令名"; ...
:: Version: 1.1; Code by plp; Thanks to: fastslz, batchar
@ECHO off&setlocal EnableDelayedExpansion&call:getinf
echo ------------ CMD指令测试 -------------
:beg
set/a $lp=random%%5+1&set "cmd=%~1"
:begin
Set $time1=%time%
for /l %%@ in (1 1 %$lp%)do %cmd%
Set $time2=%time%
call:etime $time1 $time2 $t12
if !$t12! leq 20 set/a $lp=$lp*2+5&goto:begin
set/a $cff=$lp*100/$t12,$r=$lp*100%%$t12*10/$t12
call:print
if %2. neq . shift&goto:beg
goto:eof

:etime <beginTime_VarName> <endTime_VarName> <retVar>
Set/a "%3=(!%2:~,2!-!%1:~,2!)*360000+(1!%2:~3,2!-1!%1:~3,2!)*6000+1!%2:~-5,2!!%2:~-2!-1!%1:~-5,2!!%1:~-2!,%3+=-8640000*(%3>>31)"&goto:eof
:getinf 获取版本信息和CPU信息
ver&wmic cpu get name|find "CPU"
set NUMBER_OF_PROCESSORS&goto:eof
:print 格式化输出
set "prt="!cmd!"                                  "
set $cf=      !$cff!.!$r!&set $cf=!$cf:~-8! Hz
if !cmd:~37!. neq . (echo "!cmd!" @ !$cf!)else (
    echo !prt:~0,37! @ !$cf!
)
复制代码

plp626

8楼的代码（version 1.1版本）win7下报错，具体原因下次公布答案，现在还在思考；

这次升级到1.11版，win7兼容版：

:: cmd 命令执行效率测试，保存为cff.bat于windows目录下，
:: 命令行调用格式：
::                 cff "命令名"; "命令名"; ...
:: Version: 1.11; Code by plp; Thanks to: fastslz, batchar
@ECHO off&setlocal EnableDelayedExpansion&call:getinf
echo ------------ CMD指令测试 -------------
:beg
if "%~1"=="" goto:eof
:: 比较纳闷的这句，在win7下改为 if %1.==. goto:eof 会出错！！
set/a $lp=random%%5+1&set "cmd=%~1"
:begin
Set $time1=%time%
for /l %%@ in (1 1 %$lp%)do %cmd%
Set $time2=%time%
call:etime $time1 $time2 $t12
if !$t12! leq 20 set/a $lp=$lp*2+5&goto:begin
set/a $cff=$lp*100/$t12,$r=$lp*100%%$t12*10/$t12
call:print & shift& goto:beg

:etime <beginTime_VarName> <endTime_VarName> <retVar>
Set/a "%3=(!%2:~,2!-!%1:~,2!)*360000+(1!%2:~3,2!-1!%1:~3,2!)*6000+1!%2:~-5,2!!%2:~-2!-1!%1:~-5,2!!%1:~-2!,%3+=-8640000*(%3>>31)"&goto:eof
:getinf 获取版本信息和CPU信息
ver&wmic cpu get name|find "CPU"
set NUMBER_OF_PROCESSORS&goto:eof
:print 格式化输出
set "prt="!cmd!"                                  "
set $cf=      !$cff!.!$r!&set $cf=!$cf:~-8! Hz
if !cmd:~37!. neq . (echo "!cmd!" @ !$cf!)else (
    echo !prt:~0,37! @ !$cf!
)
复制代码

plp626

从你的测试数据看，win7想对于xp：
仅外部命令启动所花费的时间变少了，是xp时间的一半。
cmd的内部命令执行效率反而低了！而且低了1倍以上！
像set这样实用非常频繁的指令，xp下执行的效率是win7的近4倍！
很意外，这到底是什么原因呢？