[文本处理] 批处理如何截取字符串到另外一个文本？[已解决]

帝尊

这里有很多行
字符A----------------A
随机字符
字符B----------------B
随机字符
字符C----------------C
随机字符
这里有很多行
复制代码

如何截取

字符A----------------A
随机字符
字符B----------------B
随机字符
字符C----------------C
随机字符
复制代码

这一段到另外一个文本？
不想要powershell和第三方。

帝尊

或者提取指定字符串与其下面一行的内容到另外一个文本。谢谢大佬。

flashercs

@echo off
cd /d "%~dp0"
set flag=
(
for /f "delims=" %%A in (1.txt) do (
  if not defined flag (
    if "%%~A"=="字符A----------------A" (
      set flag=1
    ) else if "%%~A"=="字符B----------------B" (
      set flag=1
    ) else if "%%~A"=="字符C----------------C" (
      set flag=1
    )
    if defined flag echo %%A
  ) else (
    echo %%A
    set flag=
  )
)
)>2.txt

pause
复制代码

帝尊

回复 3# flashercs


    非常感谢。

qixiaobin0715

@echo off
set var="字符A----------------A" "字符B----------------B" "字符C----------------C"
setlocal enabledelayedexpansion
(for /f "delims=" %%a in (1.txt) do (
    for %%i in (%var%) do (
        if "!str!"==%%i (
            echo,%%~i
            echo,%%a
        )
    )
    set str=%%a
))>2.txt
pause
复制代码

帝尊

回复 5# qixiaobin0715


    感谢，很好用。这个可以不让他区分大小写吗？

qixiaobin0715

回复 6# 帝尊
第6行修改：if /i "!str!"==%%i (

帝尊

回复 7# qixiaobin0715


     为什么地址加上双引号就失效了呢？有的时候地址有空格不是需要加上双引号吗？

qixiaobin0715

你在哪里加上双引号了？

帝尊

回复 9# qixiaobin0715

@echo off
set var="字符A----------------A" "字符B----------------B" "字符C----------------C"
setlocal enabledelayedexpansion
(for /f "delims=" %%a in ("UT IN/1.txt") do (
    for %%i in (%var%) do (
        if "!str!"==%%i (
            echo,%%~i
            echo,%%a
        )
    )
    set str=%%a
))>"UT IN/2.txt"
pause
复制代码

qixiaobin0715

你这样写代码，在第4行in后面的括号内，程序会以为这是一段字符串，当然会出错了。可在delims前加个usebackq，即"usebackq delims="。
请阅读论坛中关于for /f的教程。

帝尊

回复 11# qixiaobin0715


    好的。谢谢。非常感谢。我去看看。