Zhanggli

现在需要删除的是T2-M05之间的代码，包括T2行，但是不包括M05，不同文件这两者之间的代码会有不同行数，另外在M05后面加一个指令M55，多个文件需要同样处理，我总是循环不起来。

hfxiang

回复 15# Zhanggli
可用第3方工具sed（ http://bcn.bathome.net/tool/4.9/sed.exe ）

sed -e"/T2/,/M05/{/M05/!d;s/M05/M05\nM55/;}" 1.txt>2.txt
复制代码

qixiaobin0715

@echo off
for /f "delims=" %%x in ('dir /b /a-d *.txt') do (
    set n=0
    (for /f "delims=" %%i in ('type "%%x"') do (
        if "%%i"=="T2" set n=
        if defined n echo,%%i
        if "%%i"=="M05" (
            set n=0
            echo,%%i
            echo,M55
        )
    ))>"New-%%x"
)
pause
复制代码

Zhanggli

感谢qixiaobin，真的很简洁明了，再次感谢

Zhanggli

我之前的思路也是和前面的定义了两个字符串变量来处理反倒没搞好

Zhanggli

不过如果是多个文件同样处理的话需要引入临时文件变量temp吧？

77七

回复 16# Zhanggli


  

@echo off
for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
	call :1 "%%i"
)
pause & exit

	:1
	setlocal
	for /f "tokens=1* delims=:" %%a in ('findstr /nxr /c:"M05" /c:"T2" "%~1"') do (
		if not defined s (
			set s=%%a
		) else (
			set e=%%a
		)
	)
	(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "%~1"') do (
		if %%a lss %s% (
			echo=%%b
		) else if %%a equ %e% (
			echo=%%b
			echo=M55
		) else if %%a gtr %e% (
			echo=%%b
		)
	))>$
	move /y $ "%~1"
	endlocal
	exit /b
复制代码

qixiaobin0715

回复 21# Zhanggli
已修改

Zhanggli

太赞了，我试了好几次循环都没成功，底子还是太弱了，再次感谢

lovekix

回复 9# 77七


    微软总把 制表符  换成  空格   （有时候 9个   有时候8个）

有时候  还在会把
<Application Id="WindowsBackup" Executable="WindowsBackupClient.exe" EntryPoint="WindowsBackup.App" uap10:TrustLevel="mediumIL" uap10:RuntimeBehavior="windowsApp">"

替换成
<Application Id="WindowsBackup" Executable="WindowsBackupClient.exe" EntryPoint="WindowsBackup.App" uap10/4:TrustLevel="mediumIL" uap10/4:RuntimeBehavior="windowsApp">"

还有其他办法吗？

77七

回复 25# lovekix


   请把出现问题的文件传上来，看看是什么原因。

lovekix

回复 26# 77七


https://wwrj.lanzouu.com/i461Y1ggo9zc

77七

回复 27# lovekix

@echo off
set "str1=<Application Id="WindowsBackup" Executable="WindowsBackupClient.exe" EntryPoint="WindowsBackup.App" uap10[/]*[4]*:TrustLevel="mediumIL" uap10[/]*[4]*:RuntimeBehavior="windowsApp">"
set "str2=</Application>"
set "str1=%str1:"="""%"
for /f "tokens=1 delims=:" %%a in ('findstr /nxr /c:"[ 	]*%str1%" "appxmanifest.xml"') do set start=%%a
for /f "tokens=1 delims=:" %%a in ('findstr /nxr /c:"[ 	]*%str2%" "appxmanifest.xml"') do (
	if %%a gtr %start% (
		set end=%%a
		goto :next
	)
)
:next
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "appxmanifest.xml"') do (
	if %%a lss %start% echo=%%b
	if %%a gtr %end% echo=%%b
))>"appxmanifest-2.xml"
pause
复制代码

lovekix

回复 28# 77七

这行代码  可以用* 代替后面的吗？

set "str1=<Application Id="WindowsBackup" Executable="WindowsBackupClient.exe" EntryPoint="WindowsBackup.App" uap10[/]*[4]*:TrustLevel="mediumIL" uap10[/]*[4]*:RuntimeBehavior="windowsApp">"
复制代码

set "str1=<Application Id="WindowsBackup" Executable="WindowsBackupClient.exe" EntryPoint="WindowsBackup.App"*>"
复制代码

77七

回复 29# lovekix


   .*
前面加个.