[游戏娱乐] 扫雷游戏雷区查看器

老刘1号

@Echo off&Mode 94,36&Pushd "%~dp0"&TITLE 【老刘制作】扫雷游戏雷区查看器
Set 第三方名称=ReadProcessMemory.exe Loca.exe
For %%a in (%第三方名称%) Do ^
If "%%~$PATH:a" EQU "" ^
If Not Exist .\%%a ^
Echo 第三方%%a丢失。&&Pause&&Exit
Setlocal	ENABLEDELAYEDEXPANSION
:Get
For /F "Tokens=2" %%a in ('Tasklist /FI "WINDOWTITLE eq 扫雷"') Do 2>nul Set /A PID=%%a
If !PID! EQU 0 GOTO Get
:Loop
Set /A 雷区=1
Set 输出=
For /f "Delims=" %%a in ('ReadProcessMemory !PID! 16798560 864') Do (
	For %%b in (%%a) Do (
		If %%b EQU 10 (
			If !雷区! EQU 1 (
				For /F "Delims=" %%. in ("!输出!") Do Echo %%.&&Echo.
				Set 输出=
			)
			Set /A "雷区^=1"
		)
		If !雷区! EQU 1 (
			If %%b NEQ 10 (
				Set "输出=!输出! %%b"
				Set "输出=!输出:0F=空!"
				Set "输出=!输出:8F=雷!"
				Set "输出=!输出:8E=旗!"
				Set "输出=!输出:8D=﹖!"
				Set "输出=!输出:0E=旗!"
				Set "输出=!输出:CC=×!"
				Set "输出=!输出:8A=×!"
				Set "输出=!输出:40=０!"
				Set "输出=!输出:41=１!"
				Set "输出=!输出:42=２!"
				Set "输出=!输出:43=３!"
				Set "输出=!输出:44=４!"
				Set "输出=!输出:45=５!"
				Set "输出=!输出:46=６!"
				Set "输出=!输出:47=７!"
				Set "输出=!输出:48=８!"
			)
		)
	)
)
Ping 127.1 -n 2 >nul
Loca 0,0&Goto Loop
复制代码

第三方下载：Loca(设置屏幕坐标) ReadProcessMemory
XP版扫雷下载：http://js.downcc.com/game/gametool/winmine.zip