[文件操作] 批处理搜索全盘指定相同文件夹（文件）名导出路径到txt，并结尾标明多少个

吴彦祖

【已解决】例如我想要知道我的电脑有多少个包含56002名的文件

Batcher

回复 1# 吴彦祖

@echo off
set "OutFile=结果.txt"
type nul >"%OutFile%"
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist %%a:\ (
        echo 正在查找 %%a 盘
        dir /b /s %%a:\*56002* >>"%OutFile%"
    )
)
for /f %%a in ('type "%OutFile%" ^| find /c /v ""') do (
    set "RowNum=%%a"
)
echo 个数：%RowNum%
pause
复制代码

lancer

本批处理可以查询指定路径下某个文件夹数量，不区分文件夹名大小写

@echo off
echo 统计文件夹内全部文件夹数量，包含子文件夹
echo.
set DstFolder=%~dp0
setlocal enabledelayedexpansion
set /p "DstFolder= 要统计的文件夹路径，直接回车则默认为批处理所在路径："
echo.& echo 当前路径为 %DstFolder% &echo.
set /p "FileType= 输入文件夹名（不区分大小写）："
cd /d "%DstFolder%"
echo.& echo 正在查询文件夹数量，请稍等。。。。。。。
set num=0
for /f "delims=" %%i in ('dir /ad /b /s') do (
set "FileName=%%~nxi"
for %%j in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
set "FileName=!FileName:%%j=%%j!"
)
if "!FileName!" equ "%FileType%" （
echo %%i>>d:\temp.txt
set /a num+=1
)
echo.
echo %DstFolder% 目录下一共有：%num% 个%FileType%文件夹
setlocal disabledelayedexpansion
echo.&pause
复制代码

吴彦祖

回复 2# Batcher


    谢谢大哥

吴彦祖

回复 3# lancer


    谢谢大哥