[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发帖
yuboabc

Rank: 1

帖子
11 
积分
30 
技术
2  
捐助
0  
注册时间
2016-11-24 
1楼 跳转到 » 倒序看帖
打印
tT
发表于 2017-9-1 23:33 | 只看该作者

[文本处理] 读取剪贴板内容生成二维码

脚本使用的是百度的API，方便电脑与手机 pad等设备传递一些文字、连接信息。

感谢老刘的指导。。。
本人也是个渣，看代码就知道了。。。不过这个脚本用着还行。。。送给有需要的！
  1. @echo off

  2. if exist %tmp%\indexqr.html del /f/q %tmp%\indexqr.html >nul 2>nul

  3. >%tmp%\qr_getdata.vbs echo Call GetTextData

  4. >>%tmp%\qr_getdata.vbs echo function GetTextData

  5. >>%tmp%\qr_getdata.vbs echo Set objHTML=CreateObject("htmlfile")

  6. >>%tmp%\qr_getdata.vbs echo ClipboardText=objHTML.ParentWindow.ClipboardData.GetData("text")

  7. >>%tmp%\qr_getdata.vbs echo If VarType(ClipboardText)^<^>8 Or ClipboardText=Empty Then MsgBox "请复制一些内容再运行本程序^!",vbOKOnly + vbExclamation,"警告":exit function End If 

  8. >>%tmp%\qr_getdata.vbs echo Set fso=wscript.createobject("scripting.filesystemobject")

  9. >>%tmp%\qr_getdata.vbs echo Set file=fso.opentextfile("%tmp%\qr_data.txt",2,true)

  10. >>%tmp%\qr_getdata.vbs echo file.writeline ClipboardText

  11. >>%tmp%\qr_getdata.vbs echo end function:Wscript.Quit

  12. call %tmp%\qr_getdata.vbs

  13. if not exist %tmp%\qr_data.txt goto :eof

  14. >%tmp%\qr_UrlEncode.js echo var str=encodeURIComponent(WScript.Arguments(0));

  15. >>%tmp%\qr_UrlEncode.js echo WScript.echo(str);

  16. (for /f "usebackq delims=" %%i in ("%tmp%\qr_data.txt") do cscript -nologo %tmp%\qr_UrlEncode.js "%%i")>%tmp%\qr_urlcode.txt

  17. for /f %%i in (%tmp%\qr_urlcode.txt) do set n=%%i&call set m=%%m%%%%n%%%%%%0A

  18. >%tmp%\indexqr.html echo ^<html^>

  19. >>%tmp%\indexqr.html echo ^<head^>

  20. >>%tmp%\indexqr.html echo ^<title^>二维码生成^</title^>

  21. >>%tmp%\indexqr.html echo ^<script language=javascript^>function hero(){var herowidth=400;var heroheight=450;window.resizeTo(herowidth,heroheight)}hero();^</script^>	

  22. >>%tmp%\indexqr.html echo ^<script language=javascript^>^</script^>	

  23. >>%tmp%\indexqr.html echo ^<style type="text/css"^>body{overflow-x:hidden;overflow-y:hidden;text-align:center;}^</style^>		

  24. >>%tmp%\indexqr.html echo ^</head^>

  25. >>%tmp%\indexqr.html echo ^<body style="background:#C7C7C7" onresize=hero(); onkeypress=window.close() ^>

  26. >>%tmp%\indexqr.html echo ^<p style="text-align:center"^>^<img border="1" width="350" height="350" alt="按任意键关闭窗口" src="http://pan.baidu.com/share/qrcode?w=350&h=350&url=%m%"^>^</p^>

  27. >>%tmp%\indexqr.html echo ^<p style="text-align:center"^>^<b^>By.DcrClub^</b^>^</p^>

  28. >>%tmp%\indexqr.html echo ^</body^>

  29. >>%tmp%\indexqr.html echo ^</html^>

  30. start mshta "%tmp%\indexqr.html"

  31. del /f/q %tmp%\qr_* >nul 2>nul

  32. goto :eof
复制代码
是不是有点low。。。。这脚本写的！~~~

打包了一个exe文件。

链接: https://pan.baidu.com/s/19r6YRIChKNkgRuZc6nCTTg 提取码: nmnv
2

评分人数

收藏 分享

0000

Rank: 2

帖子
76 
积分
134 
技术
14  
捐助
0  
注册时间
2016-10-29 
2楼
发表于 2017-9-2 10:36 | 只看该作者
本帖最后由 0000 于 2017-9-3 12:47 编辑

觉得非常实用！
这代码风格......
  1. @echo off

  2. 

  3. >%tmp%\qr_getdata.vbs (

  4.   echo Set objHTML=CreateObject("htmlfile"^)

  5.   echo ClipboardText=objHTML.ParentWindow.ClipboardData.GetData("text"^)

  6.   echo If VarType(ClipboardText^)^<^>8 Or ClipboardText=Empty Then 

  7.   echo   MsgBox "请复制一些内容再运行本程序!",vbOKOnly + vbExclamation,"警告"

  8.   echo   WScript.Quit

  9.   echo End If 

  10.   echo Set fso=WScript.CreateObject("scripting.filesystemobject"^)

  11.   echo Set file=fso.OpenTextFile("%tmp%\qr_data.txt",2,true^)

  12.   echo file.WriteLine ClipboardText

  13.   echo WScript.Quit

  14. )

  15. call %tmp%\qr_getdata.vbs

  16. if not exist %tmp%\qr_data.txt goto :eof

  17. 

  18. >%tmp%\qr_UrlEncode.js (

  19.   echo var str=encodeURIComponent(WScript.Arguments(0^)^);

  20.   echo WScript.echo(str^);

  21. )

  22. 

  23. >%tmp%\qr_urlcode.txt (

  24.   for /f "usebackq delims=" %%i in ("%tmp%\qr_data.txt") do (

  25.     cscript -nologo %tmp%\qr_UrlEncode.js "%%i"

  26. ) )

  27. 

  28. for /f %%i in (%tmp%\qr_urlcode.txt) do (

  29.   set n=%%i

  30.   call set m=%%m%%%%n%%%%%%0A

  31. )

  32. 

  33. >%tmp%\indexqr.html (

  34.   echo ^<html^>

  35.   echo   ^<head^>

  36.   echo     ^<title^>二维码生成^</title^>

  37.   echo     ^<script language=javascript^>

  38.   echo function hero(^){

  39.   echo   var herowidth=400;

  40.   echo   var heroheight=450;

  41.   echo   window.resizeTo(herowidth,heroheight^)

  42.   echo }

  43.   echo hero(^);

  44.   echo     ^</script^>	

  45.   echo     ^<script language=javascript^>^</script^>	

  46.   echo     ^<style type="text/css"^>

  47.   echo body{

  48.   echo   overflow-x:hidden;

  49.   echo   overflow-y:hidden;

  50.   echo   text-align:center;

  51.   echo }

  52.   echo     ^</style^>		

  53.   echo   ^</head^>

  54.   echo   ^<body style="background:#C7C7C7" onresize=hero(^); onkeypress=window.close(^) ^>

  55.   echo     ^<p style="text-align:center"^>

  56.   echo       ^<img

  57.   echo         border="1"

  58.   echo         width="350"

  59.   echo         height="350"

  60.   echo         alt="按任意键关闭窗口"

  61.   echo         src="http://pan.baidu.com/share/qrcode?w=350&h=350&url=%m%"

  62.   echo       ^>

  63.   echo     ^</p^>

  64.   echo     ^<p style="text-align:center"^>

  65.   echo       ^<b^>By.DcrClub^</b^>

  66.   echo     ^</p^>

  67.   echo   ^</body^>

  68.   echo ^</html^>

  69. )

  70. 

  71. start mshta "%tmp%\indexqr.html"

  72. del /f/q %tmp%\qr_* >nul 2>nul

  73. goto :eof
复制代码

TOP

563406396

Rank: 1

帖子
7 
积分
21 
技术
0  
捐助
0  
注册时间
2014-10-13 
3楼
发表于 2017-9-2 20:26 | 只看该作者
点赞，很好用

TOP

fonyin

Rank: 1

帖子
11 
积分
25 
技术
0  
捐助
0  
注册时间
2022-9-28 
4楼
发表于 2022-9-29 22:52 | 只看该作者
回复 1# yuboabc


    ^<title^>二维码生成^</title^>

这里如何增加一个序号id呢                  ^<title^>二维码生成id^</title^>

TOP

返回列表