77七

回复 30# qixiaobin0715


   月份日期分开定义，再拆开判断，不如直接全定义 #01/01 ...#12/31，然后结束了...

qixiaobin0715

回复 31# 77七
想过，代码会缩减很多。但变量定义过多（至少366个），会影响效率。
上面说过了，主要是练练手。

WHY

回复 29# qixiaobin0715


    还要考虑一下，分隔符位于字符串开头的情况， for /f 会去掉字符串开头的分隔符。
比如输入：/03/12

WHY

个人观点：特殊字符是 CMD 的硬伤，用纯P来解此题，简直就是自找麻烦。
吐槽一下：“你认为有前途的，其他人或许认为就是辣鸡”，事实证明这句话是对的。

buyiyang

才5个字符，用批处理的话逐字符判断更可靠一些

@echo off
set/p "data=Please enter a date (MM/DD):"
set "error=echo,Invalid date&pause&goto :eof"
setlocal enabledelayedexpansion
for /l %%i in (5,-1,0) do (
    set "data%%i=!data:~%%i,1!"
    if not "!data%%i!"=="" (
        if %%i equ 5 (
            %error%
        ) else if %%i equ 2 (
            if "!data%%i!" neq "/" %error%
        ) else if "!data%%i!" lss "0" (
            %error%
        ) else if "!data%%i!" gtr "9" %error%
    ) else (
        if %%i equ 4 %error%
    )
)
if %data0% equ 0 set "data0="
if %data3% equ 0 set "data3="
set mm=%data0%%data1%
set dd=%data3%%data4%
if %mm% gtr 12 %error%
if %dd% gtr 31 %error%
for /f "tokens=2" %%i in ('wmic os get codeset^,localdatetime') do (
    set yyyy=%%i
    set "yyyy=!yyyy:~0,4!"
    )
endlocal&set /a mm=%mm%,dd=%dd%,yyyy=%yyyy%
set /a "gtm=!(mm-4)|!(mm-6)|!(mm-9)|!(mm-11)","leap=!(yyyy%%4)&!!(yyyy%%100)|!(yyyy%%400)","dlim=!(mm-2)*(28+leap)+gtm*30+(!!(mm-2)&!gtm)*31"
if %dd% gtr %dlim% (%error%) else (echo,Valid date)
pause&exit /b
复制代码

buyiyang

回复 27# aloha20200628


    因为09不是有效的八进制数字，试试0x9

77七

回复 35# buyiyang


   
大佬，00/00的情况，没有判断，防不胜防

qixiaobin0715

回复 34# WHY
我也知道这么一个问题，用cmd搞出如此复杂的代码，确实不合适。
开始看到这个帖子，主要是想籍此私下练习练习逻辑思维，等到着手写代码时，没想到会是这么复杂，自己心里没底，发出来让大家看看 ，真是漏洞百出，最后重写代码，还是有漏洞。
最后的代码是借鉴27楼的建议重写的，发上来前，在13行下面有一行代码，是用来判断第3个字符是否为“/”的，个人感觉后续代码能够处理此问题，就给删除了，看来还是有用的，最少能够修补你在33楼所说的漏洞。
还是要在29楼第13、14行之间，加上删除的那行代码：

if not "%md:~2,1%"=="/" goto :p
复制代码

qixiaobin0715

回复 31# 77七
私下试了一把，全定义确实省事。

77七

用临时文件，仅判断两位数+/+两位数，应该可以对付所有特殊字符了吧

@echo off
set /p str=input:
setlocal enabledelayedexpansion
>1.txt echo=#!str!
endlocal
findstr /rxc:"#[0-9][0-9]/[0-9][0-9]" 1.txt
if not errorlevel 1 (
	echo ok
)
pause
复制代码

aloha20200628

即便是批处这类简单脚本级的造码，也是讲究 ‘有效 》可靠 》高效 》简洁’ 四重关，新手过头关，老手要高攀，若每次出手都能 ‘会当凌绝顶’，真可谓功德圆满了... 共勉共勉

qixiaobin0715

仔细的研究了findstr命令的一般表达式，确实功能极其有限，相当于极简版的正则。有点手痒痒，也来一个吧。匹配原则：先多后少，先一般后特殊。

findstr /x "0[1-9]/[0-2][1-9] 1[0-2]/[0-2][1-9] 0[1-9]/[12]0 1[0-2]/[12]0 0[13-9]/30 1[0-2]/30 0[13578]/31 1[02]/31"
复制代码

表达式说明：
0[1-9]/[0-2][1-9]    ——    1、2组对应所有月份，日期在30以内的组合，不包括日期10、20、30，因为不易避开非法日期00，还是单独处理为好；
1[0-2]/[0-2][1-9]
0[1-9]/[12]0           ——    3、4组单独处理上面所说的未包括的日期10、20，也是对应所有月份；
1[0-2]/[12]0
0[13-9]/30              ——    5、6组对应日期为30的月份，2月除外；
1[0-2]/30
0[13578]/31            ——    最后2组对应日期为31的月份，包括1、3、5、7、8、10、12月；
1[02]/31
欢迎大家批评指正。

buyiyang

回复 37# 77七


    感谢测试，限制上限的时候忘记限制下限了，再补上 set /a "1/(!!mm&!!dd)" 2>nul ||(%error%) 就没有问题了。

qixiaobin0715

回复 36# buyiyang
细致！严谨！

aloha20200628

再练一把 ‘纯P进行到底’ 的脑力操...
给一个纯P版本的日期输入合法性检查代码，不用外部方法，不用正则匹配
算法简明得益于采用 ‘字典变量’，尽可能考虑了各种防错对策》分隔符及其错位，日月数值溢出，日月相关，平闰年天数区分... 还是回归日月均为两位数的要求。
以下代码采用循环输入以便完成各种测试，直至空回车退出...

@echo off &setlocal
set/a "_1=31,_2=28,_3=31,_4=30,_5=31,_6=30,_7=31,_8=31,_9=30,_10=31,_11=30,_12=31,y=%date:~,4%%%4"
if %y% equ 0 set "_2=29"
:[md_loop]
set "md=" &set "c=" &set/p "md=输入日期（月值/日值）："
if not defined md endlocal&exit/b
setlocal enabledelayedexpansion &set k=!md:"=!
if "!k!" neq "!md!" echo,非法&endlocal&goto[md_loop]
endlocal &if "%md:~5%" neq "" echo,非法&goto[md_loop]
if "%md:~4,1%"=="" echo,非法&goto[md_loop]
for /f "tokens=1,2 delims=/" %%1 in ("%md%") do set "m=%%1"&set "d=%%2"
if "%md%"=="%m%" echo,非法&goto[md_loop]
for /f "delims=0123456789" %%n in ("%m%%d%") do set "c=1"
if defined c echo,非法&goto[md_loop]
if not defined d echo,非法&goto[md_loop]
if "%md:~2,1%" neq "/" echo,非法&goto[md_loop]
if "%m:~0,1%" equ "0" if "%m:~1,1%" neq "" set "m=%m:~1%"
set "_m=_%m%" &set "w=非法" &setlocal enabledelayedexpansion
if "%d:~0,1%" equ "0" if "%d:~1,1%" neq "" set "d=%d:~1%"
if %d% gtr 0 if %d% leq !%_m%! set "w=合法"
echo,!w!&endlocal&goto[md_loop]
复制代码