[文件操作] [已解决]批处理如何复制文件同名不覆盖，且重命名？

qq872862088

for /f "delims=" %%a in ('dir /b /s .\*.txt') do (
copy  "%%a" .\new /-y
)
复制代码

上述代码只能提醒是否覆盖，我想实现同名文件如F:\1.txt和F:\1\1.txt拷进同一文件夹时，后拷的1.txt变成1(1).txt,求指教

aloha20200628

回复 18# newswan

每家都有几曲乡愁，彼此彼此，一方水土养一方人，苦乐痛痒其实一脉相通...

newswan

powershell 不必纠结 bat 特殊字符

$sour = ".\old"
$dest = ".\new"
$ext = "*.txt"

Get-ChildItem -Path $sour -Filter $ext | ForEach-Object {
	if ( -Not (Test-Path ( Join-Path  -Path $dest  -ChildPath $_.Name )) ) {
		Copy-Item  -Path $_.FullName  -Destination ( Join-Path -Path $dest -ChildPath $_.Name )
	} else {
		$i = 0
		do {
			$i++
		}
		while ( Test-Path ( Join-Path -Path $dest -ChildPath ($_.BaseName + $i + $_.Extension) ) )
		Copy-Item  -Path $_.FullName  -Destination ( Join-Path -Path $dest -ChildPath ($_.BaseName + $i + $_.Extension) )
	}
	
}
复制代码

aloha20200628

本帖楼主的原意是将多个子目录中的同名文件复制到目标目录时须作更名处理，其更名格式如 *(1).*，因源文件不包含类似 *(1).* 的文件，故解法要比另帖（http://www.bathome.net/thread-69152-1-1.html）来的轻快，但若假定源文件名可能包含 !&^ 等特殊字符时，其解法则须另辟捷径了》既要放弃延迟变量（以便兼容源文件名中的特殊字符），又要在循环中采用计数器（以便顺序匹配目标文件名），还要逃避复合语块中%n%变量的预处理...

@echo off &set "d1=c:\源目录" &set "d2=d:\目标目录"
pushd "%d2%"
for /f "delims=" %%a in (' dir /b/s/a-d "%d1%\*.txt" ') do (
	if not exist "%%~nxa" (copy "%%a") else (
		set/a "n=1" &set "F=%%a" &set "nF=%%~na" &set "xF=%%~xa"
		(call :copy#n)
	)
)	
popd &pause &exit/b
:copy#n
	if exist "%nF%(%n%)%xF%" (set/a "n+=1" &goto :copy#n)
	copy "%F%" "%nF%(%n%)%xF%" &exit/b
复制代码

77七

@echo off
set f1=d:\from
set f2=d:\to

cd /d "%f1%"
for /f "delims=" %%i in ('2^>nul dir /b /s /a-d *.txt *.rar') do (
	set f=%%i
	set nx=%%~nxi
	set x=%%~xi
	set n=1
	call :1 "%%~nxi"
)
pause
exit

	:1
	for /f "tokens=1* delims=(" %%a in ("%~1") do (
		if "%%b" neq "" (
			call :1 "%%b"
		) else (
			for /f "tokens=* delims=0123456789" %%c in ("%%a") do (
				if "%%c" equ ")%x%" (
					call set "str=%%nx:(%%a=%x%%%"
				) else (
					set "str=%nx%"
				)
				setlocal enabledelayedexpansion
				for /f "delims=" %%e in ("!str!") do (
					endlocal
					call :2 "%%e"
				)
			)
		)
	)
	exit /b

	:2
	set /a n+=1
	if not exist "%f2%\%~n1%~x1" (
		copy "%f%" "%f2%\%~n1%~x1"
	) else if not exist "%f2%\%~n1(%n%)%~x1" (
		copy "%f%" "%f2%\%~n1(%n%)%~x1"
	) else (
		goto :2
	)
	exit /b
复制代码

WHY

另外一种办法：

@echo off & setlocal enabledelayedexpansion    
if not "%~1"==":" (
    md d:\new 2>nul
    for /f "tokens=1*delims=/" %%i in ('"%~f0" :^|sort') do (
        if /i "%%i"=="!strName!" (
            set /a n+=1
            copy "%%j" "d:\new\%%~ni(!n!)%%~xi"
        ) else (
            set "n="
            copy "%%j" d:\new\
        )
        set "strName=%%i"
    )
    pause
) else (
    for /r %%i in (*) do echo %%~nxi/%%i
)
复制代码

CrLf

回复 4# pcl_test


    for %%i in (!fn!) do
这里有隐患

qq872862088

回复 3# WHY


    3楼和11楼完美解决了我的问题了，感谢感谢

qq872862088

回复 11# pcl_test


    文件名格式就是这样，果然是-号

pcl_test

回复 10# qq872862088

空格不影响，该是其他字符影响

3楼的dir /b /s /a-d改为dir /b /s /a-d *.txt
或6楼in (*)改为in (*.txt)皆可

qq872862088

回复 8# pcl_test


    的确，没有特殊字符就很好用，但我的文件名大多都是以日期起名的，都带有空格，有什么好方法吗

qq872862088

回复 6# WHY


    测试过，只有2个同名文件，但新文件夹出现3个同名文件，还有for /r %%i in (*) do里的*改成'dir /b /s *.txt'找不到指定文件...不知道怎么改

pcl_test

回复 5# WHY

这种方法是有此弊端的，但对于一般的文件名，效果却是极好，故也提一下
回复 7# qq872862088
不是，只是文件名有特殊字符而已

qq872862088

回复 4# pcl_test


    文件覆盖了，cmd里出现“运算符不存在”这种问题，我电脑问题吗？

WHY

for + call 方案，但效率绝逼不高

@echo off
for /r %%i in (*) do (
    set "strName=%%~nxi" & set "n="
    call :CP "%%i"
)
pause & exit

:CP
if not exist "d:\new\%strName%" copy "%~1" "d:\new\%strName%" & goto :EOF
if exist "d:\new\%strName%" set /a n+=1
set "strName=%~n1(%n%)%~x1"
goto :CP
复制代码