[文本处理] 求助批处理按照字符串的长度来分段读取并把日期数字转换为单词

surftheair

看了delims= 和 tokens= 的命令， 请问能不能按照字符串的长度来分段读取？比如我有一批照片，文件名是2009032901这样的格式，我想把它分成2009，03，29和01，然后把03替换成March，把29替换成29th，吧01替换成Morning。

随风

你的文件名都是10位数字的吗？不多也不少？
“把03替换成March” 那么04 又替换为什么呢？最好把7个都写全 ^_^ 不懂英文
“把01替换成Morning”那么02呢？03呢？99呢？

surftheair

1-4位是年份，这个不变，5-6位是月份，需要把数字替换成对应的英文的月份，7-8位是日期，需要加上st，nd，rd或者th，9-10位是一天中的不同时段，只有01，02，03和04

随风

楼主一次性多给些信息不行吗？都说了不懂英文。
5-6位是月份，需要把数字替换成对应的英文的月份 请给出英文的1-12月
7-8位是日期，需要加上st，nd，rd或者th  请说明什么情况下加st、什么情况下加 nd。。。
9-10位是一天中的不同时段，只有01，02，03和04 请问01替换为Morning、02替换为什么？03、04呢？

surftheair

不好意思。

1月：January，2月：February，3月：March，4月：April，5月：May，6月：June，7月：July，8月：Aguest，9月：September，10月：October，11月：November，12月：December

1st 2nd 3rd 4th 5th 6th 7th 8ht 9th 10th 11th 12th 13th 14th 15th 16 th 17th 18th 19th 20th 21st 22nd 23rd 24th 25th 26th 27th 28th 29th 30th 31st

01=Morning, 02=Noon, 03=Evening, 04=Midnight

随风

基本明白了，只有日期的没找到规律，到底什么情况下才是 th
只好用最笨的办法了。
假设你的照片都是jpg格式。
:

@echo off&setlocal enabledelayedexpansion
set m=January February March April May June July
set m=%m% Aguest September  October November December
for /l %%a in (1 1 31) do set n=0%%a&set "d!N:~-2!=!N:~-2!th"
for %%a in (01 21 31) do set "d%%a=%%ast"
set d02=02nd&set "d22=22nd"
set d03=03rd&set "d23=23rd"
set /a n=100
for %%a in (%m%) do (set /a n+=1&set m!n:~-2!=%%a)
set s01=Morning&set s02=Noon&set s03=Evening&set "s04=Midnight"
for /f "delims=" %%a in ('dir/b/a-d *.jpg') do (
   set "n=%%~na"
   call echo ren "%%a" "!n:~0,4! %%m!n:~4,2!%% %%d!n:~6,2!%% %%s!n:~8,2!%%%%~xa"
)
pause
复制代码

[ 本帖最后由 随风 于 2009-3-29 17:43 编辑 ]

tireless

@echo off&setlocal enabledelayedexpansion
for %%a in (January.401 February.402 March.403 April.404 May.405 June.406 July.407 Aguest.408 September.409 October.410 November.411 September.412 1st.601 2nd.602 3rd.603 4th.604 5th.605 6th.606 7th.607 8ht.608 9th.609 10th.610 11th.611 12th.612 13th.613 14th.614 15th.615 16th.616 17th.617 18th.618 19th.619 20th.620 21st.621 22nd.622 23rd.623 24th.624 25th.625 26th.626 27th.627 28th.628 29th.629 30th.630 31st.631 Morning.801 Noon.802 Evening.803 Midnight.804) do set %%~xa=%%~na

for /f "delims=" %%a in ('dir /a-d/b "*.jpg"') do (
  set n=%%~na
  for /f "tokens=1-3" %%1 in (".4!n:~4,2! .6!n:~6,2! .8!n:~8,2!") do (
    ren "%%a" "!n:~,4! !%%1! !%%2! !%%3!%%~xa"
  )
)
复制代码

[ 本帖最后由 tireless 于 2009-3-29 17:53 编辑 ]

surftheair

哇！好崇拜你啊！只是最后似乎多了一个“echo”？我去掉就能重命名了。

我以为编程的人英语都很好的。^^ 除了11，12和13，其他的情况下，尾数是1就跟st，尾数是2就跟nd，尾数是3就跟rd，其他情况下都跟th，这是初中英语的内容，呵呵 ！

再次感谢！！！！！

随风

通常给别人的代码都是测试代码，为防代码有误导致不必要的麻烦，所以一般都加上echo只起到演示作用，确定无误后，删除echo就可以正确执行。
bat 应该不算编程，26个字母分开来我倒是认识，合在一起就它认识我，我不认识它了。
编写bat代码和英文没有必然联系。
另：6楼代码有一处笔误，23应该是rd 写成了nd 以改正。

[ 本帖最后由 随风 于 2009-3-29 17:44 编辑 ]

xxx

看着这样的代码就头晕了...

Batcher

哪里不懂就问，会有人给你解释的