[注册表类] [已解决]批处理怎样显示计算机名、ip地址、子网掩码、网关信息？

ygqiang

请直接看19楼的1个小问题

set /p name=请输您的计算机名：

         
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\ComputerName\ComputerName" /v "ComputerName" /t reg_sz /d %name% /f >nul 2>nul
reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Control\ComputerName\ActiveComputerName" /v "ComputerName" /t reg_sz /d %name% /f >nul 2>nul

reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\Tcpip\Parameters" /v "NV Hostname" /t reg_sz /d %name% /f >nul 2>nul
reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\Tcpip\Parameters" /v "Hostname" /t reg_sz /d %name% /f >nul 2>nul



reg add "HKLM\SYSTEM\ControlSet001\Control\ComputerName\ActiveComputerName" /v "ComputerName" /t REG_SZ /d "%name%" /f
reg add "HKLM\SYSTEM\ControlSet001\Services\Tcpip\Parameters" /v "NV Hostname" /t REG_SZ /d "%name%" /f
reg add "HKLM\SYSTEM\ControlSet001\Services\Tcpip\Parameters" /v "Hostname" /t REG_SZ /d "%name%" /f
reg add "HKLM\SYSTEM\ControlSet002\Control\ComputerName\ComputerName" /v "ComputerName" /t REG_SZ /d "%name%" /f



set/p slection1=请输入IP地址（只输最后1位）： 
netsh interface ip set address name="本地连接" source=static addr="10.10.94.%slection1%" mask=255.255.255.0 gateway=10.10.94.1 gwmetric=1




wmic computersystem where Name="%COMPUTERNAME%" call JoinDomainOrWorkgroup Name="LIBYW"
echo 修改工作组完毕



ipconfig/all
pause


exit
复制代码

有个问题请教：

有什么批处理命令，只显示出  计算机名  ip地址  子网掩码  网关  子网的信息？（用ipconfig/all显示的信息太多、太杂乱）

Batcher

用findstr命令过滤一下

601997526

@echo off
ipconfig/all|findstr /c:"Host Name"
ipconfig/all|findstr /c:"IP Address"
ipconfig/all|findstr /c:"Subnet Mask"
ipconfig/all|findstr /c:"Default Gateway"
ipconfig/all|findstr /c:"DNS Servers"
pause
复制代码

dennisle

@ECHO OFF&Setlocal EnableDelayedExpansion
FOR /F "tokens=1,2* delims==" %%A IN ('WMIC Path Win32_ComputerSystem Get Domain^,Name /Value 2^>Nul') DO (
    IF /I "%%A"=="Domain" SET "Domain=%%B"
    IF /I "%%A"=="Name" SET "Name=%%B"&ECHO.電腦名稱: !Name:~,-1!&ECHO.工作群組: !Domain:~,-1!
)
FOR /F "tokens=1,2* delims=={,}" %%A IN ('WMIC NICConfig WHERE "IPEnabled=TRUE" GET DefaultIPGateway^,Description^,DNSServerSearchOrder^,IPAddress^,IPSubnet /value 2^>Nul') DO (
    IF /I "%%A"=="DefaultIPGateway" SET "Gateway=%%B"
    IF /I "%%A"=="Description" SET "CardName=%%B"
    IF /I "%%A"=="DNSServerSearchOrder" SET "DNS=%%B"
    IF /I "%%A"=="IPAddress" SET "IP=%%B"
    IF /I "%%A"=="IPSubnet" SET "Subnet=%%B"&ECHO.網卡名稱: !CardName:~,-1!&ECHO.IP  位址: !IP:~1,-1!&ECHO.網路遮罩: !Subnet:~1,-1!&ECHO.預設閘道: !Gateway:~1,-1!&ECHO.DNS 服務: !DNS:~1,-1!&ECHO.
)
ECHO.                            Press any key to exit...
PAUSE >Nul
复制代码

ygqiang

@echo off
ipconfig/all|findstr /c:"Host Name"
ipconfig/all|findstr /c:"IP Address"
ipconfig/all|findstr /c:"Subnet Mask"
ipconfig/all|findstr /c:"Default Gateway"
ipconfig/all|findstr /c:"DNS Ser ...
601997526 发表于 2011-6-10 12:52

这个可以解决问题。谢谢

还有个问题，如何加上 显示组名？

Batcher

5# ygqiang

systeminfo
复制代码

ygqiang

systeminfo

这个命令，好像没有显示工作组的方法？

dennisle

7# ygqiang

樓主可能需要修改一下標題，
不妨試試4樓代碼!!

Batcher

7# ygqiang


我试了一下，有。

ygqiang

7# ygqiang

樓主可能需要修改一下標題，
不妨試試4樓代碼!!
dennisle 发表于 2011-6-13 08:05

4楼代码不错。

修改如下：

echo ------------修改后的结果:------------
@ECHO OFF&Setlocal EnableDelayedExpansion
FOR /F "tokens=1,2* delims==" %%A IN ('WMIC Path Win32_ComputerSystem Get Domain^,Name /Value 2^>Nul') DO (
    IF /I "%%A"=="Domain" SET "Domain=%%B"
    IF /I "%%A"=="Name" SET "Name=%%B"&ECHO.计算机名----: !Name:~,-1!&ECHO.工作组------: !Domain:~,-1!
)
FOR /F "tokens=1,2* delims=={,}" %%A IN ('WMIC NICConfig WHERE "IPEnabled=TRUE" GET DefaultIPGateway^,Description^,DNSServerSearchOrder^,IPAddress^,IPSubnet /value 2^>Nul') DO (
    IF /I "%%A"=="DefaultIPGateway" SET "Gateway=%%B"
    IF /I "%%A"=="Description" SET "CardName=%%B"
    IF /I "%%A"=="DNSServerSearchOrder" SET "DNS=%%B"
    IF /I "%%A"=="IPAddress" SET "IP=%%B"
    IF /I "%%A"=="IPSubnet" SET "Subnet=%%B"&ECHO.IP地址------: !IP:~1,-1!&ECHO.子网掩码----: !Subnet:~1,-1!&ECHO.网关--------: !Gateway:~1,-1!&ECHO.DNS---------: !DNS:~1,-1!&ECHO.
)
ECHO.                            Press any key to exit...
PAUSE >Nul
复制代码

ygqiang

修改代码如下：

@ECHO OFF

set Addr=192.168.9
set Mask=255.255.255.128
set Gway=192.168.9.1
set usergroup=admin


netsh -C interface dump>home.txt

NETDOM.exe MEMBER /JOINWORKGROUP %usergroup%



set /p name=请输入计算机名：

reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\ComputerName\ComputerName" /v "ComputerName" /t reg_sz /d %name% /f >nul 2>nul
reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Control\ComputerName\ActiveComputerName" /v "ComputerName" /t reg_sz /d %name% /f >nul 2>nul

reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\Tcpip\Parameters" /v "NV Hostname" /t reg_sz /d %name% /f >nul 2>nul
reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\Tcpip\Parameters" /v "Hostname" /t reg_sz /d %name% /f >nul 2>nul


reg add "HKLM\SYSTEM\ControlSet001\Control\ComputerName\ActiveComputerName" /v "ComputerName" /t REG_SZ /d "%name%" /f
reg add "HKLM\SYSTEM\ControlSet001\Services\Tcpip\Parameters" /v "NV Hostname" /t REG_SZ /d "%name%" /f
reg add "HKLM\SYSTEM\ControlSet001\Services\Tcpip\Parameters" /v "Hostname" /t REG_SZ /d "%name%" /f
reg add "HKLM\SYSTEM\ControlSet002\Control\ComputerName\ComputerName" /v "ComputerName" /t REG_SZ /d "%name%" /f




set/p slection1=请输入IP地址（只输最后1位）： 


::用ipconfig /all命令获取网卡名称。
FOR /F "tokens=2*" %%i IN ('ipconfig/all^|find /i "Ethernet adapter "') DO set name=%%j
::用for命令删除网卡名称后面的冒号。
FOR /F "tokens=1* delims=:" %%i in ("%name%") do set a=%%i

netsh interface ip set address name="%a%" source=static addr="%Addr%.%slection1%" mask=%Mask% gateway=%Gway% gwmetric=1 >nul 2>nul


netsh interface ip delete dns "%a%" all >nul 2>nul


ipconfig /flushdns >nul 2>nul



echo ------------修改后的结果:------------
@ECHO OFF&Setlocal EnableDelayedExpansion
FOR /F "tokens=1,2* delims==" %%A IN ('WMIC Path Win32_ComputerSystem Get Domain^,Name /Value 2^>Nul') DO (
    IF /I "%%A"=="Domain" SET "Domain=%%B"
    IF /I "%%A"=="Name" SET "Name=%%B"&ECHO.计算机名----: !Name:~,-1!&ECHO.工作组------: !Domain:~,-1!
)
FOR /F "tokens=1,2* delims=={,}" %%A IN ('WMIC NICConfig WHERE "IPEnabled=TRUE" GET DefaultIPGateway^,Description^,DNSServerSearchOrder^,IPAddress^,IPSubnet /value 2^>Nul') DO (
    IF /I "%%A"=="DefaultIPGateway" SET "Gateway=%%B"
    IF /I "%%A"=="Description" SET "CardName=%%B"
    IF /I "%%A"=="DNSServerSearchOrder" SET "DNS=%%B"
    IF /I "%%A"=="IPAddress" SET "IP=%%B"
    IF /I "%%A"=="IPSubnet" SET "Subnet=%%B"&ECHO.IP地址------: !IP:~1,-1!&ECHO.子网掩码----: !Subnet:~1,-1!&ECHO.网关--------: !Gateway:~1,-1!&ECHO.
)
ECHO.                            Press any key to exit...
PAUSE >Nul

exit
复制代码

这个代码，遇到2个问题。

1、虽然计算机名已经修改成功，但显示“修改后的结果”的时候，显示的还是旧的计算机名。
这个如何通过批处理刷新下系统？或者刷新下注册表？来显示正确的？
2、“修改后的结果”显示的时候，DNS只显示1个，如何让2个DNS同时显示出来?

ygqiang

出现2个小问题,顶一下...

ygqiang

各位帮忙解决下啊？谢谢

qzwqzw

计算机名修改与全局环境更新一样
都需要向窗口进程发送系统配置更新消息
我尚未看到完全的解决解决方案

目前最好的方案大概还是直接重启吧

ygqiang

多谢楼上。

DNS如何将2个都显示在屏幕上呢？