[文件操作] [已解决]批处理可以在每个网页的下面加上上一页、下一页、目录页吗？

hellowbat

有很多html网页，之前用ebook做电子书可以做出，上一页    下一页 目录页的效果！！

但是他是生成chm的格式！！

请问批处理可以 做出这样的效果吗？

在每个网页的下面 加上 上一页    下一页    目录页 以便方便浏览！

基本特征规则是这样的！比如当前浏览的是 4.html 那么他的上一页就是3.html 下一页就是5.html

<a href="3.html">上一页</a>
<a href="index.html">目录页</a>
<a href="5.html">下一页</a>

谢谢大家！！

hellowbat

请问 有高手帮看一下吗 ?
应该是可以做到的，只不过偶技术很菜，希望高手帮忙。

hellowbat

分区版主在吗

hellowbat

论坛现在和这个寒冷的冬季一样冷啊

hellowbat

谁帮啊我 博个好彩头 ,坛友们2015元旦快乐

yu2n

样板在哪里？

hellowbat

回复楼上  ！！！样本在这里
http://www.meiguhulan.com/upnews/article003.htm
很多html网页做成模板形式 ，让他们自动装订成册！让每一页 有  上一页  下一页 目录 这3个按钮

CrLf

以7楼为例是这样

@echo off&setlocal enabledelayedexpansion
set n=0
for /f "delims=" %%a in ('dir /b article???.htm') do (
	set /a n+=1
	set "htm[!n!]=%%a"
)

for /l %%a in (1 1 !n!) do (
	set /a last=%%a-1,next=%%a+1
	for /f "tokens=1,2" %%b in ("!last! !next!") do set last=!htm[%%b]!&set next=!htm[%%c]!

	echo ^<div  align=right^>
	if %%a gtr 1 echo ^<a href="!last!"^>上一页^</a^>
	echo ^<a href="index.htm"^>目录页^</a^>
	if %%a lss !n! echo ^<a href="!next!"^>下一页^</a^>
	echo ^</div^>
)>>!htm[%%a]!
pause
复制代码

以顶楼为例则是

@echo off&setlocal enabledelayedexpansion

for /f "delims=" %%a in ('dir /b *.html') do (
	set /a n=%%~na,last=n-1,next=n+1

	echo ^<div  align=right^>
	if exist !last!.html echo ^<a href="!last!.html"^>上一页^</a^>
	echo ^<a href="index.html"^>目录页^</a^>
	if exist !next!.html echo ^<a href="!next!.html"^>下一页^</a^>
	echo ^</div^>
)>>%%a
pause
复制代码

CrLf

chm 可以用 hh.exe 解包
http://www.bathome.net/viewthread.php?tid=413

hellowbat

谢谢 crlf  !!!  没想到这么久的  帖子得到关注!!

祝福  坛友家家喜气洋洋,出门得意洋洋,见面神采飞扬,工作斗志昂扬,事业扬帆起航,生活阳光明媚

CrLf

回复 10# hellowbat


    主要还是有样本
    顺便修改一下，第二个代码之前忘了判断是否首尾章节

caruko

@echo off&setlocal enabledelayedexpansion
for %%a in (*.html) do (
    set /a last=%%~na-1,next=%%~na+1
    ren %%a %%a.bak
    echo,^<a href="!lase!.html"^>上一页^</a^> ^<a href="index.html"^>目录页^</a^> ^<a href="!next!.html"^>下一页^</a^> >_$
    copy %%a.bak+_$ %%a
)
rem 是否删除原文件      del *.bak /s /q  
复制代码