[文件操作] BAT脚本FOR遍历，删除文件，怎样排除目录和文件？

7758234

排除C盘下指定目录下所有的PDF DOC XLS文件，进行遍历C盘、D盘、E盘所有PDF、DOC、XLS文件，进行删除处理

77七

@echo off
rem 批处理保存为ansi编码格式。
for /r "C:\指定目录" %%i in (*.pdf *.doc *.xls) do set _"%%i"=1
for %%a in (c d e) do call :1 "%%a:\"
pause
exit

        :1
        for /r "%~1" %%b in (*.pdf *.doc *.xls) do (
                if not defined _"%%b" (
                        rem 效果满意，则删除echo再执行
                        echo del "%%b"
                )
        )
        exit /b
复制代码

代码有问题，参考5楼。

qixiaobin0715

回复 1# 7758234
这种操作还是要小心，一旦删错文件，后悔晚矣！！！

Batcher

回复 1# 7758234


请参考Q-04把bat文件保存为ANSI编码：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA

@echo off
REM 设置待排除的目录（注意以\结尾）
set "ExFolder=C:\Users\Administrator\Desktop\"
for %%a in (C D E) do (
    if exist %%a:\ (
        echo 正在搜索%%a:\
        pushd %%a:\
        for /f "delims=" %%b in ('dir /b /s /a-d *.pdf *.doc *.xls 2^>nul ^| find /v /i "%ExFolder%"') do (
            REM 如果显示的结果没有问题，把下面的echo去掉再次执行即可删除文件
            echo del /f /q "%%b"
        )
        popd
    )
)
pause
复制代码

Batcher

回复 2# 77七


    如果待排除的文件较多，可能超出变量上限。

77七

回复 5# Batcher


   谢谢站长指点！没考虑到指定目录下会存在大量待排除文件。

77七

重来一个。

@echo off
rem 批处理保存为ansi编码格式。请谨慎使用！
set "folder=C:\指定目录"
for %%a in (pdf doc xls) do attrib +H "%folder%\*.%%a" /s
echo 确认待排除文件隐藏成功，则继续执行
pause
for %%a in (c d e) do (
        pushd "%%a:\"
        del /s /q *.pdf;*.doc;*.xls
        popd
)
for %%a in (pdf doc xls) do attrib -H "%folder%\*.%%a" /s
pause
复制代码

7758234

回复 7# 77七


    谢谢，这个我看明白了，排除文件添加隐藏属性，好办法，今天又学习了

buyiyang

试试wmic，遍历所有盘

@echo off
rem 指定排除目录
set "exfolder=C:\Windows\"

set "exfolder=%exfolder:\=\\%"
wmic datafile where "not name like '%exfolder%%%' and (Extension='pdf' or Extension='doc' or Extension='xls')" get name /value | findstr .
pause
pause>nul&echo,确认删除？
pause>nul&echo,确认删除？
wmic datafile where "not name like '%exfolder%%%' and (Extension='pdf' or Extension='doc' or Extension='xls')" call delete
复制代码

7758234

回复 4# Batcher


    站长，您好，请问多个目录要如何配置添加？

7758234

回复 9# buyiyang


    我测试，执行，提示
节点 - CSG21659Q5
错误:
描述 = 无效查询
请按任意键继续. . .

7758234

回复 7# 77七


    你好，如果多个目录要如何设置添加

77七

回复 12# 7758234

@echo off
rem 批处理保存为ansi编码格式。请谨慎使用！
set "folder1=C:\指定目录1"
set "folder2=C:\指定目录2"
for %%a in (pdf doc xls) do (
	attrib +H "%folder1%\*.%%a" /s
	attrib +H "%folder2%\*.%%a" /s
)
echo 确认待排除文件隐藏成功，则继续执行
pause
for %%a in (c d e) do (
        pushd "%%a:\"
        del /s /q *.pdf;*.doc;*.xls
        popd
)
for %%a in (pdf doc xls) do (
	attrib -H "%folder1%\*.%%a" /s
	attrib -H "%folder2%\*.%%a" /s
)
pause
复制代码

Batcher

回复 10# 7758234


方法1.bat

@echo off
REM 设置待排除的目录（注意以\结尾）
set "ExFolder1=C:\Users\Administrator\Desktop\"
set "ExFolder2=C:\Program Files\"
for %%a in (C D E) do (
    if exist %%a:\ (
        echo 正在搜索%%a:\
        pushd %%a:\
        for /f "delims=" %%b in ('dir /b /s /a-d *.pdf *.doc *.xls 2^>nul ^| find /v /i "%ExFolder1%" ^| find /v /i "%ExFolder2%" ') do (
            REM 如果显示的结果没有问题，把下面的echo去掉再次执行即可删除文件
            echo del /f /q "%%b"
        )
        popd
    )
)
pause
复制代码

7758234

回复 14# Batcher


    谢谢