Silversky

【程序80】
题目：海滩上有一堆桃子，五只猴子来分。第一只猴子把这堆桃子凭据分为五份，多了一个，这只猴子把多的一个扔入海中，拿走了一份。第二只猴子把剩下的桃子又平均分成五份，又多了一个，它同样把多的一个扔入海中，拿走了一份，第三、第四、第五只猴子都是这样做的，问海滩上原来最少有多少个桃子？

@echo off & setlocal EnableDelayedExpansion
set count=0
set bad=0
for /l %%i in (4,4,2000) do (
if !count! equ 4 (if !bad! equ 0 (echo 原来最少有!j!个桃子 & pause>nul & exit))
set bad=0
set count=0
set l=%%i
for /l %%z in (0,1,4) do (
set /a j=!l!/4*5+1
set l=!j!
set /a k=!j!%%4
if !k! equ 0 (set /a count+=1) else (if !count! lss 4 (set bad=1))
)
)
复制代码

Silversky

【程序69】
题目：有n个人围成一圈，顺序排号。从第一个人开始报数（从1到3报数），凡报到3的人退出圈子，问最后留下的是原来第几号的那位。
方法一

@echo off & setlocal enabledelayedexpansion
set /p n=请输入一个数:
for /l %%i in (%n% -1 1) do set total= %%i !total!
set count=%n%
:loop
if !count! neq 1 (
  for %%i in (%total%) do (
    set /a num+=1
    if !num! equ 3 (
      set num=0
      set total=!total: %%i =!
      set /a count-=1
    )
  )
goto loop
)
echo 最后留下的序号为:%total%
pause>nul
复制代码

方法二

@echo off
set /p n=请输入一个数:
set r=0
for /l %%i in (2,1,%n%) do (set /a a=r+3 && set /a r=a%%%%i)
set /a r+=1
echo %r%
pause>nul
复制代码

Silversky

【程序20】

题目：一球从100米高度自由落下，每次落地后反跳回原高度的一半；再落下，求它在第10次落地时，共经过多少米？第10次反弹多高？

@echo off & setlocal enabledelayedexpansion
set n=100000000
set /a m=n/2
for /l %%i in (2,1,10) do (set /a n=n+2*m && set /a m/=2)
echo 共经过!n:~0,3!.!n:~-6!米
echo 第10次反弹0.0!m:~-6!米
pause>nul
复制代码

Silversky

【程序9】
题目：要求输出国际象棋棋盘。

@echo off & setlocal enabledelayedexpansion
for /l %%i in (8,-1,1) do (
  for /l %%j in (8,-1,1) do (
  set /a n=%%i%%2+%%j%%2
  if !n! == 1 (set/p=■<nul) else (set/p=  <nul)
  )
  echo/
)
pause>nul
复制代码

fish

@echo off&setlocal enabledelayedexpansion
set f=
for /l %%i in (1,1,9) do (
        for /l %%j in (0,1,9) do (
                set s=%%i%%j
                set /a r1=8*!s!
                if !r1! lss 100 (
                        set /a r2=9*!s!
                        if !r2! geq 100 (
                                set /a l=809*!s!
                                set /a r=!r1!*100+!r2!+1
                                if !l!==!r! (
                                        echo 809*!s!=800*!s!+1
                                        set f=1         
                                )
                                
                                        
                        )        
                )
                
        )
)
if not defined f echo Not found!
pause
复制代码

vsax

实践练习的好帖子。从中可以学到很多东西

lvsehuaxue

@echo off&setlocal enabledelayedexpansion
set n=1
for /l %%a in (1 1 7) do (
    set /a m+=1
    for /l %%i in (1 1 !n!) do (
         set /p=*<nul
   )
   set /a n+=2
   if !m! geq 4 set /a n-=4
   echo.
)
echo.
pause
复制代码

lvsehuaxue

@echo off&setlocal enabledelayedexpansion
set n=1
for /l %%a in (1 1 7) do (
    set /a m+=1
    for /l %%i in (1 1 !n!) do (
         set /p=*<nul
   )
   if !m! geq 4 (set /a n-=2) else  set /a n+=2
   echo.
)
pause
复制代码

lvsehuaxue

@echo off&setlocal enabledelayedexpansion
set n=1
for /l %%i in (1 1 7) do (
    call :b 6 4 2 0 2 4 6
    set /a m+=1
    for /l %%j in (1 1 !n!) do set /p v=*<nul
    if !m! lss 4 (set /a n+=4) else set /a n-=4
    echo.
)
pause>nul
:b
set /a x+=1
call set w=%%%x%
for /l %%a in (1 1 !w!) do set /p=  <nul
set /p=<nul
复制代码

zhangyanjing

在新年中学习加油继续

mac007cn

原帖由 youxi01 于 2008-4-10 23:23 发表
论坛里前几天就出现了相关代码，测试代码：@echo off &setlocal enabledelayedexpansion
set "str=1 2 3 4 "
for %%a in (%str%) do (
        set var1=!str:%%a =!
        for %%b in (!var1!) do (
        ...

好啰嗦啊。
我的【程序1】：

@echo off
set /a n=0
for /L %%a in (1,1,4) do (for /L %%b in (1,1,4) do (for /L %%c in (1,1,4) do (
    if %%a neq %%b (if %%b neq %%c (if %%c neq %%a (
        echo %%a%%b%%c
        set /a n+=1
    )))
)))
复制代码

[ 本帖最后由 mac007cn 于 2011-1-26 15:44 编辑 ]

jinzeyu

挺好的，试试看，谢谢楼主啊

linqing8

我的杨辉三角,刚费老劲做出来，还未精简：

@echo off
del num.txt
setlocal ENABLEDELAYEDEXPANSION
set /p n=请输入层数,不要超过30.
for /l %%i in (1,1,%n%) do (
  set ln=%%i
  set a1=1
  set a!ln!=1
  set num=1
  if %%i geq 3 (
  set /a r1=2
  set /a r2=!ln!-1
	for /l %%j in (!r1!,1,!r2!) do (
	set col=%%j
	set /a r3=%%j-1  
	set /a r4=!ln!-2  
	call :aaa
	)
  	 )
if !ln! geq 2 for /l %%m in (2,1,!ln!)   do (set num=!num! !a%%m!) 
echo !num! >> num.txt
  )
start num.txt
goto :eof
:aaa
for /f "skip=%r4% tokens=%r3%,%col%" %%k in (num.txt) do set /a a%col%=%%l+%%k 
复制代码

linqing8

正整数质数因子分解，经过优化，对大数字分解速度较快，效率比此贴前两个高。最大计算能力为32位二进制。如分解1999999999=31*64516129本人机子上不到4秒。

@echo off 
setlocal enabledelayedexpansion
:begin
set /p num=请输入一个正整数：
set /a n=0,num0=%num%
:cccc
set loop=10000
if %num%  GTR 10000 set /a loop=%num%/100
if %num%  GTR 1000000 set /a loop=%num%/1000
if %num%  GTR 100000000 set /a loop=%num%/10000
if %num%  GTR 10000000000 set /a loop=%num%/100000
if !num!  gtr 1 ( 
    for /l %%i in (2,1,%num%) do (
        set /a num2=%%i
        set /a num1=!num!%%!num2!
        if %%i GTR %loop% (set /a n=n+1
             set /a pr!n!=!num!
             call :ca1
             ) 
       if !num1!==0 (set /a n=n+1
            set /a num=!num!/%%i
            set /a pr!n!=%%i
            if %%i==%num% (call :ca1) else (call :cccc)
            ) 
       )
) else (set pr1=1)
goto :eof
:ca1
set prime=!pr1!
if !n! gtr 1 ( for /l %%j in (2,1,!n!) do (rem echo !pr%%j!  & pause
   set prime=!prime!×!pr%%j!
   )
)
echo %num0%分解为质数因子结果为：%num0%=!prime!
echo.&echo.&goto begin
pause>nul 
复制代码

telnet

难度很高    还是先从低处开始吧