[其他] [已解决]批处理使用管道后，如何捕获errorlevel？

shootman2

假如使用了管道符后，再去捕获errorlevel时发现，其值已变为0，即便之前的命令是否返回0。
如下代码

call myCommand.bat|mtee /d /t /+ sysLog.log

如果调用myCommand.bat后返回errorlevel值为1，但是执行如上代码后，errorlevel值又变为0了，
求大神帮助！！！

bailong360

(call myCommand.bat&Set ExitCode=!ErrorLevel!)|mtee /d /t /+ sysLog.log
这样呢?

shootman2

回复 2# bailong360

我试过了，不行的！

bailong360

call myCommand.bat&>$tmp.txt Echo;!ErrorLevel!|mtee /d /t /+ sysLog.log
Set /P ExitCode=<$tmp.txtCOPY

那就这样吧

shootman2

回复 4# bailong360


    还是没有达到我想要的结果，errorlevel是获取正确了，但是没有正确的将打印结果输出到sysLog.log文件中

CrLf

管道中不允许有独立的内部命令或代码块，所以这个 call myCommand.bat|mtee /d /t /+ sysLog.log 相当于

cmd /c call myCommand.bat|mtee /d /t /+ sysLog.logCOPY

而只要是外部命令，一定会改变退出码，所以你取到的永远是 mtee 的退出码

至于怎么解决...这里举一个比较复杂的例子：

for /f "delims=" %%a in ('cmd /c "(call myCommand.bat 1>&2 2>nul & call echo %%errorlevel^^%%) 1>&2 2>&1|mtee /d /t /+ sysLog.log" 2^>^&1') do (
	echo call myCommand.bat 的退出码是 %%a
)COPY

1>&2 2>&1 的意思是交换句柄 1 和 2，很久以前发现的小技巧，一直用不上，也不知道有没有人用过

bailong360

回复 6# CrLf


    请教一下在这里交换句柄指向的意义......表示这么高深的代码全然看不懂

shootman2

管道中不允许有独立的内部命令或代码块，所以这个 call myCommand.bat|mtee /d /t /+ sysLog.log 相当于而只 ...
CrLf 发表于 2015-3-24 22:15

    CrLf 大神，太牛了！32个赞给你。但是能不能稍微简化一下，不好理解呀！

CrLf

回复 7# bailong360


回复 8# shootman2


仔细想一下其实不需要交换句柄 1 和 2，化简一下：（外交部发言人 for /f 代表党和人民热烈欢迎英勇突围的 %errorlevel%，并致以最诚挚的问候）

for /f "delims=" %%a in ('"(call myCommand.bat 2>nul & call echo %%errorlevel^^%% 1>&2)|mtee /d /t /+ sysLog.log 2>&1"') do (
        echo call myCommand.bat 的退出码是 %%a
)COPY

----------------------------------------------------------------------------------------------------
经过预处理变成这样：（for /f 欢迎突围的 %errorlevel%）

for /f "delims=" %a in ('"(call myCommand.bat 2>nul & call echo %errorlevel^^% 1>&2)|mtee /d /t /+ sysLog.log 2>&1"') do (
        echo call myCommand.bat 的退出码是 %a
)COPY

----------------------------------------------------------------------------------------------------
for /f 隐含了一个 cmd，执行起来相当于：（这里没发生什么，只是在句柄 1 中包含了 %errorlevel% 的内容）

cmd /c "(call myCommand.bat 2>nul & call echo %errorlevel^^% 1>&2)|mtee /d /t /+ sysLog.log 2>&1"COPY

----------------------------------------------------------------------------------------------------
管道前的代码块触发了一个内层的 cmd，外面的 cmd 执行的代码相当于这样：（因为 mtee 已经取走了所有来自句柄 1 的输出，所以句柄 1 为空，可以放心将句柄 2 再重定向到句柄 1）

(cmd /c "(call myCommand.bat 2>nul & call echo %errorlevel^^% 1>&2)"|mtee /d /t /+ sysLog.log) 2>&1COPY

----------------------------------------------------------------------------------------------------
里面那个隐含的 cmd 执行的是这样：（把这句柄 1 的输出都交给 mtee 进行处理，句柄 2 的未被读取）

cmd /c (call myCommand.bat 2>nul & call echo %errorlevel^% 1>&2)COPY

----------------------------------------------------------------------------------------------------
管道前的部分执行的是这样：（先将 call myCommand.bat 的句柄 1 输出到句柄 2 中，并屏蔽原有的句柄 2 输出，再输出其 %errorlevel% 到正常的句柄 2）

(
        call myCommand.bat 2>nul
        call echo %errorlevel% 1>&2
)
rem 因为 cmd 里不存在的变量不会被扩展，所以只要不存在 errorlevel^ 变量，%errorlevel^% 就不会被扩展COPY

----------------------------------------------------------------------------------------------------
接下来，请按 ctrl+A 全选变成蓝底白字，然后从下往上看粗体字

shootman2

回复  bailong360


回复  shootman2


仔细想一下其实不需要交换句柄 1 和 2，化简一下：（外交部 ...
CrLf 发表于 2015-3-24 23:48

    myCommand.bat是有输出的，当我执行您写的代码后，结果是这样的。。。
1
call myCommand.bat 的退出码是 2015-03-25 12:06:11.833 1231312312
call myCommand.bat 的退出码是 2015-03-25 12:06:11.837 12312312312312312
请按任意键继续. . .

    myCommand.bat内容如下
@echo off
echo 1231312312
echo 12312312312312312
exit /b 1

CrLf

回复 10# shootman2


    ok，那你试试这个：

@echo off
rem 1>nul 3>&1 4>&1
 
(
	(
		(
			call myCommand.bat 2>nul & call echo %%errorlevel^^^^%% 1>&2
		)|(
			mtee /d /t /+ sysLog.log
		)
	) 1>&2 2>&3 | (
		set /p err=&call exit /b %%err^^%%
	)
) 1>&3
 
echo myCommand.bat 的退出码为 %errorlevel%
 
pauseCOPY

用了句柄重定向中的句柄备份、句柄交换两个小技巧
伪代码是这样：

【备份干净的句柄 1 到句柄 3 中备用】
 
(
	(
		(
			【屏蔽 myCommand.bat 句柄 2】
			【输出 %errorlevel% 到句柄 2】
		) | (
			【mtee 接收句柄 1 并将其内容原样输出到句柄 1】
		)
	) 【交换句柄 1 和 2，因为此时句柄 1 是“脏”的，所以从句柄 3 获取原始的句柄 1】 | (
		【获取句柄 1 的值保存到变量】
		【以此变量为退出码设定最终的 %errorlevel%】
	)
) 【将句柄 1 还原为原始的句柄 1】
 
【显示 myCommand.bat 的退出码 %errorlevel%】COPY

shootman2

回复 11# CrLf


    哈哈！实现了，感谢您，对您的景仰有如滔滔江水！

  不过还有个问题，当myCommand.bat有报错的话，是直接打印出来的，您的代码，就直接给屏蔽掉了。
  能帮忙再改改嘛？

CrLf

回复 12# shootman2


如果一定要不生成临时文件的话那没办法，StdOut 和 StdErr 一定要有一个用来输出 %errorlevel%
但如果可以用临时文件就很简单了，你把它输出到文本，比如这样：

@echo off
(call myCommand.bat & call echo %%errorlevel^^%% >errorlevel.txt) |mtee /d /t /+ sysLog.log
set /p error=<errorlevel.txt
echo myCommand.bat 的退出码为 %error%
pauseCOPY

shootman2

回复 13# CrLf


    嗯！正解。。。大神，你太牛了！对您的景仰有如滔滔江水，永远都流不尽啊！

pcl_test

回复 14# shootman2
问题得到解决后请在标题最前面注明[已解决]
http://www.bathome.net/thread-3473-1-1.html