applba

@echo off
pushd "%~dp0"
rem下面两句指定要处理的文件，请根据需要自行修改！
set file1=wellhead_422.txt
set file2=wellhead_all.txt
for /f "tokens=1*" %%a  in (%file1%) do if not "%%a"=="" set %%a=1
(for /f "tokens=1*" %%A in (%file2%) do if defined %%A echo %%A	%%B) >"new_%file1%"
echo %file1%处理完成。
pause>nul
复制代码

请把所有相关文件移动到一个目录下！

由于论坛会转换代码中的TAB到空格，楼主可以直接下载附件。

applba

回复 9# hacker85

关键代码只有两句for而已；
我都已经为你做好修改工作了，你把  set file1= 修改为其他要处理文件即可。
你要处理的文件很多吗？

applba

@echo off
SETLOCAL EnablEdElayEdExpansion
pushd "%~dp0"
if exist wellhead_all.txt ren wellhead_all.txt wellhead_all.bak
for %%i in ( wellhead_*.txt ) do (
  set file1=%%~i
  echo %%~i 处理中…
  echo.
  for /f "tokens=1*" %%a  in (!file1!) do if not "%%a"=="" set %%a=1
 (for /f "tokens=1*" %%A in (wellhead_all.bak) do if defined %%A echo %%A	%%B) > new_%%~i
  echo %%~i 处理完成
  echo.
)
if exist wellhead_all.bak ren wellhead_all.bak wellhead_all.txt 
pause
复制代码

请自行替换  %%A        %%B之间的空格为TAB。

applba

回复 12# hacker85
1、1*表示，第一列内容返回给第一个For变量，后面所有的内容原封不动作为一列内容返回给第二个For变量。
2、设置为1是使其成为defined状态，只要不是空的，可以是其他任何值～
3、使用括号括起整个For语句，可以把它的全部输出一次性重定向到文件～

applba

@echo off
pushd "%~dp0"
if exist wellhead_all.txt ren wellhead_all.txt wellhead_all.bak
for %%i in ( wellhead_*.txt ) do (
  echo %%~i 处理中…
  echo.
  SetLocal
  for /f "tokens=1*" %%a  in (%%~i) do if not "%%a"=="" set %%a=1
 (for /f "tokens=1*" %%A in (wellhead_all.bak) do if defined %%A echo %%A        %%B) > new_%%~i
 ENDLOCAL
  echo %%~i 处理完成
  echo.
)
if exist wellhead_all.bak ren wellhead_all.bak wellhead_all.txt 
pause
复制代码

自行替换空格到TAB

applba

回复 18# hacker85


    不是变量延迟扩展的原因～
    这是变量作用范围和存活期的问题，在我的理解中是叫变量的局部化～