[文本处理] 【已解决】BAT:随机读取文本数据，组合成新的文本

思想之翼

有210个文件夹，分别命名为001-210；每个文件夹内有20个txt文本，分别命名为01-20；每个txt文本记录一行数据，格式统一为00 12 54 89 05 36 63 77

现在欲从210个文件夹内，分别随机读取一个txt文本的数据，组合成210行数据，写入新建的txt文本。格式如下：
93 51 06 23 87 93 58 69 （001文件夹内随机读取的txt文本数据）
54 42 28 96 70 41 62 08 （002文件夹内随机读取的txt文本数据）
51 91 92 18 18 01 66 13 （003文件夹内随机读取的txt文本数据）
27 77 38 57 39 84 28 40 （004文件夹内随机读取的txt文本数据）
...
这样的BAT如何写？

522235677

@echo off & setlocal enabledelayedexpansion
for /l %%a in (1 1 210) do (
	if %%a lss 10 set f=00%%a
	if %%a lss 100 (if %%a gtr 9 set f=0%%a) else (set f=%%a)
	set /a rn=!random!%%20+1
	if !rn! lss 10 set rn=0!rn!
	(for /f "delims=" %%b in (!f!\!rn!.txt) do echo %%b （!f!文件夹内随机读取的txt文本数据）)>>1.txt
)
pause
复制代码

思想之翼

回复 2# 522235677

如果：每个文件夹内有300个txt文本，分别命名为001-300
上述代码修改为：
set /a rn=!random!%%300+1
就可以了吗？

522235677

回复 3# 思想之翼

@echo off & setlocal enabledelayedexpansion
for /l %%a in (1 1 210) do (
        if %%a lss 10 set f=00%%a
        if %%a lss 100 (if %%a gtr 9 set f=0%%a) else (set f=%%a)
        set /a rn=!random!%%300+1
        if !rn! lss 10 set rn=00!rn!
        if !rn! lss 100 if !rn! gtr 9 set f=0%%a
        (for /f "delims=" %%b in (!f!\!rn!.txt) do echo %%b （!f!文件夹内随机读取的txt文本数据）)>>1.txt
)
pause
复制代码

思想之翼

回复 4# 522235677

210个文件夹的名称：001-210
每个文件夹内的文本名称：001-999

代码：

@echo off & setlocal enabledelayedexpansion
for /l %%a in (1 1 210) do (
        if %%a lss 10 set f=00%%a
        if %%a lss 100 (if %%a gtr 9 set f=0%%a) else (set f=%%a)
        set /a rn=!random!%%999+1
        if !rn! lss 10 set rn=00!rn!
        if !rn! lss 100 if !rn! gtr 9 set f=0%%a
        (for /f "delims=" %%b in (!f!\!rn!.txt) do echo %%b （!f!文件夹内随机读取的txt文本数据）)>>1.txt
)
pause
复制代码

发生如下问题：

Batcher

回复 5# 思想之翼


        if %%a lss 10 set f=00%%a
        if %%a lss 100 (if %%a gtr 9 set f=0%%a) else (set f=%%a)
这两个if判断存在逻辑错误，你看看%%a等于1的时候，f被赋值成什么数字就知道了。

Batcher

回复 4# 522235677


使用 else if 结构，可以避免逻辑错误，并提高效率。

@echo off
setlocal enabledelayedexpansion
(for /l %%a in (1 1 210) do (
    if %%a lss 10 (
        set f=00%%a
    ) else if %%a lss 100 (
        set f=0%%a
    ) else (
        set f=%%a
    )
    set /a rn=!random!%%300+1
    if !rn! lss 10 (
        set rn=00!rn!
    ) else if !rn! lss 100 (
        set f=0%%a
    )
    for /f "delims=" %%b in (!f!\!rn!.txt) do (
        echo %%b （!f!文件夹内随机读取的txt文本数据）
    )
))>1.txt
复制代码

522235677

回复 6# Batcher


    哦，是没想到这个问题。多谢纠正

思想之翼

回复 7# Batcher

43 （006文件夹内随机读取的txt文本数据）
77 （007文件夹内随机读取的txt文本数据）
60 （018文件夹内随机读取的txt文本数据）
03 （030文件夹内随机读取的txt文本数据）
66 （034文件夹内随机读取的txt文本数据）
83 （035文件夹内随机读取的txt文本数据）
66 （062文件夹内随机读取的txt文本数据）
67 （065文件夹内随机读取的txt文本数据）
32 （076文件夹内随机读取的txt文本数据）
43 （080文件夹内随机读取的txt文本数据）
43 （095文件夹内随机读取的txt文本数据）
09 （097文件夹内随机读取的txt文本数据）
09 （119文件夹内随机读取的txt文本数据）
83 （132文件夹内随机读取的txt文本数据）
60 （146文件夹内随机读取的txt文本数据）
67 （149文件夹内随机读取的txt文本数据）
09 （151文件夹内随机读取的txt文本数据）
66 （164文件夹内随机读取的txt文本数据）
32 （171文件夹内随机读取的txt文本数据）
83 （173文件夹内随机读取的txt文本数据）
43 （195文件夹内随机读取的txt文本数据）
03 （198文件夹内随机读取的txt文本数据）
75 （201文件夹内随机读取的txt文本数据）
上述是001-210个文件夹、每个文件夹内有001-100个txt的随机取样，取样不全。
要求是从001-210个文件夹内，分别提取任意一个txt，组合成一个210行的新文本txt
烦请帮助看看代码错在哪了。

xxpinqz

@echo off&setlocal enabledelayedexpansion
set 文件数=100
(for /l %%a in (1001 1 1210) do (
    set /a rn=!random!%%文件数+1001,f=%%a
    for /f "delims=" %%b in (!f:~-3!\!rn:~-3!.txt)do echo,%%b
))>new.txt
复制代码

@echo off&setlocal enabledelayedexpansion
set 文件数=20
(for /l %%a in (1001 1 1210) do (
    set /a rn=!random!%%文件数+101,f=%%a
    for /f "delims=" %%b in (!f:~-3!\!rn:~-2!.txt)do echo,%%b
))>new.txt
复制代码

注意看下两个代码的2,4,5行的区别
7楼代码第15行

        set f=0%%a
复制代码

改为

set rn=0!rn!
复制代码