[文本处理] 服务器环境，bat中使用ftp出现乱码

踏沙行

制作了一个远程备份脚本，在windows 7 环境下执行正常。
然后拷贝到服务器(widows server 2012 r2)上，想实现每天定时执行备份。
但是一运行，就出现乱码。
经检查发现，是执行ftp的cd和lcd时，将中文目录名识别为了？？？
请问，有什么解决办法？
谢谢。

@echo off
:: 指定远程服务器IP、自己的登录用户名、密码
set "ftpIP=10.8.*.* 212"
set "ftpUser=******"
set "ftpPass=******"

:: 自定义服务器上有效的备份目录源（某些目录、数据无用、无效）
:: 目前可用的目录有4个，配置到Sr4。
::【注意】后面两次 for /l 中的步进结果为4，是和这里一致的。如果你需要更多目录，这3处的数量必须一致。
set "Sr1=工资统发"
set "Sr2=非税收入"
set "Sr3=支付账务"
set "Sr4=预算执行"

:: 指定日期变量、本地主目录、远程数据源目录、Ftp脚本文件
set "DateVbs=%Temp%\Curdate.vbs"
set "LocalDir=D:\数据备份"
set "FtpScript=%Temp%\FtpScript.txt"

:: 通过vbs的script隐藏窗口返回日期，获取准确的日期(昨日)格式，以保证ftp备份的文件名准确，避免失败。
:: 在vbs中，对执行符号（或成对的执行符号中的第2个符号），要使用^来转义，防止的bat中被直接执行而导致Vbs脚本执行失败。
(echo Dt=date(^)-1
echo,strDate = right(year(DT^),4^)^& "-" ^& right("0" ^& month(DT^),2^) ^& "-" ^& right("0" ^& day(DT^),2^)
echo,WScript.Echo strDate)>%DateVbs%

for /f "delims=" %%a in ('cscript /nologo %DateVbs%') do call set "CurDate=%%a"
set "tYear=%CurDate:~0,4%"
set "tMon=%CurDate:~5,2%"
set "tDay=%CurDate:~8,2%"

:: ftp脚本内容，特别说明：
:: 1、远程服务器上的目录问题：有的存在年份目录如2021，有的没年份目录，所以对远程服务器的内容目录要执行2次，一次不带有年份，一次带有年份。
:: 2、远程服务器上的文件名问题：有的使用年月日无分隔如20210212，有的使用"-"、有的使用"_"分隔。为防止遗漏，则各执行3次。
:: 3、重复执行，是因为无法通过指令获取到返回信息，从而进行选择，只好重复执行（如果你有获取指令的方法，请告诉我）。不过重复的过程中，一旦发现有错则会很快停止该指令，几乎不影响备份工作效率。

setlocal enabledelayedexpansion
:: 自动创建新的年度目录（如果存在则不执行），不必每年创建一次。
for /l %%i in (1,1,4) do (
md %LocalDir%\!Sr%%i!\%tYear% >nul 2>nul
)

> %FtpScript% (
    call echo open %ftpIP%
    call echo %ftpUser%
    call echo %ftpPass%
    call echo bin
    for /l %%i in (1,1,4) do (            
            call echo,cd /!Sr%%i!
            call echo,lcd %LocalDir%\!Sr%%i!\%tYear%
            call echo,mget *%tYear%%tMon%%tDay%.*
            call echo,mget *%tYear%-%tMon%-%tDay%.*
            call echo,mget *%tYear%_%tMon%_%tDay%.*

            call echo,cd /!Sr%%i!/%tYear%
            call echo,lcd %LocalDir%\!Sr%%i!\%tYear%
            call echo,mget *%tYear%%tMon%%tDay%.*
            call echo,mget *%tYear%-%tMon%-%tDay%.*
            call echo,mget *%tYear%_%tMon%_%tDay%.*    
    )
    call echo close
    call echo bye
  )
setlocal disabledelayedexpansion
ftp -v -i -s:%FtpScript%

del  /f /q %DateVbs%
del  /f /q %ftpScript%
echo,---------OK-------
复制代码