[文件操作] 【求助】删除空目录批处理命令

少马石

请教，在删除空目录后，如何将删除结果自动保存为一个txt文件呢？谢谢

@echo off
setlocal enabledelayedexpansion
mode con cols=66 lines=20
set /a sum=0
echo.
use>nul
echo.
echo ------------------------------------------------------------------
echo.
for /l %%i in (1 1 10) do (
for /f "delims=" %%i in ('dir /ad /b /s') do (
dir /b "%%i"|findstr .>nul||rd "%%i"&&echo 成功删除空文件夹：%%i&&set /a sum=sum+1
)

)
echo.
echo ------------------------------------------------------------------
echo.
echo      共删除%cd%目录下 空文件夹个数：%sum%
echo.
echo.
#echo    按任意键退出
#pause>nul
set sum=
exit
复制代码

77七

@echo off
rem 保存为ansi
cd /d "%~dp0"
set n=0
(
	for /f "delims=" %%i in ('dir /b /s /ad ^|sort /r') do (
		rd "%%i" 2>nul
		if not exist "%%i" (
			set /a n+=1
			echo 成功删除空文件夹：%%i
		)
	)
	call echo 共删除%cd%目录下 空文件夹个数：%%n%%
)>"log.txt"
pause
复制代码

少马石

77七 发表于 2024-7-30 19:59

导出log文件。能不能改一下。自动命名为logx年x月x日x时x分.txt。。log中最好记录一下删除目录的具体路径和名称

77七

回复 3# 少马石

@echo off
rem 保存为ansi
cd /d "%~dp0"
set n=0
for /f %%a in ('wmic os get localdatetime ^|findstr [0-9]') do (
	set t=%%a
)
(
	for /f "delims=" %%i in ('dir /b /s /ad ^|sort /r') do (
		rd "%%i" 2>nul
		if not exist "%%i" (
			set /a n+=1
			echo 成功删除空文件夹，路径:[%%~dpi] 名称:[%%~nxi]
		)
	)
	call echo 共删除%cd%目录下 空文件夹个数：%%n%%
)>"log%t:~0,4%年%t:~4,2%月%t:~6,2%日%t:~8,2%时%t:~10,2%分.txt"
pause
复制代码

少马石

回复 4# 77七
谢谢你的热情帮助，不过发现一点问题。
2楼的命令日志是乱码，4楼的命令提示语法错误。

77七

回复 5# 少马石


   
把批处理文件保存为ansi编码格式试试。

Batcher

回复 5# 少马石


请参考Q-04把bat文件保存为ANSI编码：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA
如图所示：
http://bbs.bathome.net/thread-67347-1-1.html#pid273985

少马石

回复 6# 77七
果然如此。。再次感谢，完美解决。

少马石

回复 7# Batcher
用NotePad转码后完美解决，谢谢指导