qixiaobin0715

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1-2*" %%i in (a.txt) do (
    set f1=%%i                    
    set f2=%%j                    
    echo,!f1:~,20!!f2:~,20!%%k
)
pause
复制代码

qixiaobin0715

回复 5# shenlong
没搞明白你所谓的“预期效果”是指什么？

qixiaobin0715

只能这样勉为其难了：

@echo off
setlocal enabledelayedexpansion
type a.txt>temp
echo,a>>temp
set /a n=0,y=0
for /f "delims=:" %%i in ('findstr /o .* temp') do (
    set /a x=%%i-y
    if !n! lss !x! set /a n=x
    set y=%%i
)
del temp
for /l %%i in (1,1,!n!) do set BS= !BS!
for /f "tokens=1-2*" %%i in (a.txt) do (
    set f1=%%i!BS!
    set f2=%%j!BS!
    echo,!f1:~,%n%!!f2:~,%n%!%%k
)
pause
复制代码

qixiaobin0715

这样可能要美观一些：

@echo off
for /f "tokens=1-3" %%i in (a.txt) do (
    echo,%%i>>temp1
    echo,%%j>>temp2
)
set /a n1=n2=0,y1=y2=0
setlocal enabledelayedexpansion
for %%a in (1 2) do (
    echo,a>>temp%%a
    for /f "delims=:" %%i in ('findstr /o .* temp%%a') do (
        set /a x%%a=%%i-y%%a
        if !n%%a! lss !x%%a! set /a n%%a=x%%a
        set y%%a=%%i
    )
    del temp%%a
    set /a n%%a+=4
for /l %%i in (1,1,!n%%a!) do set BS%%a= !BS%%a!
)
(for /f "tokens=1-2*" %%i in (a.txt) do (
    if "%%j"=="" (set f1=%%i) else (set f1=%%i!BS1!&set f1=!f1:~,%n1%!)
    if "%%k"=="" (set f2=%%j) else (set f2=%%j!BS2!&set f2=!f2:~,%n2%!)
    set f3=%%k
    echo,!f1!!f2!!f3!
))>b.txt
pause
复制代码

qixiaobin0715

回复 12# 娜美
只要计算出每列的最大字节数，以及各列字节数与最大字节数的差值，然后用空格补齐即可。
可能会稍微复杂些，抽空试试。

qixiaobin0715

回复 18# ppll2030
输出的txt文件你用“记事本”打开看看。
不同的文本编辑器，字符不同占用宽度可能会有区别。

qixiaobin0715

按照各列字节数与最大字节数的差值，然后用空格补齐的方法，适用含有中文字符的列：

@echo off
set colsn=4
set /a colsn-=1
for /f "tokens=1-%colsn%" %%1 in (a.txt) do (
    echo,%%1>>temp1
    echo,%%2>>temp2
    echo,%%3>>temp3
)
setlocal enabledelayedexpansion
for /l %%a in (1,1,%colsn%) do (
    echo,a>>temp%%a
    set /a x=n%%a=0
    for /f "tokens=1,2 delims=:" %%i in ('findstr /n /o .* temp%%a') do (
        set /a "x%%a=%%j-x"
        set /a "m=%%i-1"
        set "n%%a#!m!=!x%%a!"
        if !n%%a! lss !x%%a! set /a "n%%a=x%%a"
        set "x=%%j"
    )
    del temp%%a
)
for /f "tokens=1-%colsn%*" %%1 in (a.txt) do (
    set /a "n+=1"
    set f=
    set "f1=%%1"
    set "f2=%%2"
    set "f3=%%3"
    for /l %%x in (1,1,%colsn%) do (
        set /a "m%%x=n%%x-n%%x#!n!"
        for /l %%y in (1,1,!m%%x!) do set "f%%x=!f%%x! "
        set "f=!f!!f%%x!    "
    )
    echo,!f!%%4
)
pause
复制代码

由于未及仔细考虑，代码存在以下缺点：
1.代码过于复杂，可读性差；
2.除最后一列外，其余各行各列字节数均预先设置变量，处理较大文件时，速度可能会比较慢，甚至超出变量设置的上限而出错；
3.上面代码是按4列文本来处理的，如果列数有变化，需要对以上代码进行修改（虽然写代码时，考虑到了列数变化时，尽量减少修改量），通用性不是太好。

下面举例说明列数变化时，代码调整的方法：
1.如果文本内容的列数为3列，代码做如下调整：
第2行变量值修改为3；
删除第7行；
删除第27行；
将第33行的%%4改为%%3；
2.如果文本内容的列数为5列，代码做如下调整：
第2行变量值修改为5；
第7行下面增加一行：echo,%%4>>temp4
第27行下面增加一行：set "f4=%%4"
将第33行的%%4改为%%5；

qixiaobin0715

回复 47# ppll2030
感叹号的问题是变量延迟造成的，你可以试试如果感叹号成对出现，感叹号以及一对感叹号之间的字符都会“隐藏”。*的问题没有遇见过，还是留给大佬们来解释吧。

qixiaobin0715

回复 41# buyiyang
是的，相似的字符还有分号、跳格。

qixiaobin0715

自己又偷偷的写了一个代码，对for默认分隔符和通配符 *？以及延迟变量中的 ! 免疫，效率不行，没好意思发出来。

qixiaobin0715

回复 53# ppll2030
字符串分行显示时，不使用for %%a in (...) do...这样的循环结构，可以避免出现默认分隔符以及*?通配符的影响；
至于变量延迟中!会”隐藏“的问题有多种解决方法，其中一种方法可以参考http://www.bathome.net/thread-11193-1-1.html

qixiaobin0715

回复 59# ppll2030
1.排版美不美观个人看法不一，只要达到各列上下对齐的效果，调整列的宽度就是小kiss，增加或减少几个空格而已；
2.如果列数都懒得搞清楚，就太那个了吧。实际上要解决这个问题也不复杂，就是在原有代码外层加上goto循环，再if几下即可。个人感觉goto语句太过难看，很少使用此循环。

qixiaobin0715

嵌套变量延迟开关， 来消除文本中“!”的影响，弃用for %%i in (...) do...的方法，通吃文本中存在默认分隔符以及*?通配符等字符的影响，使用大多数人熟悉的cmd命令书写代码。感觉效率还可以：

@echo off
echo,>$1
:a
set Em=
set /a colsn+=1
if %colsn% equ 1 (
    (for /f "tokens=1" %%i in (a.txt) do (echo,%%i&set Em=1))>temp
) else (
    (for /f "tokens=1,%colsn%" %%i in (a.txt) do (echo,%%j&if not "%%j"=="" set Em=1))>temp
)
if not defined Em goto :b
echo,>>temp
findstr /n /o .* temp>$2
setlocal enabledelayedexpansion
    for /f "tokens=1,2 delims=:" %%i in ($2) do (
        set /a m=%%j-x
        set /a n=%%i-1
        set "a!n!=!m!"
        if !max! lss !m! set "max=!m!"
        set "x=%%j"
    )
set /a n+=1
    (for /f "delims=:" %%i in ('findstr /n .* temp') do (
        set str1=
        set str2=
        set /p str1=
        set /a z=max-a%%i
        for /l %%k in (1,1,!z!) do set str2=!str2! 
        if %%i neq !n! echo,!str1!!str2!
    ))<temp>$2
    (for /f "tokens=1* delims=:" %%i in ('findstr /n .* $2') do (
        endlocal
        set /p Line1=
        set Line2=%%j
        setlocal enabledelayedexpansion
        if "!Line1!"=="" (echo,!Line2!) else echo,!Line1!    !Line2!
    ))<$1>b.txt
type b.txt>$1
endlocal
if defined Em goto :a
:b
del temp $1 $2
pause
复制代码