【已解决】批处理按规则转换js地址为网址

ZeronoFreya

最近发现一个不错的韩文网站，cg相当棒，但不提供下载，右键无效，但有网址

http://blog.naver.com/storyphoto/viewer.jsp?src=http%3A%2F%2Fcafefiles.naver.net%2F20101107_136%2Ftkddydghk_1289072032440J2czh_jpg%2Fwbody_004-winlian_tkddydghk.jpg
复制代码

转换为

http://cafefiles.naver.net/20101107_136/tkddydghk_1289072032440J2czh_jpg/wbody_004-winlian_tkddydghk.jpg
复制代码

就可以普通的显示CG了，
简单来说就是：

      http://blog.naver.com/storyphoto/viewer.jsp?src=      删除

     %3A    替换为  ：

     %2F    替换为  /



批处理的运行方式为：

在弹出的批处理窗口中 粘贴  原始 js 地址 ，隔3行 显示 转换后的  图片网址并复制到剪贴板

大概就这样，求教各位前辈

apang

@set @n=0;/* & echo off
set /p s=原始网址：
echo,&echo,&cscript -nologo -e:jscript %0 "%s%"
pause & exit/b & rem */
var s = WScript.Arguments(0);
s = s.replace(/.*src=(.*)/i, '$1');
s = s.replace(/%([\da-f]{2})/ig,
    function(s0,s1){return String.fromCharCode('0x'+s1)}
);
var Form = new ActiveXObject('Forms.Form.1');
with (Form.Controls.Add('Forms.TextBox.1').Object) {
    MultiLine = true;
    Text = s;
    SelStart = 0;
    SelLength = TextLength;
    Copy();
}
WScript.Echo(s + '\n已复制到剪切板')
复制代码

QIAOXINGXING

需要第三方nircmd.exe

@echo off&SetLocal EnableDelayEdexpansion&cd /d "%~dp0"
set /p str=paste:
set "str=!str:http://blog.naver.com/storyphoto/viewer.jsp?src=!"
set "str=!str:%%3A=:!"
set "str=!str:%%2F=/!"
set "str=!str:~1!"
nircmd clipboard set !str!
echo;
echo;
echo;
echo !str!
pause>nul
复制代码

522235677

回复 3# QIAOXINGXING

    @echo off&SetLocal EnableDelayEdexpansion&cd /d "%~dp0"
set /p str=paste:
set "str=!str:http://blog.naver.com/storyphoto/viewer.jsp?src=!"
set "str=!str:%%3A=:!"
set "str=!str:%%2F=/!"
set "str=!str:~1!"
mshta vbscript:clipboardData.SetData("text","!str!")(close)
echo;
echo;
echo;
echo !str!
pause>nul
复制代码

QIAOXINGXING

回复  QIAOXINGXING
522235677 发表于 2014-5-17 15:23

    谢谢哈。。
我基本不会vbs，觉得nircmd挺强大，平时基本都用这个命令。。。

ZeronoFreya

回复 4# 522235677


    感谢，转换无异常！

ZeronoFreya

回复 2# apang

原始网址：http://blog.naver.com/storyphoto/viewer.jsp?src=http%3A%2F%2Fcafefiles
.naver.net%2F20101107_136%2Ftkddydghk_1289072032440J2czh_jpg%2Fwbody_004-winlian
_tkddydghk.jpg


D:\system\Desktop\han.bat(10, 1) Microsoft JScript 运行时错误: Automation 服务器
不能创建对象

请按任意键继续. . .
复制代码

汇报下结果！感谢关注！

terse

既然mshta话就直接函数啦

@echo off
set /p url=输入网址：
mshta "javascript:var s='%url%';clipboardData.setData('text',decodeURIComponent(s.replace(/^.*src=?/,'')));close();"
复制代码