tyc

@echo off
setlocal enabledelayedexpansion
::选择排序法
echo 共输入10个数
for /l %%i in (1,1,10) do (
 set /p a_%%i=请输入%%i个数
 set str=!str! !a_%%i!
)
echo %str%
for /l %%i in (1,1,9) do (
 set /a b=%%i+1
 for /l %%j in (!b!,1,10) do (
   if !a_%%i! gtr !a_%%j! (
      set /a t=a_%%i
      set /a a_%%i=a_%%j
      set /a a_%%j=t
    )
)
)
for /l %%i in (1,1,10) do (
 set str1=!str1! !a_%%i!
)
echo %str1%
pause>nul
复制代码

sjzong

题目：将一个正整数分解质因数。例如：输入90,打印出90=2*3*3*5。
程序分析：分解质因数实际就是把这数除以素数列（2 3 5 7 11 13……），从2开始除，不整除的话，换下一个素数；整除的话，就记下该数字，并求出商；若商不为1，则再把商去除素数列；商为1，就停止，表明分解结束。
由于素数列第一个数为2，后面为奇数组，所以进行判断时，等于2时就加1，不等于2时就加2，这里面有个问题就是多进行无用循环，如9 15等！还有结果是，例如：输入90,打印出90=1*2*3*3*5。

 
@echo off&setlocal EnableDelayedExpansion
set /p num=请输入要因数分解的数：
set str=!num!=1
:a
set /a n=2
:b
set /a aa=!num! %% !n!
::这if语句是能整除的语句，求出商，并记下那个质数n
if !aa! equ 0 (
  set /a num=!num!/!n!
  set str=!str!*!n!
::等于1，分解结束，跳到c，不等于1，继续把商除以素数列，跳到a
  if !num! neq 1 (goto :a) else (goto :c)
)
::这if语句是不能整除的，换下一个素数，并跳到b
if !aa! neq 0 (
::若等于2时n+1，不等于2时n+2
  if !n! equ 2 (set /a n=!n!+1) else (set /a n=!n!+2)
  goto :b
)
:c
echo 分解完是：!str!
pause
复制代码

[ 本帖最后由 sjzong 于 2009-4-9 00:53 编辑 ]

sjzong

程序分析：这个偶数应该是大于3的偶数，但是大于3的偶数中4是比较特殊的，可拆为两个2的和；其他的偶数一定要拆成两个奇数的和，然后分别判断这两个数是否为素数即可。

 
@echo off
setlocal enabledelayedexpansion
::原创：sjzong
set /p num=请输入大于3的偶数：
set /a aa=!num! %% 2
rem 判断输入的数字是否为偶数
if !aa! neq 0 (
cls
echo 你输入的数字不是偶数！
set /p num=请再次输入大于3的偶数：
)
rem 判断输入的数字是否小于等于3
if !num! leq 3 (
cls
echo 你输入的数字小于4！
set /p num=请再次输入大于3的偶数：
)
rem 判断输入的偶数是否为4，是的话直接拆分为两个2的和，不是的话进行两个奇数的拆分。
if !num!==4 (echo 偶数 !num! 是素数 2 与 2 的和。) else (
set /a yiban=!num!/2
rem 拆分偶数时只需从3到该偶数的一半即可
for /l %%a in (3 2 !yiban!) do (
  set /a shu=!num!-%%a
  set /a a1=0
  set /a a2=0
  call :test %%a
  if !flag!==1 set /a a1=1
  call :test !shu!
  if !flag!==1 set /a a2=1
  if !a1!==1 if !a2!==1 echo 偶数 !num! 是素数 %%a 与 !shu! 的和。
)
)
pause
goto :eof
rem 判断该数是否为素数时，只需计算从1到该数的一半能被该数整除的次数
rem 次数为1时表示为素数，次数大于1时表示不是素数
:test
  set /a flag=1
  set /a b=%1/2
  set /a count=0
  for /l %%a in (1 1 !b!) do (
   set /a yushu=%1 %% %%a
   if !yushu! equ 0 set /a count=!count!+1
   if !count! gtr 1 (set /a flag=0 & goto :eof)
  )
复制代码

[ 本帖最后由 sjzong 于 2009-4-10 10:01 编辑 ]

tyc

@echo off
setlocal enabledelayedexpansion
::判断是否为八进制，共几位
:1
set /p bb=请输入八进制整数:
set /a aa=%bb%
set /a n=0
:2
set b=%aa:~,1%
if %b% gtr 8  goto :1 
set /a n=n+1
set aa=!aa:~1!
if "%aa%" neq "" goto :2
::echo %n%
::利用权值，求各位十进制值并累加
:3
set /a n-=1
set /a c=%bb:~0,1%
for /l %%i in (1,1,%n%) do set /a c*=8
set /a t+=%c%
set bb=%bb:~1%
if "%bb%" neq "" goto :3
echo %t%
pause>nul
复制代码

[ 本帖最后由 tyc 于 2009-4-10 10:33 编辑 ]

tyc

@echo off
set /p x=要转换的数:
set /p y=要转换的进制:
call :10 %x% %y%
pause>nul
goto :eof
:10 
set/a t=%1/%2
if %t% gtr 0 call :10 %t% %2
set /a b=%1%%%2
set /p=%b% <nul
复制代码

[ 本帖最后由 tyc 于 2009-4-12 12:17 编辑 ]

apchyo11

精华啊。。 我很是喜欢！！

bath

好了，我承认，你们都是神！
一个菜鸟瞠目结舌，蹚乎其后

tianzhizhouyin

看到我都快头晕了，不过很好很强大。

sjzong

【程序69】
题目：有n个人围成一圈，顺序排号。从第一个人开始报数（从1到3报数），凡报到3的人退出圈子，问最后留下的是原来第几号的那位。
改一下：设有ｎ个人依次围成一圈，从第１个人开始报数，数到第ｍ个人出列，然后从出列的下一个人开始报数，数到第ｍ个人又出列，…，如此反复到所有的人全部出列为止。设ｎ个人的编号分别为1，2，…，n，打印出出列的顺序。

@echo off&setlocal enabledelayedexpansion
:n
cls
set /p n=请输入人数n:
echo.%n%|findstr "^[1-9][0-9]*$">nul||goto n
:m
set /p m=请输入报数m:
echo.%m%|findstr "^[1-9][0-9]*$">nul||goto m
for /l %%a in (1 1 %n%) do (if %%a lss 10 (set str=!str! 0%%a) else (set str=!str! %%a))
set/a b=3*!m!-3
set/a c=3*!m!
:loop
if "!str:~%b%,3!" equ "" (set s1= 空) else (set s1=!s1!!str:~%b%,3!)
if "!str:~%c%,3!" equ "" (set str=!str:~0,%b%!) else (set str=!str:~%c%!!str:~0,%b%!)
set/a n-=1
if not !n! lss !m! goto loop
echo 出列的数据是：!s1:~1!&set s1=
if !m! equ 1 (echo 剩下的数据是：空&set str=) else (echo 剩下的数据是：!str:~1!&set str=)
pause>nul&goto n
复制代码

sxqylz

就是需要这样的贴子啊，给新手们的帮助太大了，看完了教程就得要这样的东西来练练

keen

其实本论坛，还有很多给新手出的题目，在 新手练功区 版块。

xwk003

来学学，本是也不会

正在找人教

nopr

程序1

@ECHO OFF
setlocal enabledelayedexpansion
for /l %%i in (1,1,4) do (
     for /l %%j in (1,1,4) do (
         for /l %%k in (1,1,4) do (
                 if not %%i==%%j (
                     if not %%i==%%k (
                         if not %%j==%%k echo %%i%%j%%k)
                           )
                           )
                           )
                           )
pause
复制代码

[ 本帖最后由 nopr 于 2009-8-5 20:39 编辑 ]

nopr

@ECHO OFF
setlocal enabledelayedexpansion
:1
echo 查询日期请介于1900和2200年之间
ping /n 1 127.1>nul
set /p b=请输入年份:....

if %b% leq 1900 echo 你输入年份不符合要求,请重新输入!&ping /n 2 127.1>nul&cls&goto 1
if %b% gtr 2200 echo 你输入年份不符合要求,请重新输入!&ping /n 2 127.1>nul&cls&goto 1
:2
cls
set /p b1=请输入月份:
if %b1% lss 1 goto 2
if %b1% gtr 12 goto 2
:3
cls
set /p b2=请输入日期:
if %b2% lss 1 goto 3
if %b2% gtr 31 goto 3
cls&set /a b3=%b1%-1
call :4
for /l %%i in (1,1,%b3%) do (
         for %%j in (1 3 5 7 8 10 12) do (
             if %%i == %%j (set /a a+=31)
             )
         for %%k in (4 6 9 11) do (
             if %%i == %%k (set /a a1+=30)
             )
             )
for /l %%h in (1900 4 2200) do echo %%h>>a.txt
find "%b%" a.txt >nul && (set /a a2=%a1%+29) || set /a a2=%a1%+28
set /a a3=%a%+%a2%+%b2%
echo 你要查询的日期是%b%的第%a3%天
del a.txt&pause>nul&goto :eof
:4
for /l %%y in (1 1 20) do (
     set /p=*<nul
     for /l %%z in (1 1 500) do ver>nul
     )
cls
goto :eof
复制代码

nopr

@echo off
setlocal enabledelayedexpansion
for /l %%i in (1,1,9) do (
     echo.
     for /l %%j in (1,1,9) do (
     set /a aa=%%i*%%j
     set a=%%jx%%i=!aa!
     if %%j leq %%i set/p=!a! <nul
     )
     )
pause>nul
复制代码