批处理挑战智能五子棋

foxJL

很早以前曾经帮百度贴吧一位朋友写了个五子棋的界面,可以自己和自己对战.
可是我到目前为止还没有想到更好的算法能计算出胜负.
虽说做好了也不一定有人会真的去拿这个游戏,但是我们应该勇于挑战.
这个难题,大家共同解决.

@echo off && setlocal enabledelayedexpansion
color 27 & mode con cols=35 lines=20
set BQ=●&set HQ=○&set KB=┼&set xz=0&set yx=1
del bq.wzq,hq.wzq>nul 2>nul
:home
for %%i in (a b c d e f g h i j k l m) do (
for %%j in (1 2 3 4 5 6 7 8 9 10 11 12 13)do (
set %%i%%j=%KB%))
for /f %%k in (bq.wzq) do (set %%k=%bq%)
for /f %%k in (hq.wzq) do (set %%k=%hq%)
cls
echo\
echo      ＡＢＣＤＥＦＧＨＩＪＫＬＭ
echo    ┌┬┬┬┬┬┬┬┬┬┬┬┬┬┐
echo   1├%a1%%b1%%c1%%d1%%e1%%f1%%g1%%h1%%i1%%j1%%k1%%l1%%m1%┤
echo   2├%a2%%b2%%c2%%d2%%e2%%f2%%g2%%h2%%i2%%j2%%k2%%l2%%m2%┤
echo   3├%a3%%b3%%c3%%d3%%e3%%f3%%g3%%h3%%i3%%j3%%k3%%l3%%m3%┤
echo   4├%a4%%b4%%c4%%d4%%e4%%f4%%g4%%h4%%i4%%j4%%k4%%l4%%m4%┤
echo   5├%a5%%b5%%c5%%d5%%e5%%f5%%g5%%h5%%i5%%j5%%k5%%l5%%m5%┤
echo   6├%a6%%b6%%c6%%d6%%e6%%f6%%g6%%h6%%i6%%j6%%k6%%l6%%m6%┤
echo   7├%a7%%b7%%c7%%d7%%e7%%f7%%g7%%h7%%i7%%j7%%k7%%l7%%m7%┤
echo   8├%a8%%b8%%c8%%d8%%e8%%f8%%g8%%h8%%i8%%j8%%k8%%l8%%m8%┤
echo   9├%a9%%b9%%c9%%d9%%e9%%f9%%g9%%h9%%i9%%j9%%k9%%l9%%m9%┤
echo  10├%a10%%b10%%c10%%d10%%e10%%f10%%g10%%h10%%i10%%j10%%k10%%l10%%m10%┤
echo  11├%a11%%b11%%c11%%d11%%e11%%f11%%g11%%h11%%i11%%j11%%k11%%l11%%m11%┤
echo  12├%a12%%b12%%c12%%d12%%e12%%f12%%g12%%h12%%i12%%j12%%k12%%l12%%m12%┤
echo  13├%a13%%b13%%c13%%d13%%e13%%f13%%g13%%h13%%i13%%j13%%k13%%l13%%m13%┤
echo    └┴┴┴┴┴┴┴┴┴┴┴┴┴┘
if %yx% equ 1 (
echo.&set /p xz=现在是[●],请下子:
echo !xz!>>bq.wzq
set yx=0) else (
echo.&set /p xz2=现在是[○],请下子:
echo !xz2!>>hq.wzq
set yx=1)
goto :home
复制代码

随风

先帮你简化一下棋盘吧。
那么多 echo
:

@echo off && setlocal enabledelayedexpansion
color 27 & mode con cols=35 lines=20
set BQ=●&set HQ=○&set KB=┼&set xz=0&set yx=1
del bq.wzq,hq.wzq>nul 2>nul
:home
for %%i in (a b c d e f g h i j k l m) do (
for %%j in (1 2 3 4 5 6 7 8 9 10 11 12 13)do (
set %%i%%j=%KB%))
for /f %%k in (bq.wzq) do (set %%k=%bq%)
for /f %%k in (hq.wzq) do (set %%k=%hq%)
cls&echo\&echo      ＡＢＣＤＥＦＧＨＩＪＫＬＭ
echo    ┌┬┬┬┬┬┬┬┬┬┬┬┬┬┐
for /l %%i in (1 1 10) do (
if %%i equ 10 (set /p= %%i├<nul) else set/p=  %%i├<nul
   for %%z in (a b c d e f g h i j k l m) do set/p=!%%z%%i!<nul
    set/p=┤<nul&echo.
)
echo    └┴┴┴┴┴┴┴┴┴┴┴┴┴┘
if %yx% equ 1 (
echo.&set /p xz=现在是[●],请下子:
echo !xz!>>bq.wzq
set yx=0) else (
echo.&set /p xz2=现在是[○],请下子:
echo !xz2!>>hq.wzq
set yx=1)
goto :home
复制代码

ieutk

不知道set xz=0这个有什么用?

黑子输入a1后，白子也可以输入a1，那就覆盖了原来的，这个也要解决

ranon

怎么玩?..........................

xxx3212

生成的临时文件太多了

随风

看看这个如何
http://bbs.bathome.net/viewthread.php?tid=820&extra=page%3D1

小竹

这个http://bbs.verybat.org/viewthrea ... ge=1&extra=

随风

呵呵。。。。

ak42d

写的是不错   可是有个bug 不知道有没有发现啊


不整齐啊   一开始  和最后几行 请看一下啊

batman

就是不能实现电脑智能和人机对栾(情况过于复杂，批处理难以胜任)：

@echo off&setlocal enabledelayedexpansion
rem 设置窗口大小及色彩----------------------------------------------------------------------
color 1f&mode con cols=55 lines=27
title 五子棋 by zw19750516 thanks for namejm
echo.&echo.&echo.&echo.&echo  程序载入中...
set "codes=A B C D E F G H I J K L M N O P Q R S"
set "code= %codes: =%"&set /a n=-1,m=0
rem ----------------------------------------------------------------------------------------

rem 获取电脑随机步数并乱序------------------------------------------------------------------
for /l %%a in (1,1,19) do (
    for /l %%i in (1,1,19) do (
        set "a=!code:~%%i,1!"&set /a num+=1
        set ".!num!=%%a!a!"
))
for /l %%i in (1,1,361) do (
    set /a a=!random!%%361+1
    call,set "b=%%.!a!%%"
    set ".!a!=!.%%i!"
    set ".%%i=!b!"
    set "a="&set "b="
)
rem ----------------------------------------------------------------------------------------

rem 走子大循环(输出棋盘)--------------------------------------------------------------------
:begin
set "num=%m%"
set /a n+=1,m+=1&if !m! equ 2 set m=0
if %m% equ 0 (set "zi=●"&set "vins=●●●●●") else (set "zi=○"&set "vins=○○○○○")
if defined vin set "zi=胜"
if defined auto (set "_!.%n%!=%zi%") else (set "_%a%%b%=%zi%")
echo.>temp.txt
echo ┌───────────────────┐>>temp.txt
for /l %%a in (1,1,19) do (
    for /l %%i in (1,1,19) do (
        if %%a equ 1 (
           if %%i equ 1 (
              set "_p=│┌"
              ) else (
              if %%i equ 19 (
                 set "_p=┐│"
                 ) else (
                 set "_p=┬"
           ))) else (
           if %%a equ 19 (
              if %%i equ 1 (
                 set "_p=│└"
                 ) else (
                 if %%i equ 19 (
                    set "_p=┘│"
                    ) else (
                    set "_p=┴"
              ))) else (
              if %%i equ 1 (
                 set "_p=│├"
                 ) else (
                 if %%i equ 19 (
                    set "_p=┤│"
                    ) else (
                    set "_p=┼"
        ))))  
        set str=!code:~%%i,1!
        if defined _%%a!str! (
           call :lop %%a %%i
           ) else (
           if %%i equ 19 (
              set /p=!_p!%%a<nul>>temp.txt
              ) else (
              set /p=!_p!<nul>>temp.txt
    )))
    echo.>>temp.txt
)
echo └───────────────────┘>>temp.txt
echo    %codes%>>temp.txt
cls&type temp.txt
rem ----------------------------------------------------------------------------------------

rem 选择走棋方式----------------------------------------------------------------------------
if defined hand goto step
if defined auto goto next
:choice
set /p select=请选择(1.人下 2.电脑下)：
if %select% equ 2 set "auto=a"&goto begin
if %select% equ 1 set "hand=a"&set /a n-=1&goto begin
goto wrong
:step
if defined vin goto next
if defined step (
   if %m% equ 0 (set /p=黑子下，<nul) else (set /p=白子下，<nul)
   echo 对手上一步走的：%step%<nul
   ) else (
   set /p=黑子先，<nul
)
set "ab="&set /p ab=请按纵、横顺序输入坐标(如：4h)：
rem ----------------------------------------------------------------------------------------

rem 判断人工输入是否正确-------------------------------------------------------------------
if not defined ab goto wrong
if "%ab:~1%" equ "" goto wrong
if "%ab:~3%" neq "" goto wrong
if "%ab:~2%" equ "" (set "a=%ab:~,1%"&set "b=%ab:~1%") else (set "a=%ab:~,2%"&set "b=%ab:~2,1%")
if "%a:~,1%" equ "0" goto wrong
echo %a%|findstr "[^0-9]">nul&&goto wrong
echo %b%|findstr "[0-9]">nul&&goto wrong
if %a% lss 1 goto wrong
if %a% gtr 19 goto wrong
if "!codes:%b%=!" equ "%codes%" goto wrong
if defined _%a%%b% goto wrong
set "step=%ab%"
rem ----------------------------------------------------------------------------------------

rem 输出结果--------------------------------------------------------------------------------
:next
del /q temp.txt
if defined vin (
   if %m% equ 0 (set /p=白子胜，<nul) else (set /p=黑子胜，<nul)
   echo 最后落子为：%a%%b%。
   pause>nul&exit
)
if %n% neq 361 (goto begin) else (echo 结果不分胜负!&pause>nul&exit)
rem ----------------------------------------------------------------------------------------

rem 判断是否胜出----------------------------------------------------------------------------
:lop
if %2 equ 1 (set "ll=set /p=│<nul>>temp.txt&") else (set "ll=")
if %2 equ 19 (set "rr=&set /p=│%1<nul>>temp.txt") else (set "rr=")
%ll%set /p=!_%1%str%!<nul>>temp.txt%rr%
if "%1%str%" equ "!.%n%!" set "a=%1"&set "b=%str%"&goto judge
if /i "%1%str%"=="%step%" goto judge
goto :eof
:judge
set "hang="&set "lie="&set "ls="&set "rs="&set "ss="&set "x=0"&set "y=0"&set "z=0"
set /a x1=%2-4,x2=%2+4,y1=%1+4,y2=%1-4
if %x1% lss 0 set "x1=0"
if %y2% lss 0 set "y2=0"
if %x2% gtr 19 set "x2=19"
if %y1% gtr 19 set "y1=19"
for /l %%i in (%x1%,1,%x2%) do set "ss=!ss! !code:~%%i,1!"
for %%i in (%ss%) do if defined _%1%%i (set "hang=!hang!!_%1%%i!") else (set "hang=!hang!#")
for /l %%i in (%y2%,1,%y1%) do if defined _%%i%str% (set "lie=!lie!!_%%i%str%!") else (set "lie=!lie!#")
for %%a in (%ss%) do (
    set /a x+=1,y=0,z=0
    for /l %%b in (%y1%,-1,%y2%) do (
        set /a y+=1
        if !x! equ !y! (
           if defined _%%b%%a (
              set "ls=!ls!!_%%b%%a!"
              ) else (
              set "ls=!ls!#"
    )))
    for /l %%c in (%y2%,1,%y1%) do (
        set /a z+=1
        if !x! equ !z! (
           if defined _%%c%%a (
              set "rs=!rs!!_%%c%%a!"
              ) else (
              set "rs=!rs!#"
))))
for %%i in (%hang% %lie% %ls% %rs%) do (
    set var=%%i
    if defined var if "!var:%vins%=!" neq "!var!" set /a n-=1&set "vin=a"&set "m=%num%"&goto begin
)
goto :eof
rem ----------------------------------------------------------------------------------------

rem 报错-----------------------------------------------------------------------------------
:wrong
set /p=错误，请正确输入。<nul&set "m=%num%"
ping /n 2 127.1>nul&set "a="&set "b="&set /a n-=1&goto begin
rem ----------------------------------------------------------------------------------------
复制代码

[ 本帖最后由 zw19750516 于 2008-7-19 13:23 编辑 ]

骚鸡

现在的这个不错了~~好像比随风的要好

tjtchly

10楼的太牛了。佩服。

gbw911

很好啊，就是少了点rem，这样才能让everyone看懂

zonixkula

太好了，上课时拿来解解闷。