[ 新手练习题 6 ]批处理检查文本中是否存在某字串

wxcute

[ 新手练习题 6 ] 检查文本中是否存在某字串
检查下列文本文件中是否存在“批处理之家”字符串，显示出含有该字串的文件名。
其中字符串与文本文件均可自行构建。
cn.txt

欢迎来到批处理之家
欢迎来到新手练功区
复制代码

en.txt

欢迎来到BATHOME
欢迎来到新手练功区
复制代码

目的：掌握判断文本中是否含有字符串的方法，用于查找文件等实际用途。

要求：可自行创建多个文件进行查找。可利用外部命令，当然也可不用。
　　　若是自已构建，请将查找的字串写出来，还有示例文本。
　　　方法不限。

评分：代码可读性 1 分；
　　　首个新方法 5 分，第二个 4 分，依次类推，最少 2 分；
　　　一人可多种方法，新方法追加 2 分，已经出现过的方法追加 1 分。

CrLf

15# Hello123World


findstr是匹配字节的，所以面对汉字这种占两个字节的宽字符常常会出现诡异的现象，所以最好打开 /l 或者 /r 开关，而 /c: 也是保险起见而加上的，因为谁知道宽字符里是否会含有半个空格呢...

Hello123World

使用通配符受教了，不过/l /c参数没必要吧。

CrLf

13# Hello123World

可以用通配

findstr /m /l /c:"批处理之家" *.txt
复制代码

Hello123World

1# wxcute

@echo off
for /r %%i in (*.txt) do findstr /m "批处理之家" "%%i"
pause
复制代码

common

3# 风行者

请教楼上：for /r %%a in (*.txt) do findstr /r "\<批处理之家\>" "%%a" >nul && echo %%~nxa
这句中"%%a" >nul 的做用与 echo %%~nxa 中的~nx又是什么意思
没看懂，请教下

wangqi0077

@echo off
findstr "批处理之家" *.txt
pause
复制代码

meihaodehuiyi

@echo off
find "批处理之家" <cn.txt
if %errorlevel%==0 (echo 该字符串在cn.txt中) else (find "批处理之家" <en.txt)&if %errorlevel%==o (echo ^
该字符串在en.txt中)
pause >nul
复制代码

[ 本帖最后由 meihaodehuiyi 于 2010-10-15 08:28 编辑 ]

backup

@echo off
set /p words=input the word you want to find in files:
set /p files=input the range you want to define:
if "%files:~-4%"==".txt" findstr /n /c:"%words%" "%files%"&pause>nul&goto :eof
for /f "delims=" %%a in ('dir  /s /b %files%\*.txt') do (
findstr /n /c:"%words%" "%%a">tmps.txt && echo %%a
for /f "tokens=1,2 delims=:" %%b in (tmps.txt) do echo %%c  line:%%b
)
del tmps.txt /q 2>nul
pause>nul
复制代码

imin

@echo off
cd\
c:
findstr 批处理之家 1.txt
rem:1.txt的内容就是cn.txt，2.txt的内容就是en.txt。
if %errorlevel%==0 goto y
if %errorlevel%==1 goto n
:y
echo 这是1.txt。
pause
exit
:n
findstr 批处理之家 2.txt
if %errorlevel%==0 echo 这是2.txt。

pause
exit
复制代码

poxi

答：
是这样么...

 @echo off
call :find cn.txt
call :find en.txt
pause
exit
:find
for /f " delims=:" %%i in ('findstr "批处理之家" "%1"') do echo %1
goto :eof
复制代码

===========
end；

DXSX

一条命令就可以解决：
FOR /F "TOKENS=2 DELIMS= " %C IN ('FIND /C /I "批处理之家" *.TXT') DO @ECHO %~NC.TXT

不过如果文件名有空格就不好用了，可以用下一个方法

@echo off
for /f "delims=" %%c in ('dir /b /a-d *.txt') do (
find /c /i "批处理之家"  "%%c" >nul
if not errorlevel 1 echo %%c
)
pause

[ 本帖最后由 DXSX 于 2009-8-25 17:43 编辑 ]

cs19860814

a.txt：

批处理之家是一个很好的批处理学习平台！！！

代码：

@echo off
for /r %%i in (*.txt) do  findstr /c:批处理之家 "%%i">nul && echo %%~nxi
pause>nul
复制代码

quake_wu

@echo off
 set /p a=请输入查找的关键字：
for /F "tokens=1 delims=:" %%i in ('findstr /C:%a% *.txt ') do echo  %%i
复制代码

风行者

@echo off
for /r %%a in (*.txt) do findstr /r "\<批处理之家\>" "%%a" >nul && echo %%~nxa 
pause 
复制代码