[文本处理] [已解决]批处理如何转换 for /f 提取文本中带环境变量的路径为实际对应路径

lonron

如图所示：Test.txt 文本中的第一列是带环境变量的路径（如：%UserProfile%\Desktop） 第二列是文件名（如：Test.exe）
那么：

for /f "skip=1 tokens=1,2" %%a in (Test.txt) do if exist %%a\%%b del /q %%a\%%b
复制代码

此时的%%a是字符串形式的 %UserProfile%\Desktop 而不是对应的 C:\Users\[用户名]\Desktop，请问这种情况要如何转换为实际路径，使后面的删除文件命令可以执行成功？

czjt1234

批处理本身就支持环境变量，不用特别转换

如果你不能成功删除

for /f "eol=＃ skip=1 tokens=2-6" %%b in (Test.txt) do @echo %%b\%%c

看看运行结果

lonron

回复 2# czjt1234


  
我知道cmd可以识别环境变量，但是for /f 的方式提取 Test.txt 文本中 路径 这段的时候，直接显示的结果就是 %UserProfile%\Desktop 而不会自动转成当前账户对应的 C:\Users\[用户名]\Desktop，所以导致我后面的判断失败不能删除 C:\Users\[用户名]\Desktop\测试.exe 文件。

lonron

回复 2# czjt1234


   

所以才想知道这种情况要怎么才能正确识别

77七

大概涉及到变量嵌套了，可以参考一下这个帖子，我也正在学习中...批处理中的变量嵌套变量用法

@echo off
for /f "skip=1 tokens=1,2" %%a in (Test.txt) do (
        call echo %%a\%%b
)
pause
复制代码

我能写出来，但是我也不是很清楚为什么要这样写
要是判断 可以call set m=%%a 在for语句里面判断需要开启延迟变量
更新

@echo off
for /f "skip=1 tokens=1,2" %%a in (Test.txt) do (
        call if exist %%a\%%b (
                echo 存在
        )
)
pause
复制代码

这样居然也可以

lonron

回复 5# 77七


    用call这个妙啊，不过我没明白你不是说判断的话要开启延迟变量吗，但是第二段示例好像没开也可以得到正确结果。

lonron

回复 5# 77七

@echo off
for /f "skip=1 tokens=1,2" %%a in (Test.txt) do (
        call if exist %%a\%%b (
                echo 存在
        )
)
pause
复制代码

@echo off
for /f "skip=1 tokens=1,2" %%a in (Test.txt) do call if exist %%a\%%b (echo 存在)
pause
复制代码

为什么换成下面这段就不正常了，显示if不是内部命令

77七

回复 6# lonron

把%%a赋值给m，在for语句里面判断 要开
直接判断就不用了

回复 7# lonron
写成多行吧，我也不明白

lonron

回复 8# 77七


    好的，我吸收下，感谢帮助

lonron

回复 8# 77七


    刚有测试了下，判断的那段代码虽然可以转换环境变量，但好像结果并不是正确的，如果我把目标文件改成别的名称它依然会显示“存在”。

terse

变通一下 for里这样

     call cd /d  %%a\
     if exist %%b del /q %%b
复制代码

     call cd /d  %%a\
     if exist %%b del /q %%b
复制代码

WHY

@echo off
for /f "skip=1 tokens=1-2" %%a in (Test.txt) do (
    call :Next %%a\%%b
)
pause & exit

:Next
if exist "%~1" echo;del "%~1"
复制代码

@echo off
for /f "skip=1 tokens=1-2" %%a in (Test.txt) do (
    for /f "delims=" %%i in ('echo;%%a\%%b') do (
        if exist "%%i" echo del "%%i"
    )
)
pause
复制代码

WHY

或者，不用if判断，直接删除

@echo off
for /f "skip=1 tokens=1-2" %%a in (Test.txt) do (
    call del "%%a\%%b" 2>nul
)
pause
复制代码

77七

回复 10# lonron

看来不能乱用，估计call把 if和echo当成两条命令了
楼上两位大神已提供教科书般答案，我在续写一下我昨晚提到的call set，如果开延迟变量，可以省略赋值n，把if写到for语句里面

@echo off
for /f "skip=1 tokens=1,2" %%a in (Test.txt) do (
        call set "m=%%a"
        set "n=%%b"
)
if exist "%m%\%n%" (
        echo 存在"%m%\%n%"
)
pause
复制代码