[文件操作] [已解决]批处理怎样查找多个文件夹分别复制文件？

剑气如霜

举例:
C:\Program Files\xxx\software_版本号
C:\Program Files(x86)\xxx\software_版本号
<software_版本号>可能安装在Program Files，也可能安装在Program Files(x86)，版本可能是software_1.0，software_2.5，software_10多个版本同时存在，把DATA_1.0，DATA_2.5，DATA_10，用xcopy分别复制到对应安装目录下。

77七

回复 8# 剑气如霜


   如果software是不变的，做个变量替换就行。

剑气如霜

回复 7# 77七
我以前自己写的就是多个if的写法，这种方式不能自动匹配版本，比如明年软件出了个新版本，然后设置了<DATA_新版本>以后，还要回头在批处理里面添加对应的版本号，3L或者5L的这种方式更适合我的环境。用xcopy是因为DATA里面包含文件夹，用copy无法实现，不用robocopy是因为winxp无此命令，代码的兼容性很重要。谢谢你的热心帮助。

77七

可以试试2楼代码，其中4-10行，没有采用分隔符切割文件名缩短代码，用了多个if，本意为方便楼主自定义修改。（早已预判）
因标题中表明是复制文件，故用的copy，可以改为

robocopy "DATA_1.0" "%%d\DATA_1.0" /e
复制代码

剑气如霜

搞定，谢谢！测试的时候发现一些奇怪的彩蛋，winxp不支持同时查找2个路径，win7及以上就可以。然后第9行的MD命令删掉也可以，xcopy应该是具备复制+同时创建路径的功能。因为实际环境的规则比例子复杂，比如实际中software有3个空格，然后实际<版本号 1.5>对应的是<DATA_1_5>等等，给大家添麻烦也不好意思，最后还是用回3L的代码，把特例手动写进去完工。

flashercs

@echo off
cd /d "%~dp0"
REM 设置software分隔符 _或空格
set "delims= "

for /d %%A in ("C:\Program Files\xxx\software%delims%*" "C:\Program Files (x86)\xxx\software%delims%*") do (
  for /f "tokens=1* delims=%delims%" %%B in ("%%~nxA") do (
    if exist "DATA%delims%%%~C\" (
      md "%allusersprofile%\Application Data\xxx\software%delims%%%~C\DATA%delims%%%~C" 2>nul
      xcopy "DATA%delims%%%~C\*" "%allusersprofile%\Application Data\xxx\software%delims%%%~C\DATA%delims%%%~C\" /E /H /R
    )
  )
)

pause
exit /b
复制代码

剑气如霜

谢谢2位朋友的帮助！3楼的代码很智能，非常好用。在这里能不能延伸一下问题，如果<software 版本号>这种以空格来区分的文件夹该如何判断？然后如果xcopy最后要复制的目标路径是%allusersprofile%\Application Data\xxx\DATA 版本号，该如何修改代码？
比如查找到"C:\Program Files\xxx\software 2.5"
用xcopy复制DATA 2.5文件夹到%allusersprofile%\Application Data\xxx\software 2.5\DATA 2.5路径
隔行如隔山，个人搞不来这种问题，只能求助各位，谢谢！

flashercs

@echo off
cd /d "%~dp0"
for /d %%A in ("C:\Program Files\xxx\software_*" "C:\Program Files (x86)\xxx\software_*") do (
  for /f "tokens=1* delims=_" %%B in ("%%~nxA") do (
    if exist "DATA_%%~C\" (
      md "%%~A\DATA_%%~C" 2>nul
      xcopy "DATA_%%~C\*" "%%~A\DATA_%%~C\" /E /H /R
    )
  )
)
pause
复制代码

77七

@echo off & cd /d "%~dp0" & fltmc >nul || (powershell -Command "Start-Process '%~f0' -Verb RunAs" & exit /b)
rem 保存为ansi编码
for /f "delims=" %%d in ('dir /b /s /ad "C:\Program Files\software_*" "C:\Program Files (x86)\software_*"') do (
	if /i "%%~nxd" equ "software_1.0" (
		copy "DATA_1.0" "%%d\"
	) else if /i "%%~nxd" equ "software_2.5" (
		copy "DATA_2.5" "%%d\"
	) else if /i "%%~nxd" equ "software_10" (
		copy "DATA_10" "%%d\"
	)
)
pause
复制代码

假设 C:\Program Files C:\Program Files (x86) 均已存在