[ 新手练习 4 ] 批处理计算字符串长度

wxcute

假定一字符串 “123ABC上中下”，计算出这个字符串的长度，即有几个字符。

目的：掌握变量截取与条件判断用法。

要求：让批处理自动计算出字符串的长度。字符串可自定义，暂不考虑特殊字符。

评分：代码可读性 1 分；
　　　首个新方法 6 分，第二个 5 分，依次类推，最少 2 分；
　　　一人可多种方法，新方法追加 3 分，已经出现过的方法追加 1 分。

BBCC

@echo off&setlocal EnableDelayedExpansion
set "var=1234567890   1 $"
:loop
set /a a+=1
if not "!var:~%a%,1!" equ "" (goto :loop) else (echo %var%&echo. %a%&pause) 
复制代码

效率极为低下.

lhjoanna

对上述的两种方法进行了稍许改进，并且自己新加了一种方法，并加以比较运行效率。得出对于1000个字符的(似乎最长也只能处理长度为1000左右的字符串)长度计算，三楼方法(改进后)比二楼快约500毫秒，新方法(法三)效率与二楼相当，是在我的机子上。所以如果求的字符串数量很多的话（如成千上万个），还是用第二种方法较好！
       测试字符串生成可以用如下命令  @set /p=%random%<nul >>a.txt&%0
       新加了法四,batman的高见！

@echo off&setlocal enabledelayedexpansion
set /p "var=请输入字符串:"
echo ========================
echo [法一]
set time1=%time%
set /a time1_second=1%time1:~-5,2%-100
set /a time1_millisec=1%time1:~-2,2%-100
rem ----------[法一]主程序开始---------------------
:loop
set /a a+=1
if not "!var:~%a%,1!" equ "" goto :loop 
echo 共有%a%个字符
rem ----------[法一]主程序结束---------------------
set time2=%time%
set /a time2_second=1%time2:~-5,2%-100
set /a time2_millisec=1%time2:~-2,2%-100
if %time2_millisec% lss %time1_millisec% set /a time2_millisec+=100&set /a time2_second-=1
set /a second=time2_second-time1_second
set /a millisec=time2_millisec-time1_millisec
echo 开始时间:%time1%  结束时间:%time2%
echo 程序1运行时间为%second%秒%millisec%0毫秒
echo ========================
echo [法二]
set time1=%time%
set /a time1_second=1%time1:~-5,2%-100
set /a time1_millisec=1%time1:~-2,2%-100
rem ----------[法二]主程序开始---------------------
for /l %%a in (0,1,10000) do if "!var:~%%a,1!" equ "" set length=%%a&goto end
:end
echo 共有%length%个字符
rem ----------[法二]主程序结束---------------------
set time2=%time%
set /a time2_second=1%time2:~-5,2%-100
set /a time2_millisec=1%time2:~-2,2%-100
if %time2_millisec% lss %time1_millisec% set /a time2_millisec+=100&set /a time2_second-=1
set /a second=time2_second-time1_second
set /a millisec=time2_millisec-time1_millisec
echo 开始时间:%time1%  结束时间:%time2%
echo 程序2运行时间为%second%秒%millisec%0毫秒
echo ========================
echo [法三]
set time1=%time%
set /a time1_second=1%time1:~-5,2%-100
set /a time1_millisec=1%time1:~-2,2%-100
rem ----------[法三]主程序开始---------------------
set count=0
:loop2
set /a num+=1
for /f %%i in ("%num%") do if not "!var:~%%i,1!"=="" goto loop2
echo 共有%num%个字符
rem ----------[法三]主程序结束---------------------
set time2=%time%
set /a time2_second=1%time2:~-5,2%-100
set /a time2_millisec=1%time2:~-2,2%-100
if %time2_millisec% lss %time1_millisec% set /a time2_millisec+=100&set /a time2_second-=1
set /a second=time2_second-time1_second
set /a millisec=time2_millisec-time1_millisec
echo 开始时间:%time1%  结束时间:%time2%
echo 程序3运行时间为%second%秒%millisec%0毫秒
echo ========================
echo [法四] batman's idea
set time1=%time%
set /a time1_second=1%time1:~-5,2%-100
set /a time1_millisec=1%time1:~-2,2%-100
rem ----------[法四]主程序开始---------------------
echo %var%>a.txt
echo.>>a.txt
for /f "tokens=1 delims=:" %%i in ('findstr /o .* a.txt') do set /a length=%%i-2&if not %%i  
equ 0 echo 共有%length%个字符&goto end
:end
del a.txt
rem ----------[法四]主程序结束---------------------
set time2=%time%
set /a time2_second=1%time2:~-5,2%-100
set /a time2_millisec=1%time2:~-2,2%-100
if %time2_millisec% lss %time1_millisec% set /a time2_millisec+=100&set /a time2_second-=1
set /a second=time2_second-time1_second
set /a millisec=time2_millisec-time1_millisec
echo 开始时间:%time1%  结束时间:%time2%
echo 程序4运行时间为%second%秒%millisec%0毫秒
pause>nul
复制代码

刚有些小问题，已修改，大家运行看看！！！

[ 本帖最后由 lhjoanna 于 2008-11-29 21:46 编辑 ]

batman

大家可以想想怎么利用findstr /o去实现吧

lhjoanna

batman的方法果然很好啊，我一直都没有注意到也没有用过参数/o，每一个参数都有存在的价值啊，佩服！刚写出来运行了一下看(不知代码够不够简洁)，效率与[法二]相当。很值得推荐啊！在4楼更新了一下！

[ 本帖最后由 lhjoanna 于 2008-11-29 21:46 编辑 ]

BBCC

[法一]
共有1234568个字符
开始时间:21:54:45.96  结束时间:21:54:45.96
程序1运行时间为0秒00毫秒
========================
[法二]
共有10个字符
开始时间:21:54:45.96  结束时间:21:54:46.05
程序2运行时间为0秒90毫秒
========================
[法三]
共有10个字符
开始时间:21:54:46.05  结束时间:21:54:46.07
程序3运行时间为0秒20毫秒
========================
[法四] batman's idea
命令语法不正确。

有点问题哦

lhjoanna

我这里可以啊，你再运行看看？？

========================
[法一]
共有1021个字符
开始时间:21:57:20.33  结束时间:21:57:21.52
程序1运行时间为1秒190毫秒
========================
[法二]
共有1021个字符
开始时间:21:57:21.52  结束时间:21:57:21.70
程序2运行时间为0秒180毫秒
========================
[法三]
共有1021个字符
开始时间:21:57:21.70  结束时间:21:57:23.00
程序3运行时间为1秒300毫秒
========================
[法四] batman's idea
共有1021个字符
开始时间:21:57:23.00  结束时间:21:57:23.21
程序4运行时间为0秒210毫秒
复制代码

经过测试发现[法一]与[法三]在字符数很少时，比如100个以内时会比[法二]和[法四]小，字符数很多时会增到1秒以上，而[法二]和[法四]总是维持在150-250毫秒之间。算法的好坏判断是运行时间(效率)不随测试数据的变化而大幅波动，总是稳定在一定的范围内。所以在求字符串长度中，[法二]与[法四]可以算较好的算法。

[ 本帖最后由 lhjoanna 于 2008-11-29 22:07 编辑 ]

BBCC

这次就行了

[法一]
共有83个字符
开始时间:22:02:01.70  结束时间:22:02:01.75
程序1运行时间为0秒50毫秒
========================
[法二]
共有83个字符
开始时间:22:02:01.77  结束时间:22:02:01.85
程序2运行时间为0秒80毫秒
========================
[法三]
共有83个字符
开始时间:22:02:01.85  结束时间:22:02:01.91
程序3运行时间为0秒60毫秒
========================
[法四] batman's idea
共有83个字符
开始时间:22:02:01.91  结束时间:22:02:01.95
程序4运行时间为0秒40毫秒
复制代码

还是batman的牛啊,越长越快捷，但是能够解释一下为什么会多2出来吗？

[ 本帖最后由 BBCC 于 2008-11-29 22:08 编辑 ]

BBCC

[法四]可以算较好的算法

findstr的牛逼用途导致有那么高的效率

lhjoanna

你用findstr /o对一个文本文件进行操作，看一下结果，把数字与冒号也算做偏移量，第二行显示的数字就是第一行字符的长度加上开始的数字与冒号，所以减2就是第一行的字符串长度了。我推测的，没有任何理论依据，还请高手来个权威的解释啊。

[ 本帖最后由 lhjoanna 于 2008-11-29 22:18 编辑 ]

BBCC

看了一下英语版的帮助，不明白
/O         rints character offset before each matching line.

在每行之前显示偏移量？

[ 本帖最后由 BBCC 于 2008-11-29 22:20 编辑 ]

batman

关于findstr /o的用法，大家可以参照这个帖子：
http://www.bathome.net/viewthrea ... hlight=%C1%B7%CF%B0

Batcher

多出来的2个，并非冒号以及前面的数字，而是行尾的回车(CR)和换行(LN)。

lhjoanna

原来如此啊，以前总以为回车与换行是一个的。搜索了一下资料，发现回车是回到行首，换行是换到下一行。用二进制编辑器看行尾#13#10，十六进制看行尾为0d0a。说明我们平常输入的回车符其实是两个字符。#13为回车，#10为换行。0d为回车，0a为换行。大家把0d或0a改为00看看。又学到了一点！

[ 本帖最后由 lhjoanna 于 2008-11-29 23:20 编辑 ]

myzwd

@echo off
set /p tt=please input---
set n=-1
call:circle
goto:eof
:circle
setlocal
set tt1=%tt:~,1%
set tt2=%tt:~1%
set tt=%tt2%_%tt1%
set /a n+=1
if "%tt1%" neq "_" goto circle
echo %n%
endlocal