[文件操作] [已解决]查找文件夹文本内容判断，符合条件则输出

czvde

文件夹中有3个文件：
123.txt
456.txt
abc.txt


123.txt

123

3
123
1
123
1
123
1
123
1
复制代码

456.txt

1
2
1111
3

1111
1

1111
1
1111
复制代码

abc.txt

1
2
1111
3
1

1
1111
1
复制代码

批处理运行之后，生成a.txt的文本内容为

123.txt
456.txt
复制代码

生成b.txt的文本内容为

123.txt
复制代码

已解决！

Batcher

回复 1# czvde


    大于10行算满足还是不满足？

czvde

回复 2# Batcher

查找的文件，文本内容有10行以上（包含10行）都把文件名输出到a.txt

Batcher

回复 3# czvde


    顶楼的例子里面456.txt有个空行，abc.txt也有个空行，为何一个满足另一个不满足？

czvde

回复 4# Batcher


    已修正abc.txt文本内容

went

@echo off & cd /d "%~dp0"
(
	for %%i in (*.txt) do (
		findstr /n .* %%i | findstr "^10" >nul 2>nul && echo %%i
	)
)>"a.txt"
pause&exit
复制代码

Batcher

回复 5# czvde


    如果abc.txt总行数是11，但是有2个空行，算满足吗？

czvde

回复 7# Batcher


   1楼已重新修改要求

qixiaobin0715

如果各个文本文件行数不多的话，可以考虑下面代码。未测试：

@echo off
set LineNum=10:
for /f "delims=" %%a in ('dir /b /a-d *.txt') do (
    findstr /n .* %%a|findstr /b %LineNum%>nul
    if not errorlevel 1 (
        echo,%%a>>a.txt
        findstr . %%a|findstr /n .|findstr /b %LineNum%>nul
        if not errorlevel 1 echo,%%a>>b.txt
    )
)
pause
复制代码

Batcher

回复 1# czvde

@echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
    for /f "delims=" %%j in ('type "%%i" ^| find /v /c ""') do (
        echo %%i [包含空行]: %%j
        if %%j geq 10 (
            >>"a.log" echo,%%i
            for /f "delims=" %%k in ('findstr . "%%i" ^| find /v /c ""') do (
                echo %%i [不包含空行]: %%k
                if %%k geq 10 (
                    >>"b.log" echo,%%i
                )
            )
        )
    )
)
复制代码