[特效代码] 一句什么命令可屏蔽整个批处理的正常输出，不用每句后都>nul?

Cameron

在咱们论坛上见过一个类似的帖子，可现在怎么也找不到了。还请各位再讲一遍，或帮忙找出那个帖子,拜托了！

namejm

　　没有这样的语句，论坛也没有类似的帖子。

pusofalse

可以这样做：
打开cmd，输入批处理的名字，假设为a.bat，输入a.bat>nul，这样即可屏蔽所有标准输出。
利用这个思路，可以用下面的代码来实现：

@echo off
if "%~1" equ "" start/b %~fs0 a>nul&exit
echo test
ver
pause
exit
复制代码

本该显示如下信息：

test
Microsoft Windows XP [版本 5.1.2600]
请按任意键继续. . .
复制代码

但用了start/b %~fs0 a>nul即将所有的结果屏蔽。

yslyxqysl

rem 1>nul 3>nul

Cameron

我记得那个代码很简洁的，明明见过~

Batcher

这个？

@echo off
(echo a
echo b
echo c
echo d
)>nul
复制代码

Cameron

batcher的方法可以满足需求，thx！
不过还不是我见到的那个方法。

qql528

if "%~1" equ "" start/b %~fs0 a>nul&exit这句怎么理解啊.我一头雾水.~~~！刚开始看批处理
不懂，能解释下吗？

随风

@echo off
echo. 1>nul 3>nul
echo 标准输出已经全被屏蔽了
echo 这些内容看不见
echo 还是看不见。。
echo. 1>nul 4>con
echo 看见了。。。
echo 已经恢复了
pause
复制代码

[ 本帖最后由 随风 于 2008-10-16 19:56 编辑 ]

Cameron

哈，就是随风版主这个！谢了！我见的那个帖子是您发的吧？
另外，很喜欢你的签名！“上善若水，在能处下，能利万物而不争，夫唯不争，故天下莫能与之争！圣人之境，虽不能至，心向往之！”

再另外，还请解释下控制台设备文件及其参数。

[ 本帖最后由 Cameron 于 2008-10-16 20:11 编辑 ]

随风

当 批处理中有多处echo需要定向到文本中，可以使用这种方法，以使代码简化
如：、

@echo off
echo abcd>>a.txt
echo 1234>>a.txt
echo ldjfafj>>a.txt
echo 9f7jfa8fd>>a.txt
复制代码

可以这样

@echo off
echo. 1>nul 3>a.txt
echo abcd
echo 1234
echo ljfafja;f
echo flfjalfjadfa;
 
复制代码

[ 本帖最后由 随风 于 2008-10-16 20:07 编辑 ]

lolo

1 是正常输出
2 是错误输出

Quote:
句柄 句柄的数字代号 说明
STDIN 0 键盘输入
STDOUT 1 输出到命令提示符窗口
STDERR 2 错误输出到命令提示符窗口
UNDEFINED 3-9 这些句柄由应用程序和各个具体工具单独定义。

Cameron

高手很多嘛！
lolo能再详细些吗，或者给出在哪些资料上能查到。

zqz0012005

系统有自带的CMD手册：命令行参考

见我的签名

随风

看此帖
http://bbs.verybat.org/viewthrea ... a=page%3D1#pid81403