[文本处理] [已解决]空格补位，把输出内容对齐的批处理

shenlong

a.txt 内容
aa  1232   米
bbbbb  66  米
想要把内容补空格后输出到 b.txt
aa          1232    米
bbbbb     66       米
以下我测试的代码，不能达到预期效果，请各位围观帮忙，先行谢过 。

@echo off
setlocal enabledelayedexpansion
set "k=                    "
(for /f "tokens=1-4  delims=  " %%a in (a.txt) do (
    set "n1=%%a" && set "n2=%%b" && set "n3=%%c" && set "n4=%%d"
    set a=!n1!%k% && set b=!n2!%k%  && set  c=!n3!%k%  && set  d=!n4!%k% 
    echo.  !a:~0,15! !b:~0,15! !c:~0,15! !d:~0,15! 
)) > b.txt
endlocal
复制代码

qixiaobin0715

嵌套变量延迟开关， 来消除文本中“!”的影响，弃用for %%i in (...) do...的方法，通吃文本中存在默认分隔符以及*?通配符等字符的影响，使用大多数人熟悉的cmd命令书写代码。感觉效率还可以：

@echo off
echo,>$1
:a
set Em=
set /a colsn+=1
if %colsn% equ 1 (
    (for /f "tokens=1" %%i in (a.txt) do (echo,%%i&set Em=1))>temp
) else (
    (for /f "tokens=1,%colsn%" %%i in (a.txt) do (echo,%%j&if not "%%j"=="" set Em=1))>temp
)
if not defined Em goto :b
echo,>>temp
findstr /n /o .* temp>$2
setlocal enabledelayedexpansion
    for /f "tokens=1,2 delims=:" %%i in ($2) do (
        set /a m=%%j-x
        set /a n=%%i-1
        set "a!n!=!m!"
        if !max! lss !m! set "max=!m!"
        set "x=%%j"
    )
set /a n+=1
    (for /f "delims=:" %%i in ('findstr /n .* temp') do (
        set str1=
        set str2=
        set /p str1=
        set /a z=max-a%%i
        for /l %%k in (1,1,!z!) do set str2=!str2! 
        if %%i neq !n! echo,!str1!!str2!
    ))<temp>$2
    (for /f "tokens=1* delims=:" %%i in ('findstr /n .* $2') do (
        endlocal
        set /p Line1=
        set Line2=%%j
        setlocal enabledelayedexpansion
        if "!Line1!"=="" (echo,!Line2!) else echo,!Line1!    !Line2!
    ))<$1>b.txt
type b.txt>$1
endlocal
if defined Em goto :a
:b
del temp $1 $2
pause
复制代码

buyiyang

算字节长度其实也可以将文本转换为16进制字串进行计算和处理，而且不用担心任何特殊字符。

@echo off&setlocal enabledelayedexpansion
set "input=a.txt"&set /a m=line=1&set "act=set/p=,&set/a m=1"
for %%i in ("%input%") do fsutil file creATenew "%input%.zero" %%~zi >nul
(for /f "tokens=2" %%a in ('fc /b "%input%" "%input%.zero"^|findstr /irc:"[0-9A-F]*: [0-9A-F][0-9A-F] 00"') do (
    if /i "%%a"=="0A" (echo,&set/a m=1,line+=1,col=0) else if /i "%%a"=="0D" (echo,
        for %%l in (!line!) do for /l %%i in (1,1,!col!) do (
            if !C%%i_%%l! gtr !C%%imax! set/a C%%imax=C%%i_%%l
            set "C%%i_%%l="
            ) ) else if /i "%%a"=="20" (%act%) else if /i "%%a"=="09" (%act%) else (
                    set/p=%%a
                    set /a col+=m,m=0
                    set /a C!col!_!line!+=1
                   )
        ))<nul >"%input%.temp"
(for /f "delims=" %%a in (%input%.temp) do (
    set /a col=0
    for %%i in (%%a) do (
        set /a col+=1&set "space="
        set /a size=C!col!max,len=size*2+2
        for /l %%i in (1,1,!size!) do set "space=!space!20"
        set "outstr=%%i!space!"
        for %%i in (!len!) do echo,!outstr:~0,%%i!
        )   
    set /p =0d0a
)   )<nul >"out_%input%"
del /q "%input%.zero" "%input%.temp" 
certutil -decodehex -f "out_%input%" "out_%input%" >nul
pause
复制代码

qixiaobin0715

回复 59# ppll2030
1.排版美不美观个人看法不一，只要达到各列上下对齐的效果，调整列的宽度就是小kiss，增加或减少几个空格而已；
2.如果列数都懒得搞清楚，就太那个了吧。实际上要解决这个问题也不复杂，就是在原有代码外层加上goto循环，再if几下即可。个人感觉goto语句太过难看，很少使用此循环。

77七

回复 57# ppll2030


   
去掉就行，提供两种方法...

@echo off
set "str=    1  2 3 *  ?    "
set "str=x %str%"
set "str=%str: =&echo;%"
for /f "skip=1" %%a in ('echo %%str%%') do (
	echo [%%a]
)
pause
for /f "tokens=*" %%a in ("    1  2 3 *  ?    ") do (
	set str=%%a
	if defined str (
		call set "str=%%str: =&echo;%%"
		for /f %%a in ('call echo %%str%%') do (
			echo [%%a]
		)
	)
)
pause
复制代码

aloha20200628

回复 60# ppll2030

我说的过滤掉中英文空格+制表符构成的 ‘全空白行’，其中的中文空格即全角空格。delims表达式指定的这三个字符复制到代码区中有时会 ‘变形’ 不过知道此意你在自己的代码中调整就是了

ppll2030

回复 58# aloha20200628


    老大。你的delims那边的有点问题，害我找了好久。
就是那个中英文空格你给打了三个。直接卡当了。修改为一个制表符和一个空格就OK了
像我这边，还加入全角符的空格，也完美支持了。标点符号也完美显示。
大赞哦~！

ppll2030

回复 56# qixiaobin0715


    你的代码有些还看不明，需要研究一下
不过31楼的大佬，貌似也是按列来取值，然后根据每列最大字符串得到每列最大宽度。从而使得结果排版更加的完美。
而它第一段可以自动识别最大的列数。不需要手动填写，或许可以借鉴到你的代码里。
他的代码后半段很复杂。我一时半会不能理解透。
等研究透aloha的版本，再去研究31楼的。毕竟aloha的版本感觉思路跟我的有相似之处，好理解一些。

aloha20200628

回复 54# ppll2030

更新了50楼代码，滤掉了全空白字符行（仅包含中英文空格+制表符），以免运行中被阻塞...

ppll2030

回复 55# 77七


    哈哈。果然有取巧的办法。感谢指导

不过这个用在这里会引发另一个bug

当每行开头是几个空格开始的情况，取值第一个会是ECHO

qixiaobin0715

回复 53# ppll2030
字符串分行显示时，不使用for %%a in (...) do...这样的循环结构，可以避免出现默认分隔符以及*?通配符的影响；
至于变量延迟中!会”隐藏“的问题有多种解决方法，其中一种方法可以参考http://www.bathome.net/thread-11193-1-1.html

77七

回复 53# ppll2030


   50楼大佬已经给出答案了。如果没有其它特殊字符，只有通配符，也可以试试以下思路(老帖子看到的)，将行变成竖排

@echo off
set "str=1  2 3 *  ?    "
set "str=%str: =&echo;%"
for /f %%a in ('echo %%str%%') do (
	echo [%%a]
)
pause
复制代码

ppll2030

回复 50# aloha20200628


    厉害了。换一个思路就搞定了特殊符号问题。这思维真是服了。

不过又有一个新问题: 对于包含有空格或制表符的空行（整行都不显示字符的，看着就像一空行），脚本会卡住，无法进行下去。

不过这不是很大的问题。我目前是加一段去除所有空行的命令，再继续执行就完美了。

再次感谢老大，通过这几段，学习到了很多。

ppll2030

回复 51# 77七
回复 48# qixiaobin0715

感谢两位大佬的指点。原因是已经找到了。只是想知道有没有什么好的经验或是取巧的办法可以避免这些通配符。
毕竟还想保持这么精简而干练的代码

qixiaobin0715

自己又偷偷的写了一个代码，对for默认分隔符和通配符 *？以及延迟变量中的 ! 免疫，效率不行，没好意思发出来。